CMakeLists.txt
author Ryan C. Gordon <icculus@icculus.org>
Thu, 18 Jun 2015 22:34:39 -0400
changeset 9758 cf4d3ee2b37b
parent 9731 a8140c580b85
child 9853 3d08cb641cd5
permissions -rw-r--r--
CMake fixes for MingW (thanks, Ozkan!).

- ignore DXSDK_DIR for mingw environment
- use dxerr8 instead of dxerr for mingw.

Partially fixes Bugzilla #3016.
     1 if(${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
     2   message(FATAL_ERROR "Prevented in-tree built. Please create a build directory outside of the SDL source code and call cmake from there")
     3 endif()
     4 
     5 cmake_minimum_required(VERSION 2.8)
     6 project(SDL2 C)
     7 include(CheckFunctionExists)
     8 include(CheckLibraryExists)
     9 include(CheckIncludeFiles)
    10 include(CheckIncludeFile)
    11 include(CheckSymbolExists)
    12 include(CheckCSourceRuns)
    13 include(CheckCCompilerFlag)
    14 include(CheckTypeSize)
    15 include(CheckStructHasMember)
    16 include(CMakeDependentOption)
    17 include(FindPkgConfig)
    18 set(CMAKE_MODULE_PATH "${SDL2_SOURCE_DIR}/cmake")
    19 include(${SDL2_SOURCE_DIR}/cmake/macros.cmake)
    20 include(${SDL2_SOURCE_DIR}/cmake/sdlchecks.cmake)
    21 
    22 # General settings
    23 # Edit include/SDL_version.h and change the version, then:
    24 #   SDL_MICRO_VERSION += 1;
    25 #   SDL_INTERFACE_AGE += 1;
    26 #   SDL_BINARY_AGE += 1;
    27 # if any functions have been added, set SDL_INTERFACE_AGE to 0.
    28 # if backwards compatibility has been broken,
    29 # set SDL_BINARY_AGE and SDL_INTERFACE_AGE to 0.
    30 set(SDL_MAJOR_VERSION 2)
    31 set(SDL_MINOR_VERSION 0)
    32 set(SDL_MICRO_VERSION 4)
    33 set(SDL_INTERFACE_AGE 0)
    34 set(SDL_BINARY_AGE 4)
    35 set(SDL_VERSION "${SDL_MAJOR_VERSION}.${SDL_MINOR_VERSION}.${SDL_MICRO_VERSION}")
    36 
    37 # Calculate a libtool-like version number
    38 math(EXPR LT_CURRENT "${SDL_MICRO_VERSION} - ${SDL_INTERFACE_AGE}")
    39 math(EXPR LT_AGE "${SDL_BINARY_AGE} - ${SDL_INTERFACE_AGE}")
    40 math(EXPR LT_MAJOR "${LT_CURRENT}- ${LT_AGE}")
    41 set(LT_REVISION "${SDL_INTERFACE_AGE}")
    42 set(LT_RELEASE "${SDL_MAJOR_VERSION}.${SDL_MINOR_VERSION}")
    43 set(LT_VERSION "${LT_MAJOR}.${LT_AGE}.${LT_REVISION}")
    44 
    45 message(STATUS "${LT_VERSION} :: ${LT_AGE} :: ${LT_REVISION} :: ${LT_CURRENT} :: ${LT_RELEASE}")
    46 
    47 # General settings & flags
    48 set(LIBRARY_OUTPUT_DIRECTORY "build")
    49 # Check for 64 or 32 bit
    50 set(SIZEOF_VOIDP ${CMAKE_SIZEOF_VOID_P})
    51 if(CMAKE_SIZEOF_VOID_P EQUAL 8)
    52   set(ARCH_64 TRUE)
    53   set(PROCESSOR_ARCH "x64")
    54 else()
    55   set(ARCH_64 FALSE)
    56   set(PROCESSOR_ARCH "x86")
    57 endif()
    58 set(LIBNAME SDL2)
    59 if(NOT LIBTYPE)
    60   set(LIBTYPE SHARED)
    61 endif()
    62 
    63 # Get the platform
    64 if(WIN32)
    65   if(NOT WINDOWS)
    66     set(WINDOWS TRUE)
    67   endif()
    68 elseif(UNIX AND NOT APPLE)
    69   if(CMAKE_SYSTEM_NAME MATCHES ".*Linux")
    70     set(LINUX TRUE)
    71   elseif(CMAKE_SYSTEM_NAME MATCHES "kFreeBSD.*")
    72     set(FREEBSD TRUE)
    73   elseif(CMAKE_SYSTEM_NAME MATCHES "kNetBSD.*|NetBSD.*")
    74     set(NETBSD TRUE)
    75   elseif(CMAKE_SYSTEM_NAME MATCHES "kOpenBSD.*|OpenBSD.*")
    76     set(OPENBSD TRUE)
    77   elseif(CMAKE_SYSTEM_NAME MATCHES ".*GNU.*")
    78     set(GNU TRUE)
    79   elseif(CMAKE_SYSTEM_NAME MATCHES ".*BSDI.*")
    80     set(BSDI TRUE)
    81   elseif(CMAKE_SYSTEM_NAME MATCHES "DragonFly.*|FreeBSD")
    82     set(FREEBSD TRUE)
    83   elseif(CMAKE_SYSTEM_NAME MATCHES "SYSV5.*")
    84     set(SYSV5 TRUE)
    85   elseif(CMAKE_SYSTEM_NAME MATCHES "Solaris.*")
    86     set(SOLARIS TRUE)
    87   elseif(CMAKE_SYSTEM_NAME MATCHES "HP-UX.*")
    88     set(HPUX TRUE)
    89   elseif(CMAKE_SYSTEM_NAME MATCHES "AIX.*")
    90     set(AIX TRUE)
    91   elseif(CMAKE_SYSTEM_NAME MATCHES "Minix.*")
    92     set(MINIX TRUE)
    93   endif()
    94 elseif(APPLE)
    95   if(CMAKE_SYSTEM_NAME MATCHES ".*Darwin.*")
    96     set(DARWIN TRUE)
    97   elseif(CMAKE_SYSTEM_NAME MATCHES ".*MacOS.*")
    98     set(MACOSX TRUE)
    99   endif()
   100   # TODO: iOS?
   101 elseif(CMAKE_SYSTEM_NAME MATCHES "BeOS.*")
   102   message_error("BeOS support has been removed as of SDL 2.0.2.")
   103 elseif(CMAKE_SYSTEM_NAME MATCHES "Haiku.*")
   104   set(HAIKU TRUE)
   105 endif()
   106 
   107 # Don't mistake osx for unix
   108 if(UNIX AND NOT APPLE)
   109   set(UNIX_SYS ON)
   110 else()
   111   set(UNIX_SYS OFF)
   112 endif()
   113 
   114 if(UNIX OR APPLE)
   115   set(UNIX_OR_MAC_SYS ON)
   116 else()
   117   set(UNIX_OR_MAC_SYS OFF)
   118 endif()
   119 
   120 if (UNIX_OR_MAC_SYS AND NOT EMSCRIPTEN) # JavaScript does not yet have threading support, so disable pthreads when building for Emscripten.
   121   set(SDL_PTHREADS_ENABLED_BY_DEFAULT ON)
   122 else()
   123   set(SDL_PTHREADS_ENABLED_BY_DEFAULT OFF)
   124 endif()
   125 
   126 # Default option knobs
   127 if(APPLE OR ARCH_64)
   128   set(OPT_DEF_SSEMATH ON)
   129 endif()
   130 if(UNIX OR MINGW OR MSYS)
   131   set(OPT_DEF_LIBC ON)
   132 endif()
   133 
   134 # Compiler info
   135 if(CMAKE_COMPILER_IS_GNUCC)
   136   set(USE_GCC TRUE)
   137   set(OPT_DEF_ASM TRUE)
   138 elseif(CMAKE_C_COMPILER_ID MATCHES "Clang")
   139   set(USE_CLANG TRUE)
   140   set(OPT_DEF_ASM TRUE)
   141 elseif(MSVC_VERSION GREATER 1400) # VisualStudio 8.0+
   142   set(OPT_DEF_ASM TRUE)
   143   #set(CMAKE_C_FLAGS "/ZI /WX- /
   144 else()
   145   set(OPT_DEF_ASM FALSE)
   146 endif()
   147 
   148 # Default flags, if not set otherwise
   149 if("$ENV{CFLAGS}" STREQUAL "")
   150   if(USE_GCC OR USE_CLANG)
   151     set(CMAKE_C_FLAGS "-g -O3")
   152   endif()
   153 else()
   154   set(CMAKE_C_FLAGS "$ENV{CFLAGS}")
   155   list(APPEND EXTRA_CFLAGS "$ENV{CFLAGS}")
   156 endif()
   157 if(NOT ("$ENV{CFLAGS}" STREQUAL "")) # Hackish, but does the trick on Win32
   158   list(APPEND EXTRA_LDFLAGS "$ENV{LDFLAGS}")
   159 endif()
   160 
   161 if(MSVC)
   162   option(FORCE_STATIC_VCRT "Force /MT for static VC runtimes" OFF)
   163   if(FORCE_STATIC_VCRT)
   164     foreach(flag_var
   165         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
   166         CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO)
   167       if(${flag_var} MATCHES "/MD")
   168         string(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
   169       endif()
   170     endforeach()
   171   endif()
   172 endif()
   173 
   174 # Those are used for pkg-config and friends, so that the SDL2.pc, sdl2-config,
   175 # etc. are created correctly.
   176 set(SDL_LIBS "-lSDL2")
   177 set(SDL_CFLAGS "")
   178 
   179 # Emscripten toolchain has a nonempty default value for this, and the checks 
   180 # in this file need to change that, so remember the original value, and 
   181 # restore back to that afterwards. For check_function_exists() to work in
   182 # Emscripten, this value must be at its default value.
   183 set(ORIG_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
   184 
   185 if(CYGWIN)
   186   # We build SDL on cygwin without the UNIX emulation layer
   187   include_directories("-I/usr/include/mingw")
   188   set(CMAKE_REQUIRED_FLAGS "-mno-cygwin")
   189   check_c_source_compiles("int main(int argc, char **argv) {}"
   190     HAVE_GCC_NO_CYGWIN)
   191   set(CMAKE_REQUIRED_FLAGS ${ORIG_CMAKE_REQUIRED_FLAGS})
   192   if(HAVE_GCC_NO_CYGWIN)
   193     list(APPEND EXTRA_LDFLAGS "-mno-cygwin")
   194     list(APPEND SDL_LIBS "-mno-cygwin")
   195   endif()
   196   set(SDL_CFLAGS "${SDL_CFLAGS} -I/usr/include/mingw")
   197 endif()
   198 
   199 add_definitions(-DUSING_GENERATED_CONFIG_H)
   200 # General includes
   201 include_directories(${SDL2_BINARY_DIR}/include ${SDL2_SOURCE_DIR}/include)
   202 
   203 # All these ENABLED_BY_DEFAULT vars will default to ON if not specified, so
   204 #  you only need to have a platform override them if they are disabling.
   205 set(OPT_DEF_ASM TRUE)
   206 if(EMSCRIPTEN)
   207   # Set up default values for the currently supported set of subsystems:
   208   # Emscripten/Javascript does not have assembly support, a dynamic library 
   209   # loading architecture, low-level CPU inspection or multithreading.
   210   set(OPT_DEF_ASM FALSE)
   211   set(SDL_SHARED_ENABLED_BY_DEFAULT OFF)
   212   set(SDL_ATOMIC_ENABLED_BY_DEFAULT OFF)
   213   set(SDL_THREADS_ENABLED_BY_DEFAULT OFF)
   214   set(SDL_LOADSO_ENABLED_BY_DEFAULT OFF)
   215   set(SDL_CPUINFO_ENABLED_BY_DEFAULT OFF)
   216   set(SDL_DLOPEN_ENABLED_BY_DEFAULT OFF)
   217 endif()
   218 
   219 if (NOT DEFINED SDL_SHARED_ENABLED_BY_DEFAULT)
   220     set(SDL_SHARED_ENABLED_BY_DEFAULT ON)
   221 endif()
   222 
   223 set(SDL_SUBSYSTEMS
   224     Atomic Audio Video Render Events Joystick Haptic Power Threads Timers
   225     File Loadso CPUinfo Filesystem Dlopen)
   226 foreach(_SUB ${SDL_SUBSYSTEMS})
   227   string(TOUPPER ${_SUB} _OPT)
   228   if (NOT DEFINED SDL_${_OPT}_ENABLED_BY_DEFAULT)
   229     set(SDL_${_OPT}_ENABLED_BY_DEFAULT ON)
   230   endif()
   231   option(SDL_${_OPT} "Enable the ${_SUB} subsystem" ${SDL_${_OPT}_ENABLED_BY_DEFAULT})
   232 endforeach()
   233 
   234 option_string(ASSERTIONS "Enable internal sanity checks (auto/disabled/release/enabled/paranoid)" "auto")
   235 #set_option(DEPENDENCY_TRACKING "Use gcc -MMD -MT dependency tracking" ON)
   236 set_option(LIBC                "Use the system C library" ${OPT_DEF_LIBC})
   237 set_option(GCC_ATOMICS         "Use gcc builtin atomics" ${USE_GCC})
   238 set_option(ASSEMBLY            "Enable assembly routines" ${OPT_DEF_ASM})
   239 set_option(SSEMATH             "Allow GCC to use SSE floating point math" ${OPT_DEF_SSEMATH})
   240 set_option(MMX                 "Use MMX assembly routines" ${OPT_DEF_ASM})
   241 set_option(3DNOW               "Use 3Dnow! MMX assembly routines" ${OPT_DEF_ASM})
   242 set_option(SSE                 "Use SSE assembly routines" ${OPT_DEF_ASM})
   243 set_option(SSE2                "Use SSE2 assembly routines" ${OPT_DEF_SSEMATH})
   244 set_option(ALTIVEC             "Use Altivec assembly routines" ${OPT_DEF_ASM})
   245 set_option(DISKAUDIO           "Support the disk writer audio driver" ON)
   246 set_option(DUMMYAUDIO          "Support the dummy audio driver" ON)
   247 set_option(VIDEO_DIRECTFB      "Use DirectFB video driver" OFF)
   248 dep_option(DIRECTFB_SHARED     "Dynamically load directfb support" ON "VIDEO_DIRECTFB" OFF)
   249 set_option(FUSIONSOUND         "Use FusionSound audio driver" OFF)
   250 dep_option(FUSIONSOUND_SHARED  "Dynamically load fusionsound audio support" ON "FUSIONSOUND" OFF)
   251 set_option(VIDEO_DUMMY         "Use dummy video driver" ON)
   252 set_option(VIDEO_OPENGL        "Include OpenGL support" ON)
   253 set_option(VIDEO_OPENGLES      "Include OpenGL ES support" ON)
   254 set_option(PTHREADS            "Use POSIX threads for multi-threading" ${SDL_PTHREADS_ENABLED_BY_DEFAULT})
   255 dep_option(PTHREADS_SEM        "Use pthread semaphores" ON "PTHREADS" OFF)
   256 set_option(SDL_DLOPEN          "Use dlopen for shared object loading" ${SDL_DLOPEN_ENABLED_BY_DEFAULT})
   257 set_option(OSS                 "Support the OSS audio API" ${UNIX_SYS})
   258 set_option(ALSA                "Support the ALSA audio API" ${UNIX_SYS})
   259 dep_option(ALSA_SHARED         "Dynamically load ALSA audio support" ON "ALSA" OFF)
   260 set_option(ESD                 "Support the Enlightened Sound Daemon" ${UNIX_SYS})
   261 dep_option(ESD_SHARED          "Dynamically load ESD audio support" ON "ESD" OFF)
   262 set_option(PULSEAUDIO          "Use PulseAudio" ${UNIX_SYS})
   263 dep_option(PULSEAUDIO_SHARED   "Dynamically load PulseAudio support" ON "PULSEAUDIO" OFF)
   264 set_option(ARTS                "Support the Analog Real Time Synthesizer" ${UNIX_SYS})
   265 dep_option(ARTS_SHARED         "Dynamically load aRts audio support" ON "ARTS" OFF)
   266 set_option(NAS                 "Support the NAS audio API" ${UNIX_SYS})
   267 set_option(NAS_SHARED          "Dynamically load NAS audio API" ${UNIX_SYS})
   268 set_option(SNDIO               "Support the sndio audio API" ${UNIX_SYS})
   269 set_option(RPATH               "Use an rpath when linking SDL" ${UNIX_SYS})
   270 set_option(CLOCK_GETTIME       "Use clock_gettime() instead of gettimeofday()" OFF)
   271 set_option(INPUT_TSLIB         "Use the Touchscreen library for input" ${UNIX_SYS})
   272 set_option(VIDEO_X11           "Use X11 video driver" ${UNIX_SYS})
   273 set_option(VIDEO_WAYLAND       "Use Wayland video driver" ${UNIX_SYS})
   274 dep_option(WAYLAND_SHARED      "Dynamically load Wayland support" ON "VIDEO_WAYLAND" OFF)
   275 dep_option(VIDEO_WAYLAND_QT_TOUCH  "QtWayland server support for Wayland video driver" ON "VIDEO_WAYLAND" OFF)
   276 set_option(VIDEO_MIR           "Use Mir video driver" ${UNIX_SYS})
   277 dep_option(MIR_SHARED          "Dynamically load Mir support" ON "VIDEO_MIR" OFF)
   278 set_option(VIDEO_RPI           "Use Raspberry Pi video driver" ${UNIX_SYS})
   279 dep_option(X11_SHARED          "Dynamically load X11 support" ON "VIDEO_X11" OFF)
   280 set(SDL_X11_OPTIONS Xcursor Xinerama XInput Xrandr Xscrnsaver XShape Xvm)
   281 foreach(_SUB ${SDL_X11_OPTIONS})
   282   string(TOUPPER "VIDEO_X11_${_SUB}" _OPT)
   283   dep_option(${_OPT}           "Enable ${_SUB} support" ON "VIDEO_X11" OFF)
   284 endforeach()
   285 set_option(VIDEO_COCOA         "Use Cocoa video driver" ${APPLE})
   286 set_option(DIRECTX             "Use DirectX for Windows audio/video" ${WINDOWS})
   287 set_option(RENDER_D3D          "Enable the Direct3D render driver" ${WINDOWS})
   288 set_option(VIDEO_VIVANTE       "Use Vivante EGL video driver" ${UNIX_SYS})
   289 
   290 # TODO: We should (should we?) respect cmake's ${BUILD_SHARED_LIBS} flag here
   291 # The options below are for compatibility to configure's default behaviour.
   292 set(SDL_SHARED ${SDL_SHARED_ENABLED_BY_DEFAULT} CACHE BOOL "Build a shared version of the library")
   293 set(SDL_STATIC ON CACHE BOOL "Build a static version of the library")
   294 
   295 # General source files
   296 file(GLOB SOURCE_FILES
   297   ${SDL2_SOURCE_DIR}/src/*.c
   298   ${SDL2_SOURCE_DIR}/src/atomic/*.c
   299   ${SDL2_SOURCE_DIR}/src/audio/*.c
   300   ${SDL2_SOURCE_DIR}/src/cpuinfo/*.c
   301   ${SDL2_SOURCE_DIR}/src/dynapi/*.c
   302   ${SDL2_SOURCE_DIR}/src/events/*.c
   303   ${SDL2_SOURCE_DIR}/src/file/*.c
   304   ${SDL2_SOURCE_DIR}/src/libm/*.c
   305   ${SDL2_SOURCE_DIR}/src/render/*.c
   306   ${SDL2_SOURCE_DIR}/src/render/*/*.c
   307   ${SDL2_SOURCE_DIR}/src/stdlib/*.c
   308   ${SDL2_SOURCE_DIR}/src/thread/*.c
   309   ${SDL2_SOURCE_DIR}/src/timer/*.c
   310   ${SDL2_SOURCE_DIR}/src/video/*.c)
   311 
   312 
   313 if(ASSERTIONS STREQUAL "auto")
   314   # Do nada - use optimization settings to determine the assertion level
   315 elseif(ASSERTIONS STREQUAL "disabled")
   316   set(SDL_DEFAULT_ASSERT_LEVEL 0)
   317 elseif(ASSERTIONS STREQUAL "release")
   318   set(SDL_DEFAULT_ASSERT_LEVEL 1)
   319 elseif(ASSERTIONS STREQUAL "enabled")
   320   set(SDL_DEFAULT_ASSERT_LEVEL 2)
   321 elseif(ASSERTIONS STREQUAL "paranoid")
   322   set(SDL_DEFAULT_ASSERT_LEVEL 3)
   323 else()
   324   message_error("unknown assertion level")
   325 endif()
   326 set(HAVE_ASSERTIONS ${ASSERTIONS})
   327 
   328 # Compiler option evaluation
   329 if(USE_GCC OR USE_CLANG)
   330   if(DEPENDENCY_TRACKING)
   331     check_c_source_compiles("
   332         #if !defined(__GNUC__) || __GNUC__ < 3
   333         #error Dependency tracking requires GCC 3.0 or newer
   334         #endif
   335         int main(int argc, char **argv) { }" HAVE_DEPENDENCY_TRACKING)
   336   endif()
   337 
   338   if(GCC_ATOMICS)
   339     check_c_source_compiles("int main(int argc, char **argv) {
   340         int a;
   341         void *x, *y, *z;
   342         __sync_lock_test_and_set(&a, 4);
   343         __sync_lock_test_and_set(&x, y);
   344         __sync_fetch_and_add(&a, 1);
   345         __sync_bool_compare_and_swap(&a, 5, 10);
   346         __sync_bool_compare_and_swap(&x, y, z); }" HAVE_GCC_ATOMICS)
   347     if(NOT HAVE_GCC_ATOMICS)
   348       check_c_source_compiles("int main(int argc, char **argv) {
   349           int a;
   350           __sync_lock_test_and_set(&a, 1);
   351           __sync_lock_release(&a); }" HAVE_GCC_SYNC_LOCK_TEST_AND_SET)
   352     endif()
   353   endif()
   354 
   355   set(CMAKE_REQUIRED_FLAGS "-mpreferred-stack-boundary=2")
   356   check_c_source_compiles("int x = 0; int main(int argc, char **argv) {}"
   357     HAVE_GCC_PREFERRED_STACK_BOUNDARY)
   358   set(CMAKE_REQUIRED_FLAGS ${ORIG_CMAKE_REQUIRED_FLAGS})
   359 
   360   set(CMAKE_REQUIRED_FLAGS "-fvisibility=hidden -Werror")
   361   check_c_source_compiles("
   362       #if !defined(__GNUC__) || __GNUC__ < 4
   363       #error SDL only uses visibility attributes in GCC 4 or newer
   364       #endif
   365       int main(int argc, char **argv) {}" HAVE_GCC_FVISIBILITY)
   366   if(HAVE_GCC_FVISIBILITY)
   367     list(APPEND EXTRA_CFLAGS "-fvisibility=hidden")
   368   endif()
   369   set(CMAKE_REQUIRED_FLAGS ${ORIG_CMAKE_REQUIRED_FLAGS})
   370 
   371   check_c_compiler_flag(-Wall HAVE_GCC_WALL)
   372   if(HAVE_GCC_WALL)
   373     list(APPEND EXTRA_CFLAGS "-Wall")
   374     if(HAIKU)
   375       set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-multichar")
   376     endif()
   377   endif()
   378   check_c_compiler_flag(-Wshadow HAVE_GCC_WSHADOW)
   379   if(HAVE_GCC_WSHADOW)
   380     list(APPEND EXTRA_CFLAGS "-Wshadow")
   381   endif()
   382 
   383   set(CMAKE_REQUIRED_FLAGS "-Wl,--no-undefined")
   384   check_c_compiler_flag("" HAVE_NO_UNDEFINED)
   385   set(CMAKE_REQUIRED_FLAGS)
   386   if(HAVE_NO_UNDEFINED)
   387     list(APPEND EXTRA_LDFLAGS "-Wl,--no-undefined")
   388   endif()
   389 endif()
   390 
   391 if(ASSEMBLY)
   392   if(USE_GCC OR USE_CLANG)
   393     set(SDL_ASSEMBLY_ROUTINES 1)
   394     # TODO: Those all seem to be quite GCC specific - needs to be
   395     # reworked for better compiler support
   396     set(HAVE_ASSEMBLY TRUE)
   397     if(MMX)
   398       set(CMAKE_REQUIRED_FLAGS "-mmmx")
   399       check_c_source_compiles("
   400           #ifdef __MINGW32__
   401           #include <_mingw.h>
   402           #ifdef __MINGW64_VERSION_MAJOR
   403           #include <intrin.h>
   404           #else
   405           #include <mmintrin.h>
   406           #endif
   407           #else
   408           #include <mmintrin.h>
   409           #endif
   410           #ifndef __MMX__
   411           #error Assembler CPP flag not enabled
   412           #endif
   413           int main(int argc, char **argv) { }" HAVE_MMX)
   414       if(HAVE_MMX)
   415         list(APPEND EXTRA_CFLAGS "-mmmx")
   416       endif()
   417       set(CMAKE_REQUIRED_FLAGS ${ORIG_CMAKE_REQUIRED_FLAGS})
   418     endif()
   419 
   420     if(3DNOW)
   421       set(CMAKE_REQUIRED_FLAGS "-m3dnow")
   422       check_c_source_compiles("
   423           #include <mm3dnow.h>
   424           #ifndef __3dNOW__
   425           #error Assembler CPP flag not enabled
   426           #endif
   427           int main(int argc, char **argv) {
   428             void *p = 0;
   429             _m_prefetch(p);
   430           }" HAVE_3DNOW)
   431       if(HAVE_3DNOW)
   432         list(APPEND EXTRA_CFLAGS "-m3dnow")
   433       endif()
   434       set(CMAKE_REQUIRED_FLAGS ${ORIG_CMAKE_REQUIRED_FLAGS})
   435     endif()
   436 
   437     if(SSE)
   438       set(CMAKE_REQUIRED_FLAGS "-msse")
   439       check_c_source_compiles("
   440           #ifdef __MINGW32__
   441           #include <_mingw.h>
   442           #ifdef __MINGW64_VERSION_MAJOR
   443           #include <intrin.h>
   444           #else
   445           #include <xmmintrin.h>
   446           #endif
   447           #else
   448           #include <xmmintrin.h>
   449           #endif
   450           #ifndef __SSE__
   451           #error Assembler CPP flag not enabled
   452           #endif
   453           int main(int argc, char **argv) { }" HAVE_SSE)
   454       if(HAVE_SSE)
   455         list(APPEND EXTRA_CFLAGS "-msse")
   456       endif()
   457       set(CMAKE_REQUIRED_FLAGS ${ORIG_CMAKE_REQUIRED_FLAGS})
   458     endif()
   459 
   460     if(SSE2)
   461       set(CMAKE_REQUIRED_FLAGS "-msse2")
   462       check_c_source_compiles("
   463           #ifdef __MINGW32__
   464           #include <_mingw.h>
   465           #ifdef __MINGW64_VERSION_MAJOR
   466           #include <intrin.h>
   467           #else
   468           #include <emmintrin.h>
   469           #endif
   470           #else
   471           #include <emmintrin.h>
   472           #endif
   473           #ifndef __SSE2__
   474           #error Assembler CPP flag not enabled
   475           #endif
   476           int main(int argc, char **argv) { }" HAVE_SSE2)
   477       if(HAVE_SSE2)
   478         list(APPEND EXTRA_CFLAGS "-msse2")
   479       endif()
   480       set(CMAKE_REQUIRED_FLAGS ${ORIG_CMAKE_REQUIRED_FLAGS})
   481     endif()
   482 
   483     if(SSEMATH)
   484       if(SSE OR SSE2)
   485         if(USE_GCC)
   486           list(APPEND EXTRA_CFLAGS "-mfpmath=387")
   487         endif()
   488         set(HAVE_SSEMATH TRUE)
   489       endif()
   490     endif()
   491 
   492     if(ALTIVEC)
   493       set(CMAKE_REQUIRED_FLAGS "-maltivec")
   494       check_c_source_compiles("
   495           #include <altivec.h>
   496           vector unsigned int vzero() {
   497               return vec_splat_u32(0);
   498           }
   499           int main(int argc, char **argv) { }" HAVE_ALTIVEC_H_HDR)
   500       check_c_source_compiles("
   501           vector unsigned int vzero() {
   502               return vec_splat_u32(0);
   503           }
   504           int main(int argc, char **argv) { }" HAVE_ALTIVEC)
   505       set(CMAKE_REQUIRED_FLAGS ${ORIG_CMAKE_REQUIRED_FLAGS})
   506       if(HAVE_ALTIVEC OR HAVE_ALTIVEC_H_HDR)
   507         set(HAVE_ALTIVEC TRUE) # if only HAVE_ALTIVEC_H_HDR is set
   508         list(APPEND EXTRA_CFLAGS "-maltivec")
   509         set(SDL_ALTIVEC_BLITTERS 1)
   510         if(HAVE_ALTIVEC_H_HDR)
   511           set(HAVE_ALTIVEC_H 1)
   512         endif()
   513       endif()
   514     endif()
   515   elseif(MSVC_VERSION GREATER 1500)
   516     # TODO: SDL_cpuinfo.h needs to support the user's configuration wish
   517     # for MSVC - right now it is always activated
   518     if(NOT ARCH_64)
   519       set(HAVE_MMX TRUE)
   520       set(HAVE_3DNOW TRUE)
   521     endif()
   522     set(HAVE_SSE TRUE)
   523     set(HAVE_SSE2 TRUE)
   524     set(SDL_ASSEMBLY_ROUTINES 1)
   525   endif()
   526 # TODO:
   527 #else()
   528 #  if(USE_GCC OR USE_CLANG)
   529 #    list(APPEND EXTRA_CFLAGS "-mno-sse" "-mno-sse2" "-mno-mmx")
   530 #  endif()
   531 endif()
   532 
   533 # TODO: Can't deactivate on FreeBSD? w/o LIBC, SDL_stdinc.h can't define
   534 # anything.
   535 if(LIBC)
   536   if(WINDOWS AND NOT MINGW)
   537     set(HAVE_LIBC TRUE)
   538     foreach(_HEADER stdio.h string.h ctype.h math.h)
   539       string(TOUPPER "HAVE_${_HEADER}" _UPPER)
   540       string(REPLACE "." "_" _HAVE_H ${_UPPER})
   541       set(${_HAVE_H} 1)
   542     endforeach()
   543     set(HAVE_SIGNAL_H 1)
   544     foreach(_FN
   545             malloc calloc realloc free qsort abs memset memcpy memmove memcmp
   546             strlen _strrev _strupr _strlwr strchr strrchr strstr itoa _ltoa
   547             _ultoa strtol strtoul strtoll strtod atoi atof strcmp strncmp
   548             _stricmp _strnicmp sscanf atan atan2 acos asin ceil copysign cos
   549             cosf fabs floor log pow scalbn sin sinf sqrt sqrtf tan tanf)
   550       string(TOUPPER ${_FN} _UPPER)
   551       set(HAVE_${_UPPER} 1)
   552     endforeach()
   553     if(NOT CYGWIN AND NOT MINGW)
   554       set(HAVE_ALLOCA 1)
   555     endif()
   556     set(HAVE_M_PI 1)
   557     add_definitions(-D_USE_MATH_DEFINES) # needed for M_PI
   558     set(STDC_HEADERS 1)
   559   else()
   560     set(HAVE_LIBC TRUE)
   561     check_include_file(sys/types.h HAVE_SYS_TYPES_H)
   562     foreach(_HEADER
   563             stdio.h stdlib.h stddef.h stdarg.h malloc.h memory.h string.h
   564             strings.h inttypes.h stdint.h ctype.h math.h iconv.h signal.h)
   565       string(TOUPPER "HAVE_${_HEADER}" _UPPER)
   566       string(REPLACE "." "_" _HAVE_H ${_UPPER})
   567       check_include_file("${_HEADER}" ${_HAVE_H})
   568     endforeach()
   569 
   570     check_include_files("dlfcn.h;stdint.h;stddef.h;inttypes.h;stdlib.h;strings.h;string.h;float.h" STDC_HEADERS)
   571     check_type_size("size_t" SIZEOF_SIZE_T)
   572     check_symbol_exists(M_PI math.h HAVE_M_PI)
   573     # TODO: refine the mprotect check
   574     check_c_source_compiles("#include <sys/types.h>
   575                              #include <sys/mman.h>
   576                              int main() { }" HAVE_MPROTECT)
   577     foreach(_FN
   578             strtod malloc calloc realloc free getenv setenv putenv unsetenv
   579             qsort abs bcopy memset memcpy memmove memcmp strlen strlcpy strlcat
   580             strdup _strrev _strupr _strlwr strchr strrchr strstr itoa _ltoa
   581             _uitoa _ultoa strtol strtoul _i64toa _ui64toa strtoll strtoull
   582             atoi atof strcmp strncmp _stricmp strcasecmp _strnicmp strncasecmp
   583             vsscanf vsnprintf fseeko fseeko64 sigaction setjmp
   584             nanosleep sysconf sysctlbyname
   585             )
   586       string(TOUPPER ${_FN} _UPPER)
   587       set(_HAVEVAR "HAVE_${_UPPER}")
   588       check_function_exists("${_FN}" ${_HAVEVAR})
   589     endforeach()
   590 
   591     check_library_exists(m pow "" HAVE_LIBM)
   592     if(HAVE_LIBM)
   593       set(CMAKE_REQUIRED_LIBRARIES m)
   594       foreach(_FN
   595               atan atan2 ceil copysign cos cosf fabs floor log pow scalbn sin
   596               sinf sqrt sqrtf tan tanf acos asin)
   597         string(TOUPPER ${_FN} _UPPER)
   598         set(_HAVEVAR "HAVE_${_UPPER}")
   599         check_function_exists("${_FN}" ${_HAVEVAR})
   600       endforeach()
   601       set(CMAKE_REQUIRED_LIBRARIES)
   602       list(APPEND EXTRA_LIBS m)
   603     endif()
   604 
   605     check_library_exists(iconv iconv_open "" HAVE_LIBICONV)
   606     if(HAVE_LIBICONV)
   607       list(APPEND EXTRA_LIBS iconv)
   608       set(HAVE_ICONV 1)
   609     endif()
   610 
   611     if(NOT APPLE)
   612       check_include_file(alloca.h HAVE_ALLOCA_H)
   613       check_function_exists(alloca HAVE_ALLOCA)
   614     else()
   615       set(HAVE_ALLOCA_H 1)
   616       set(HAVE_ALLOCA 1)
   617     endif()
   618 
   619     check_struct_has_member("struct sigaction" "sa_sigaction" "signal.h" HAVE_SA_SIGACTION)
   620   endif()
   621 else()
   622   if(WINDOWS)
   623     set(HAVE_STDARG_H 1)
   624     set(HAVE_STDDEF_H 1)
   625   endif()
   626 endif()
   627 
   628 
   629 # Enable/disable various subsystems of the SDL library
   630 foreach(_SUB ${SDL_SUBSYSTEMS})
   631   string(TOUPPER ${_SUB} _OPT)
   632   if(NOT SDL_${_OPT})
   633     set(SDL_${_OPT}_DISABLED 1)
   634   endif()
   635 endforeach()
   636 if(SDL_JOYSTICK)
   637   file(GLOB JOYSTICK_SOURCES ${SDL2_SOURCE_DIR}/src/joystick/*.c)
   638   set(SOURCE_FILES ${SOURCE_FILES} ${JOYSTICK_SOURCES})
   639 endif()
   640 if(SDL_HAPTIC)
   641   if(NOT SDL_JOYSTICK)
   642     # Haptic requires some private functions from the joystick subsystem.
   643     message_error("SDL_HAPTIC requires SDL_JOYSTICK, which is not enabled")
   644   endif()
   645   file(GLOB HAPTIC_SOURCES ${SDL2_SOURCE_DIR}/src/haptic/*.c)
   646   set(SOURCE_FILES ${SOURCE_FILES} ${HAPTIC_SOURCES})
   647 endif()
   648 if(SDL_POWER)
   649   file(GLOB POWER_SOURCES ${SDL2_SOURCE_DIR}/src/power/*.c)
   650   set(SOURCE_FILES ${SOURCE_FILES} ${POWER_SOURCES})
   651 endif()
   652 # TODO: in configure.in, the test for LOADSO and SDL_DLOPEN is a bit weird:
   653 # if LOADSO is not wanted, SDL_LOADSO_DISABLED is set
   654 # If however on Unix or APPLE dlopen() is detected via CheckDLOPEN(),
   655 # SDL_LOADSO_DISABLED will not be set, regardless of the LOADSO settings
   656 
   657 # General SDL subsystem options, valid for all platforms
   658 if(SDL_AUDIO)
   659   # CheckDummyAudio/CheckDiskAudio - valid for all platforms
   660   if(DUMMYAUDIO)
   661     set(SDL_AUDIO_DRIVER_DUMMY 1)
   662     file(GLOB DUMMYAUDIO_SOURCES ${SDL2_SOURCE_DIR}/src/audio/dummy/*.c)
   663     set(SOURCE_FILES ${SOURCE_FILES} ${DUMMYAUDIO_SOURCES})
   664     set(HAVE_DUMMYAUDIO TRUE)
   665   endif()
   666   if(DISKAUDIO)
   667     set(SDL_AUDIO_DRIVER_DISK 1)
   668     file(GLOB DISKAUDIO_SOURCES ${SDL2_SOURCE_DIR}/src/audio/disk/*.c)
   669     set(SOURCE_FILES ${SOURCE_FILES} ${DISKAUDIO_SOURCES})
   670     set(HAVE_DISKAUDIO TRUE)
   671   endif()
   672 endif()
   673 
   674 if(SDL_DLOPEN)
   675   # Relevant for Unix/Darwin only
   676   if(UNIX OR APPLE)
   677     CheckDLOPEN()
   678   endif()
   679 endif()
   680 
   681 if(SDL_VIDEO)
   682   if(VIDEO_DUMMY)
   683     set(SDL_VIDEO_DRIVER_DUMMY 1)
   684     file(GLOB VIDEO_DUMMY_SOURCES ${SDL2_SOURCE_DIR}/src/video/dummy/*.c)
   685     set(SOURCE_FILES ${SOURCE_FILES} ${VIDEO_DUMMY_SOURCES})
   686     set(HAVE_VIDEO_DUMMY TRUE)
   687     set(HAVE_SDL_VIDEO TRUE)
   688   endif()
   689 endif()
   690 
   691 # Platform-specific options and settings
   692 if(EMSCRIPTEN)
   693   # Hide noisy warnings that intend to aid mostly during initial stages of porting a new
   694   # project. Uncomment at will for verbose cross-compiling -I/../ path info.
   695   add_definitions(-Wno-warn-absolute-paths)
   696   if(SDL_AUDIO)
   697     set(SDL_AUDIO_DRIVER_EMSCRIPTEN 1)
   698     file(GLOB EM_AUDIO_SOURCES ${SDL2_SOURCE_DIR}/src/audio/emscripten/*.c)
   699     set(SOURCE_FILES ${SOURCE_FILES} ${EM_AUDIO_SOURCES})
   700     set(HAVE_SDL_AUDIO TRUE)
   701   endif()
   702   if(SDL_FILESYSTEM)
   703     set(SDL_FILESYSTEM_EMSCRIPTEN 1)
   704     file(GLOB EM_FILESYSTEM_SOURCES ${SDL2_SOURCE_DIR}/src/filesystem/emscripten/*.c)
   705     set(SOURCE_FILES ${SOURCE_FILES} ${EM_FILESYSTEM_SOURCES})
   706     set(HAVE_SDL_FILESYSTEM TRUE)
   707   endif()
   708   if(SDL_JOYSTICK)
   709     set(SDL_JOYSTICK_EMSCRIPTEN 1)
   710     file(GLOB EM_JOYSTICK_SOURCES ${SDL2_SOURCE_DIR}/src/joystick/emscripten/*.c)
   711     set(SOURCE_FILES ${SOURCE_FILES} ${EM_JOYSTICK_SOURCES})
   712     set(HAVE_SDL_JOYSTICK TRUE)
   713   endif()
   714   if(SDL_POWER)
   715     set(SDL_POWER_EMSCRIPTEN 1)
   716     file(GLOB EM_POWER_SOURCES ${SDL2_SOURCE_DIR}/src/power/emscripten/*.c)
   717     set(SOURCE_FILES ${SOURCE_FILES} ${EM_POWER_SOURCES})
   718     set(HAVE_SDL_POWER TRUE)
   719   endif()
   720   if(SDL_VIDEO)
   721     set(SDL_VIDEO_DRIVER_EMSCRIPTEN 1)
   722     file(GLOB EM_VIDEO_SOURCES ${SDL2_SOURCE_DIR}/src/video/emscripten/*.c)
   723     set(SOURCE_FILES ${SOURCE_FILES} ${EM_VIDEO_SOURCES})
   724     set(HAVE_SDL_VIDEO TRUE)
   725 
   726     #enable gles
   727     if(VIDEO_OPENGLES)
   728       set(SDL_VIDEO_OPENGL_EGL 1)
   729       set(HAVE_VIDEO_OPENGLES TRUE)
   730       set(SDL_VIDEO_OPENGL_ES2 1)
   731       set(SDL_VIDEO_RENDER_OGL_ES2 1)
   732     endif()
   733   endif()
   734 elseif(UNIX AND NOT APPLE)
   735   if(SDL_AUDIO)
   736     if(SYSV5 OR SOLARIS OR HPUX)
   737         set(SDL_AUDIO_DRIVER_SUNAUDIO 1)
   738         file(GLOB SUN_AUDIO_SOURCES ${SDL2_SOURCE_DIR}/src/audio/sun/*.c)
   739         set(SOURCE_FILES ${SOURCE_FILES} ${SUN_AUDIO_SOURCES})
   740         set(HAVE_SDL_AUDIO TRUE)
   741     elseif(NETBSD OR OPENBSD)
   742         set(SDL_AUDIO_DRIVER_BSD 1)
   743         file(GLOB BSD_AUDIO_SOURCES ${SDL2_SOURCE_DIR}/src/audio/bsd/*.c)
   744         set(SOURCE_FILES ${SOURCE_FILES} ${BSD_AUDIO_SOURCES})
   745         set(HAVE_SDL_AUDIO TRUE)
   746     elseif(AIX)
   747         set(SDL_AUDIO_DRIVER_PAUDIO 1)
   748         file(GLOB AIX_AUDIO_SOURCES ${SDL2_SOURCE_DIR}/src/audio/paudio/*.c)
   749         set(SOURCE_FILES ${SOURCE_FILES} ${AIX_AUDIO_SOURCES})
   750         set(HAVE_SDL_AUDIO TRUE)
   751     endif()
   752     CheckOSS()
   753     CheckALSA()
   754     CheckPulseAudio()
   755     CheckESD()
   756     CheckARTS()
   757     CheckNAS()
   758     CheckSNDIO()
   759     CheckFusionSound()
   760   endif()
   761 
   762   if(SDL_VIDEO)
   763     # Need to check for Raspberry PI first and add platform specific compiler flags, otherwise the test for GLES fails!
   764     CheckRPI()
   765     CheckX11()
   766     CheckMir()
   767     CheckDirectFB()
   768     CheckOpenGLX11()
   769     CheckOpenGLESX11()
   770     CheckWayland()
   771     CheckVivante()
   772   endif()
   773 
   774   if(LINUX)
   775     check_c_source_compiles("
   776         #include <linux/input.h>
   777         #ifndef EVIOCGNAME
   778         #error EVIOCGNAME() ioctl not available
   779         #endif
   780         int main(int argc, char** argv) {}" HAVE_INPUT_EVENTS)
   781 
   782     check_c_source_compiles("
   783         #include <linux/kd.h>
   784         #include <linux/keyboard.h>
   785 
   786         int main(int argc, char **argv) 
   787         {
   788             struct kbentry kbe;
   789             kbe.kb_table = KG_CTRL;
   790             ioctl(0, KDGKBENT, &kbe);
   791         }" HAVE_INPUT_KD)
   792 
   793     file(GLOB CORE_SOURCES ${SDL2_SOURCE_DIR}/src/core/linux/*.c)
   794     set(SOURCE_FILES ${SOURCE_FILES} ${CORE_SOURCES})
   795 
   796     if(HAVE_INPUT_EVENTS)
   797       set(SDL_INPUT_LINUXEV 1)
   798     endif()
   799 
   800     if(SDL_HAPTIC AND HAVE_INPUT_EVENTS)
   801       set(SDL_HAPTIC_LINUX 1)
   802       file(GLOB HAPTIC_SOURCES ${SDL2_SOURCE_DIR}/src/haptic/linux/*.c)
   803       set(SOURCE_FILES ${SOURCE_FILES} ${HAPTIC_SOURCES})
   804       set(HAVE_SDL_HAPTIC TRUE)
   805     endif()
   806 
   807     if(HAVE_INPUT_KD)
   808       set(SDL_INPUT_LINUXKD 1)
   809     endif()
   810 
   811     check_include_file("libudev.h" HAVE_LIBUDEV_H)
   812 
   813     # !!! FIXME: this needs pkg-config to find the include path, I think.
   814     check_include_file("dbus/dbus.h" HAVE_DBUS_DBUS_H)
   815   endif()
   816 
   817   if(INPUT_TSLIB)
   818     check_c_source_compiles("
   819         #include \"tslib.h\"
   820         int main(int argc, char** argv) { }" HAVE_INPUT_TSLIB)
   821     if(HAVE_INPUT_TSLIB)
   822       set(SDL_INPUT_TSLIB 1)
   823       list(APPEND EXTRA_LIBS ts)
   824     endif()
   825   endif()
   826 
   827   if(SDL_JOYSTICK)
   828     CheckUSBHID()   # seems to be BSD specific - limit the test to BSD only?
   829     if(LINUX)
   830       set(SDL_JOYSTICK_LINUX 1)
   831       file(GLOB JOYSTICK_SOURCES ${SDL2_SOURCE_DIR}/src/joystick/linux/*.c)
   832       set(SOURCE_FILES ${SOURCE_FILES} ${JOYSTICK_SOURCES})
   833       set(HAVE_SDL_JOYSTICK TRUE)
   834     endif()
   835   endif()
   836 
   837   CheckPTHREAD()
   838 
   839   if(CLOCK_GETTIME)
   840     check_library_exists(rt clock_gettime "" FOUND_CLOCK_GETTIME)
   841     if(FOUND_CLOCK_GETTIME)
   842       list(APPEND EXTRA_LIBS rt)
   843       set(HAVE_CLOCK_GETTIME 1)
   844     else()
   845       check_library_exists(c clock_gettime "" FOUND_CLOCK_GETTIME)
   846       if(FOUND_CLOCK_GETTIME)
   847         set(HAVE_CLOCK_GETTIME 1)
   848       endif()
   849     endif()
   850   endif()
   851 
   852   check_include_file(linux/version.h HAVE_LINUX_VERSION_H)
   853   if(HAVE_LINUX_VERSION_H)
   854     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -DHAVE_LINUX_VERSION_H")
   855   endif()
   856 
   857   if(SDL_POWER)
   858     if(LINUX)
   859       set(SDL_POWER_LINUX 1)
   860       file(GLOB POWER_SOURCES ${SDL2_SOURCE_DIR}/src/power/linux/*.c)
   861       set(SOURCE_FILES ${SOURCE_FILES} ${POWER_SOURCES})
   862       set(HAVE_SDL_POWER TRUE)
   863     endif()
   864   endif()
   865 
   866   if(SDL_FILESYSTEM)
   867     set(SDL_FILESYSTEM_UNIX 1)
   868     file(GLOB FILESYSTEM_SOURCES ${SDL2_SOURCE_DIR}/src/filesystem/unix/*.c)
   869     set(SOURCE_FILES ${SOURCE_FILES} ${FILESYSTEM_SOURCES})
   870     set(HAVE_SDL_FILESYSTEM TRUE)
   871   endif()
   872 
   873   if(SDL_TIMERS)
   874     set(SDL_TIMER_UNIX 1)
   875     file(GLOB TIMER_SOURCES ${SDL2_SOURCE_DIR}/src/timer/unix/*.c)
   876     set(SOURCE_FILES ${SOURCE_FILES} ${TIMER_SOURCES})
   877     set(HAVE_SDL_TIMERS TRUE)
   878   endif()
   879 
   880   if(RPATH)
   881     set(SDL_RLD_FLAGS "")
   882     if(BSDI OR FREEBSD OR LINUX OR NETBSD)
   883       set(SDL_RLD_FLAGS "-Wl,-rpath,\${libdir}")
   884     elseif(SOLARIS)
   885       set(SDL_RLD_FLAGS "-R\${libdir}")
   886     endif()
   887     set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
   888     set(HAVE_RPATH TRUE)
   889   endif()
   890 
   891 elseif(WINDOWS)
   892   find_program(WINDRES windres)
   893 
   894   check_c_source_compiles("
   895     #include <windows.h>
   896     int main(int argc, char **argv) { }" HAVE_WIN32_CC)
   897 
   898   file(GLOB CORE_SOURCES ${SDL2_SOURCE_DIR}/src/core/windows/*.c)
   899   set(SOURCE_FILES ${SOURCE_FILES} ${CORE_SOURCES})
   900 
   901   # Check for DirectX
   902   if(DIRECTX)
   903     if(NOT CMAKE_COMPILER_IS_MINGW)
   904       if("$ENV{DXSDK_DIR}" STREQUAL "")
   905         message_error("DIRECTX requires the \$DXSDK_DIR environment variable to be set")
   906       endif()
   907       set(CMAKE_REQUIRED_FLAGS "/I\"$ENV{DXSDK_DIR}\\Include\"")
   908     endif()
   909     check_include_file(d3d9.h HAVE_D3D_H)
   910     check_include_file(d3d11_1.h HAVE_D3D11_H)
   911     check_include_file(ddraw.h HAVE_DDRAW_H)
   912     check_include_file(dsound.h HAVE_DSOUND_H)
   913     check_include_file(dinput.h HAVE_DINPUT_H)
   914     check_include_file(xaudio2.h HAVE_XAUDIO2_H)
   915     check_include_file(xinput.h HAVE_XINPUT_H)
   916     check_include_file(dxgi.h HAVE_DXGI_H)
   917     if(HAVE_D3D_H OR HAVE_D3D11_H OR HAVE_DDRAW_H OR HAVE_DSOUND_H OR HAVE_DINPUT_H OR HAVE_XAUDIO2_H)
   918       set(HAVE_DIRECTX TRUE)
   919       if(NOT CMAKE_COMPILER_IS_MINGW)
   920       # TODO: change $ENV{DXSDL_DIR} to get the path from the include checks
   921         link_directories($ENV{DXSDK_DIR}\\lib\\${PROCESSOR_ARCH})
   922         include_directories($ENV{DXSDK_DIR}\\Include)
   923       endif()
   924     endif()
   925     set(CMAKE_REQUIRED_FLAGS ${ORIG_CMAKE_REQUIRED_FLAGS})
   926   endif()
   927 
   928   if(SDL_AUDIO)
   929     set(SDL_AUDIO_DRIVER_WINMM 1)
   930     file(GLOB WINMM_AUDIO_SOURCES ${SDL2_SOURCE_DIR}/src/audio/winmm/*.c)
   931     set(SOURCE_FILES ${SOURCE_FILES} ${WINMM_AUDIO_SOURCES})
   932     set(HAVE_SDL_AUDIO TRUE)
   933 
   934     if(HAVE_DSOUND_H)
   935       set(SDL_AUDIO_DRIVER_DSOUND 1)
   936       file(GLOB DSOUND_AUDIO_SOURCES ${SDL2_SOURCE_DIR}/src/audio/directsound/*.c)
   937       set(SOURCE_FILES ${SOURCE_FILES} ${DSOUND_AUDIO_SOURCES})
   938     endif()
   939 
   940     if(HAVE_XAUDIO2_H)
   941       set(SDL_AUDIO_DRIVER_XAUDIO2 1)
   942       file(GLOB XAUDIO2_AUDIO_SOURCES ${SDL2_SOURCE_DIR}/src/audio/xaudio2/*.c)
   943       set(SOURCE_FILES ${SOURCE_FILES} ${XAUDIO2_AUDIO_SOURCES})
   944     endif()
   945   endif()
   946 
   947   if(SDL_VIDEO)
   948     # requires SDL_LOADSO on Windows (IME, DX, etc.)
   949     if(NOT SDL_LOADSO)
   950       message_error("SDL_VIDEO requires SDL_LOADSO, which is not enabled")
   951     endif()
   952     set(SDL_VIDEO_DRIVER_WINDOWS 1)
   953     file(GLOB WIN_VIDEO_SOURCES ${SDL2_SOURCE_DIR}/src/video/windows/*.c)
   954     set(SOURCE_FILES ${SOURCE_FILES} ${WIN_VIDEO_SOURCES})
   955 
   956     if(RENDER_D3D AND HAVE_D3D_H)
   957       set(SDL_VIDEO_RENDER_D3D 1)
   958       set(HAVE_RENDER_D3D TRUE)
   959     endif()
   960     if(RENDER_D3D AND HAVE_D3D11_H)
   961       set(SDL_VIDEO_RENDER_D3D11 1)
   962       set(HAVE_RENDER_D3D TRUE)
   963     endif()
   964     set(HAVE_SDL_VIDEO TRUE)
   965   endif()
   966 
   967   if(SDL_THREADS)
   968     set(SDL_THREAD_WINDOWS 1)
   969     set(SOURCE_FILES ${SOURCE_FILES}
   970       ${SDL2_SOURCE_DIR}/src/thread/windows/SDL_sysmutex.c
   971       ${SDL2_SOURCE_DIR}/src/thread/windows/SDL_syssem.c
   972       ${SDL2_SOURCE_DIR}/src/thread/windows/SDL_systhread.c
   973       ${SDL2_SOURCE_DIR}/src/thread/windows/SDL_systls.c
   974       ${SDL2_SOURCE_DIR}/src/thread/generic/SDL_syscond.c)
   975     set(HAVE_SDL_THREADS TRUE)
   976   endif()
   977 
   978   if(SDL_POWER)
   979     set(SDL_POWER_WINDOWS 1)
   980     set(SOURCE_FILES ${SOURCE_FILES} ${SDL2_SOURCE_DIR}/src/power/windows/SDL_syspower.c)
   981     set(HAVE_SDL_POWER TRUE)
   982   endif()
   983 
   984   if(SDL_FILESYSTEM)
   985     set(SDL_FILESYSTEM_WINDOWS 1)
   986     file(GLOB FILESYSTEM_SOURCES ${SDL2_SOURCE_DIR}/src/filesystem/windows/*.c)
   987     set(SOURCE_FILES ${SOURCE_FILES} ${FILESYSTEM_SOURCES})
   988     set(HAVE_SDL_FILESYSTEM TRUE)
   989   endif()
   990 
   991   # Libraries for Win32 native and MinGW
   992   list(APPEND EXTRA_LIBS user32 gdi32 winmm imm32 ole32 oleaut32 version uuid)
   993 
   994   # TODO: in configure.in the check for timers is set on
   995   # cygwin | mingw32* - does this include mingw32CE?
   996   if(SDL_TIMERS)
   997     set(SDL_TIMER_WINDOWS 1)
   998     file(GLOB TIMER_SOURCES ${SDL2_SOURCE_DIR}/src/timer/windows/*.c)
   999     set(SOURCE_FILES ${SOURCE_FILES} ${TIMER_SOURCES})
  1000     set(HAVE_SDL_TIMERS TRUE)
  1001   endif()
  1002 
  1003   if(SDL_LOADSO)
  1004     set(SDL_LOADSO_WINDOWS 1)
  1005     file(GLOB LOADSO_SOURCES ${SDL2_SOURCE_DIR}/src/loadso/windows/*.c)
  1006     set(SOURCE_FILES ${SOURCE_FILES} ${LOADSO_SOURCES})
  1007     set(HAVE_SDL_LOADSO TRUE)
  1008   endif()
  1009 
  1010   file(GLOB CORE_SOURCES ${SDL2_SOURCE_DIR}/src/core/windows/*.c)
  1011   set(SOURCE_FILES ${SOURCE_FILES} ${CORE_SOURCES})
  1012 
  1013   if(SDL_VIDEO)
  1014     if(VIDEO_OPENGL)
  1015       set(SDL_VIDEO_OPENGL 1)
  1016       set(SDL_VIDEO_OPENGL_WGL 1)
  1017       set(SDL_VIDEO_RENDER_OGL 1)
  1018       set(HAVE_VIDEO_OPENGL TRUE)
  1019     endif()
  1020   endif()
  1021 
  1022   if(SDL_JOYSTICK)
  1023     file(GLOB JOYSTICK_SOURCES ${SDL2_SOURCE_DIR}/src/joystick/windows/*.c)
  1024     set(SOURCE_FILES ${SOURCE_FILES} ${JOYSTICK_SOURCES})
  1025     if(HAVE_DINPUT_H)
  1026       set(SDL_JOYSTICK_DINPUT 1)
  1027       list(APPEND EXTRA_LIBS dinput8 dxguid)
  1028       if(CMAKE_COMPILER_IS_MINGW)
  1029         list(APPEND EXTRA_LIBS dxerr8)
  1030       else()
  1031         list(APPEND EXTRA_LIBS dxerr)
  1032       endif()
  1033     endif()
  1034     if(HAVE_XINPUT_H)
  1035       set(SDL_JOYSTICK_XINPUT 1)
  1036     endif()
  1037     if(NOT HAVE_DINPUT_H AND NOT HAVE_XINPUT_H)
  1038       set(SDL_JOYSTICK_WINMM 1)
  1039     endif()
  1040     set(HAVE_SDL_JOYSTICK TRUE)
  1041 
  1042     if(SDL_HAPTIC)
  1043       if(HAVE_DINPUT_H OR HAVE_XINPUT_H)
  1044         file(GLOB HAPTIC_SOURCES ${SDL2_SOURCE_DIR}/src/haptic/windows/*.c)
  1045         if(HAVE_DINPUT_H)
  1046           set(SDL_HAPTIC_DINPUT 1)
  1047         endif()
  1048         if(HAVE_XINPUT_H)
  1049           set(SDL_HAPTIC_XINPUT 1)
  1050         endif()
  1051       else()
  1052         file(GLOB HAPTIC_SOURCES ${SDL2_SOURCE_DIR}/src/haptic/dummy/*.c)
  1053         set(SDL_HAPTIC_DUMMY 1)
  1054       endif()
  1055       set(SOURCE_FILES ${SOURCE_FILES} ${HAPTIC_SOURCES})
  1056       set(HAVE_SDL_HAPTIC TRUE)
  1057     endif()
  1058   endif()
  1059 
  1060   file(GLOB VERSION_SOURCES ${SDL2_SOURCE_DIR}/src/main/windows/*.rc)
  1061   file(GLOB SDLMAIN_SOURCES ${SDL2_SOURCE_DIR}/src/main/windows/*.c)
  1062   if(MINGW OR CYGWIN)
  1063     list(APPEND EXTRA_LIBS mingw32)
  1064     list(APPEND EXTRA_LDFLAGS "-mwindows")
  1065     set(SDL_CFLAGS "${SDL_CFLAGS} -Dmain=SDL_main")
  1066     list(APPEND SDL_LIBS "-lmingw32" "-lSDL2main" "-mwindows")
  1067   endif()
  1068 elseif(APPLE)
  1069   # TODO: rework this for proper MacOS X, iOS and Darwin support
  1070 
  1071   # Requires the darwin file implementation
  1072   if(SDL_FILE)
  1073     file(GLOB EXTRA_SOURCES ${PROJECT_SOURCE_DIR}/src/file/cocoa/*.m)
  1074     set(SOURCE_FILES ${EXTRA_SOURCES} ${SOURCE_FILES})
  1075     set_source_files_properties(${EXTRA_SOURCES} PROPERTIES LANGUAGE C)
  1076     set(HAVE_SDL_FILE TRUE)
  1077     set(SDL_FRAMEWORK_COCOA 1)
  1078     set(SDL_FRAMEWORK_COREVIDEO 1)
  1079   else()
  1080     message_error("SDL_FILE must be enabled to build on MacOS X")
  1081   endif()
  1082 
  1083   if(SDL_AUDIO)
  1084     set(SDL_AUDIO_DRIVER_COREAUDIO 1)
  1085     file(GLOB AUDIO_SOURCES ${SDL2_SOURCE_DIR}/src/audio/coreaudio/*.c)
  1086     set(SOURCE_FILES ${SOURCE_FILES} ${AUDIO_SOURCES})
  1087     set(HAVE_SDL_AUDIO TRUE)
  1088     set(SDL_FRAMEWORK_COREAUDIO 1)
  1089     set(SDL_FRAMEWORK_AUDIOUNIT 1)
  1090   endif()
  1091 
  1092   if(SDL_JOYSTICK)
  1093     set(SDL_JOYSTICK_IOKIT 1)
  1094     file(GLOB JOYSTICK_SOURCES ${SDL2_SOURCE_DIR}/src/joystick/darwin/*.c)
  1095     set(SOURCE_FILES ${SOURCE_FILES} ${JOYSTICK_SOURCES})
  1096     set(HAVE_SDL_JOYSTICK TRUE)
  1097     set(SDL_FRAMEWORK_IOKIT 1)
  1098     set(SDL_FRAMEWORK_FF 1)
  1099   endif()
  1100 
  1101   if(SDL_HAPTIC)
  1102     set(SDL_HAPTIC_IOKIT 1)
  1103     file(GLOB HAPTIC_SOURCES ${SDL2_SOURCE_DIR}/src/haptic/darwin/*.c)
  1104     set(SOURCE_FILES ${SOURCE_FILES} ${HAPTIC_SOURCES})
  1105     set(HAVE_SDL_HAPTIC TRUE)
  1106     set(SDL_FRAMEWORK_IOKIT 1)
  1107     set(SDL_FRAMEWORK_FF 1)
  1108     if(NOT SDL_JOYSTICK)
  1109       message(FATAL_ERROR "SDL_HAPTIC requires SDL_JOYSTICK to be enabled")
  1110     endif()
  1111   endif()
  1112 
  1113   if(SDL_POWER)
  1114     set(SDL_POWER_MACOSX 1)
  1115     file(GLOB POWER_SOURCES ${SDL2_SOURCE_DIR}/src/power/macosx/*.c)
  1116     set(SOURCE_FILES ${SOURCE_FILES} ${POWER_SOURCES})
  1117     set(HAVE_SDL_POWER TRUE)
  1118     set(SDL_FRAMEWORK_CARBON 1)
  1119     set(SDL_FRAMEWORK_IOKIT 1)
  1120   endif()
  1121 
  1122   if(SDL_TIMERS)
  1123     set(SDL_TIMER_UNIX 1)
  1124     file(GLOB TIMER_SOURCES ${SDL2_SOURCE_DIR}/src/timer/unix/*.c)
  1125     set(SOURCE_FILES ${SOURCE_FILES} ${TIMER_SOURCES})
  1126     set(HAVE_SDL_TIMERS TRUE)
  1127   endif(SDL_TIMERS)
  1128 
  1129   if(SDL_FILESYSTEM)
  1130     set(SDL_FILESYSTEM_COCOA 1)
  1131     file(GLOB FILESYSTEM_SOURCES ${SDL2_SOURCE_DIR}/src/filesystem/cocoa/*.m)
  1132     set_source_files_properties(${FILESYSTEM_SOURCES} PROPERTIES LANGUAGE C)
  1133     set(SOURCE_FILES ${SOURCE_FILES} ${FILESYSTEM_SOURCES})
  1134     set(HAVE_SDL_FILESYSTEM TRUE)
  1135   endif()
  1136 
  1137   # Actually load the frameworks at the end so we don't duplicate include.
  1138   if(SDL_FRAMEWORK_COREVIDEO)
  1139     find_library(COREVIDEO CoreVideo)
  1140     list(APPEND EXTRA_LIBS ${COREVIDEO})
  1141   endif()
  1142   if(SDL_FRAMEWORK_COCOA)
  1143     find_library(COCOA_LIBRARY Cocoa)
  1144     list(APPEND EXTRA_LIBS ${COCOA_LIBRARY})
  1145   endif()
  1146   if(SDL_FRAMEWORK_IOKIT)
  1147     find_library(IOKIT IOKit)
  1148     list(APPEND EXTRA_LIBS ${IOKIT})
  1149   endif()
  1150   if(SDL_FRAMEWORK_FF)
  1151     find_library(FORCEFEEDBACK ForceFeedback)
  1152     list(APPEND EXTRA_LIBS ${FORCEFEEDBACK})
  1153   endif()
  1154   if(SDL_FRAMEWORK_CARBON)
  1155     find_library(CARBON_LIBRARY Carbon)
  1156     list(APPEND EXTRA_LIBS ${CARBON_LIBRARY})
  1157   endif()
  1158   if(SDL_FRAMEWORK_COREAUDIO)
  1159     find_library(COREAUDIO CoreAudio)
  1160     list(APPEND EXTRA_LIBS ${COREAUDIO})
  1161   endif()
  1162   if(SDL_FRAMEWORK_AUDIOUNIT)
  1163     find_library(AUDIOUNIT AudioUnit)
  1164     list(APPEND EXTRA_LIBS ${AUDIOUNIT})
  1165   endif()
  1166 
  1167   # iOS hack needed - http://code.google.com/p/ios-cmake/ ?
  1168   if(SDL_VIDEO)
  1169     CheckCOCOA()
  1170     if(VIDEO_OPENGL)
  1171       set(SDL_VIDEO_OPENGL 1)
  1172       set(SDL_VIDEO_OPENGL_CGL 1)
  1173       set(SDL_VIDEO_RENDER_OGL 1)
  1174       set(HAVE_VIDEO_OPENGL TRUE)
  1175     endif()
  1176   endif()
  1177 
  1178   CheckPTHREAD()
  1179 elseif(HAIKU)
  1180   if(SDL_VIDEO)
  1181     set(SDL_VIDEO_DRIVER_HAIKU 1)
  1182     file(GLOB HAIKUVIDEO_SOURCES ${SDL2_SOURCE_DIR}/src/video/haiku/*.c)
  1183     set(SOURCE_FILES ${SOURCE_FILES} ${HAIKUVIDEO_SOURCES})
  1184     set(HAVE_SDL_VIDEO TRUE)
  1185 
  1186     set(SDL_FILESYSTEM_HAIKU 1)
  1187     file(GLOB FILESYSTEM_SOURCES ${SDL2_SOURCE_DIR}/src/filesystem/haiku/*.cc)
  1188     set(SOURCE_FILES ${SOURCE_FILES} ${FILESYSTEM_SOURCES})
  1189     set(HAVE_SDL_FILESYSTEM TRUE)
  1190 
  1191     if(SDL_TIMERS)
  1192       set(SDL_TIMER_HAIKU 1)
  1193       file(GLOB TIMER_SOURCES ${SDL2_SOURCE_DIR}/src/timer/haiku/*.c)
  1194       set(SOURCE_FILES ${SOURCE_FILES} ${TIMER_SOURCES})
  1195       set(HAVE_SDL_TIMERS TRUE)
  1196     endif(SDL_TIMERS)
  1197 
  1198     if(VIDEO_OPENGL)
  1199       # TODO: Use FIND_PACKAGE(OpenGL) instead
  1200       set(SDL_VIDEO_OPENGL 1)
  1201       set(SDL_VIDEO_OPENGL_BGL 1)
  1202       set(SDL_VIDEO_RENDER_OGL 1)
  1203       list(APPEND EXTRA_LIBS GL)
  1204       set(HAVE_VIDEO_OPENGL TRUE)
  1205     endif()
  1206   endif()
  1207 
  1208   CheckPTHREAD()
  1209 endif()
  1210 
  1211 # Dummies
  1212 # configure.in does it differently:
  1213 # if not have X
  1214 #   if enable_X {  SDL_X_DISABLED = 1 }
  1215 #   [add dummy sources]
  1216 # so it always adds a dummy, without checking, if it was actually requested.
  1217 # This leads to missing internal references on building, since the
  1218 # src/X/*.c does not get included.
  1219 if(NOT HAVE_SDL_JOYSTICK)
  1220   set(SDL_JOYSTICK_DISABLED 1)
  1221   if(SDL_JOYSTICK AND NOT APPLE) # results in unresolved symbols on OSX
  1222 
  1223     file(GLOB JOYSTICK_SOURCES ${SDL2_SOURCE_DIR}/src/joystick/dummy/*.c)
  1224     set(SOURCE_FILES ${SOURCE_FILES} ${JOYSTICK_SOURCES})
  1225   endif()
  1226 endif()
  1227 if(NOT HAVE_SDL_HAPTIC)
  1228   set(SDL_HAPTIC_DISABLED 1)
  1229   file(GLOB HAPTIC_SOURCES ${SDL2_SOURCE_DIR}/src/haptic/dummy/*.c)
  1230   set(SOURCE_FILES ${SOURCE_FILES} ${HAPTIC_SOURCES})
  1231 endif()
  1232 if(NOT HAVE_SDL_LOADSO)
  1233   set(SDL_LOADSO_DISABLED 1)
  1234   file(GLOB LOADSO_SOURCES ${SDL2_SOURCE_DIR}/src/loadso/dummy/*.c)
  1235   set(SOURCE_FILES ${SOURCE_FILES} ${LOADSO_SOURCES})
  1236 endif()
  1237 if(NOT HAVE_SDL_FILESYSTEM)
  1238   set(SDL_FILESYSTEM_DISABLED 1)
  1239   file(GLOB FILESYSTEM_SOURCES ${SDL2_SOURCE_DIR}/src/filesystem/dummy/*.c)
  1240   set(SOURCE_FILES ${SOURCE_FILES} ${FILESYSTEM_SOURCES})
  1241 endif()
  1242 
  1243 # We always need to have threads and timers around
  1244 if(NOT HAVE_SDL_THREADS)
  1245   set(SDL_THREADS_DISABLED 1)
  1246   file(GLOB THREADS_SOURCES ${SDL2_SOURCE_DIR}/src/thread/generic/*.c)
  1247   set(SOURCE_FILES ${SOURCE_FILES} ${THREADS_SOURCES})
  1248 endif()
  1249 if(NOT HAVE_SDL_TIMERS)
  1250   set(SDL_TIMERS_DISABLED 1)
  1251   file(GLOB TIMER_SOURCES ${SDL2_SOURCE_DIR}/src/timer/dummy/*.c)
  1252   set(SOURCE_FILES ${SOURCE_FILES} ${TIMER_SOURCES})
  1253 endif()
  1254 
  1255 if(NOT SDLMAIN_SOURCES)
  1256   file(GLOB SDLMAIN_SOURCES ${SDL2_SOURCE_DIR}/src/main/dummy/*.c)
  1257 endif()
  1258 
  1259 # Append the -MMD -MT flags
  1260 # if(DEPENDENCY_TRACKING)
  1261 #   if(COMPILER_IS_GNUCC)
  1262 #     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -MMD -MT \$@")
  1263 #   endif()
  1264 # endif()
  1265 
  1266 configure_file("${SDL2_SOURCE_DIR}/include/SDL_config.h.cmake"
  1267   "${SDL2_BINARY_DIR}/include/SDL_config.h")
  1268 
  1269 # Prepare the flags and remove duplicates
  1270 if(EXTRA_LDFLAGS)
  1271   list(REMOVE_DUPLICATES EXTRA_LDFLAGS)
  1272 endif()
  1273 if(EXTRA_LIBS)
  1274   list(REMOVE_DUPLICATES EXTRA_LIBS)
  1275 endif()
  1276 if(EXTRA_CFLAGS)
  1277   list(REMOVE_DUPLICATES EXTRA_CFLAGS)
  1278 endif()
  1279 listtostr(EXTRA_CFLAGS _EXTRA_CFLAGS)
  1280 set(EXTRA_CFLAGS ${_EXTRA_CFLAGS})
  1281 
  1282 # Compat helpers for the configuration files
  1283 if(NOT WINDOWS OR CYGWIN)
  1284   # TODO: we need a Windows script, too
  1285   execute_process(COMMAND sh ${SDL2_SOURCE_DIR}/build-scripts/updaterev.sh)
  1286 
  1287   set(prefix ${CMAKE_INSTALL_PREFIX})
  1288   set(exec_prefix "\${prefix}")
  1289   set(libdir "\${exec_prefix}/lib${LIB_SUFFIX}")
  1290   set(bindir "\${exec_prefix}/bin")
  1291   set(includedir "\${prefix}/include")
  1292   if(SDL_STATIC)
  1293     set(ENABLE_STATIC_TRUE "")
  1294     set(ENABLE_STATIC_FALSE "#")
  1295   else()
  1296     set(ENABLE_STATIC_TRUE "#")
  1297     set(ENABLE_STATIC_FALSE "")
  1298   endif()
  1299   if(SDL_SHARED)
  1300     set(ENABLE_SHARED_TRUE "")
  1301     set(ENABLE_SHARED_FALSE "#")
  1302   else()
  1303     set(ENABLE_SHARED_TRUE "#")
  1304     set(ENABLE_SHARED_FALSE "")
  1305   endif()
  1306 
  1307   # Clean up the different lists
  1308   listtostr(EXTRA_LIBS _EXTRA_LIBS "-l")
  1309   set(SDL_STATIC_LIBS ${SDL_LIBS} ${EXTRA_LDFLAGS} ${_EXTRA_LIBS})
  1310   list(REMOVE_DUPLICATES SDL_STATIC_LIBS)
  1311   listtostr(SDL_STATIC_LIBS _SDL_STATIC_LIBS)
  1312   set(SDL_STATIC_LIBS ${_SDL_STATIC_LIBS})
  1313   listtostr(SDL_LIBS _SDL_LIBS)
  1314   set(SDL_LIBS ${_SDL_LIBS})
  1315 
  1316   # MESSAGE(STATUS "SDL_LIBS: ${SDL_LIBS}")
  1317   # MESSAGE(STATUS "SDL_STATIC_LIBS: ${SDL_STATIC_LIBS}")
  1318 
  1319   configure_file("${SDL2_SOURCE_DIR}/sdl2.pc.in"
  1320     "${SDL2_BINARY_DIR}/sdl2.pc" @ONLY)
  1321   configure_file("${SDL2_SOURCE_DIR}/sdl2-config.in"
  1322     "${SDL2_BINARY_DIR}/sdl2-config")
  1323   configure_file("${SDL2_SOURCE_DIR}/sdl2-config.in"
  1324     "${SDL2_BINARY_DIR}/sdl2-config" @ONLY)
  1325   configure_file("${SDL2_SOURCE_DIR}/SDL2.spec.in"
  1326     "${SDL2_BINARY_DIR}/SDL2.spec" @ONLY)
  1327 endif()
  1328 
  1329 ##### Info output #####
  1330 message(STATUS "")
  1331 message(STATUS "SDL2 was configured with the following options:")
  1332 message(STATUS "")
  1333 message(STATUS "Platform: ${CMAKE_SYSTEM}")
  1334 message(STATUS "64-bit:   ${ARCH_64}")
  1335 message(STATUS "Compiler: ${CMAKE_C_COMPILER}")
  1336 message(STATUS "")
  1337 message(STATUS "Subsystems:")
  1338 foreach(_SUB ${SDL_SUBSYSTEMS})
  1339   string(TOUPPER ${_SUB} _OPT)
  1340   message_bool_option(${_SUB} SDL_${_OPT})
  1341 endforeach()
  1342 message(STATUS "")
  1343 message(STATUS "Options:")
  1344 list(SORT ALLOPTIONS)
  1345 foreach(_OPT ${ALLOPTIONS})
  1346   # Longest option is VIDEO_X11_XSCREENSAVER = 22 characters
  1347   # Get the padding
  1348   string(LENGTH ${_OPT} _OPTLEN)
  1349   math(EXPR _PADLEN "23 - ${_OPTLEN}")
  1350   string(RANDOM LENGTH ${_PADLEN} ALPHABET " " _PADDING)
  1351   message_tested_option(${_OPT} ${_PADDING})
  1352 endforeach()
  1353 message(STATUS "")
  1354 message(STATUS " CFLAGS:        ${CMAKE_C_FLAGS}")
  1355 message(STATUS " EXTRA_CFLAGS:  ${EXTRA_CFLAGS}")
  1356 message(STATUS " EXTRA_LDFLAGS: ${EXTRA_LDFLAGS}")
  1357 message(STATUS " EXTRA_LIBS:    ${EXTRA_LIBS}")
  1358 message(STATUS "")
  1359 message(STATUS " Build Shared Library: ${SDL_SHARED}")
  1360 message(STATUS " Build Static Library: ${SDL_STATIC}")
  1361 message(STATUS "")
  1362 if(UNIX)
  1363   message(STATUS "If something was not detected, although the libraries")
  1364   message(STATUS "were installed, then make sure you have set the")
  1365   message(STATUS "CFLAGS and LDFLAGS environment variables correctly.")
  1366   message(STATUS "")
  1367 endif()
  1368 
  1369 # Ensure that the extra cflags are used at compile time
  1370 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${EXTRA_CFLAGS}")
  1371 
  1372 # Always build SDLmain
  1373 add_library(SDL2main STATIC ${SDLMAIN_SOURCES})
  1374 set(_INSTALL_LIBS "SDL2main")
  1375 
  1376 if(SDL_SHARED)
  1377   add_library(SDL2 SHARED ${SOURCE_FILES})
  1378   if(UNIX)
  1379     set_target_properties(SDL2 PROPERTIES
  1380       VERSION ${LT_VERSION}
  1381       SOVERSION ${LT_REVISION}
  1382       OUTPUT_NAME "SDL2-${LT_RELEASE}")
  1383   else()
  1384     set_target_properties(SDL2 PROPERTIES
  1385       VERSION ${SDL_VERSION}
  1386       SOVERSION ${LT_REVISION}
  1387       OUTPUT_NAME "SDL2")
  1388   endif()
  1389  set(_INSTALL_LIBS "SDL2" ${_INSTALL_LIBS})
  1390  target_link_libraries(SDL2 ${EXTRA_LIBS} ${EXTRA_LDFLAGS})
  1391 endif()
  1392 
  1393 if(SDL_STATIC)
  1394   set (BUILD_SHARED_LIBS FALSE)
  1395   add_library(SDL2-static STATIC ${SOURCE_FILES})
  1396   set_target_properties(SDL2-static PROPERTIES OUTPUT_NAME "SDL2")
  1397   if(MSVC)
  1398     set_target_properties(SDL2-static PROPERTIES LINK_FLAGS_RELEASE "/NODEFAULTLIB")
  1399     set_target_properties(SDL2-static PROPERTIES LINK_FLAGS_DEBUG "/NODEFAULTLIB")
  1400     set_target_properties(SDL2-static PROPERTIES STATIC_LIBRARY_FLAGS "/NODEFAULTLIB")
  1401   endif()
  1402   # TODO: Win32 platforms keep the same suffix .lib for import and static
  1403   # libraries - do we need to consider this?
  1404   set(_INSTALL_LIBS "SDL2-static" ${_INSTALL_LIBS})
  1405   target_link_libraries(SDL2-static ${EXTRA_LIBS} ${EXTRA_LDFLAGS})
  1406 endif()
  1407 
  1408 ##### Installation targets #####
  1409 install(TARGETS ${_INSTALL_LIBS}
  1410   LIBRARY DESTINATION "lib${LIB_SUFFIX}"
  1411   ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
  1412   RUNTIME DESTINATION bin)
  1413 
  1414 file(GLOB INCLUDE_FILES ${SDL2_SOURCE_DIR}/include/*.h)
  1415 file(GLOB BIN_INCLUDE_FILES ${SDL2_BINARY_DIR}/include/*.h)
  1416 foreach(_FNAME ${BIN_INCLUDE_FILES})
  1417   get_filename_component(_INCNAME ${_FNAME} NAME)
  1418   list(REMOVE_ITEM INCLUDE_FILES ${SDL2_SOURCE_DIR}/include/${_INCNAME})
  1419 endforeach()
  1420 list(APPEND INCLUDE_FILES ${BIN_INCLUDE_FILES})
  1421 install(FILES ${INCLUDE_FILES} DESTINATION include/SDL2)
  1422 
  1423 if(NOT WINDOWS OR CYGWIN)
  1424   if(SDL_SHARED)
  1425     install(CODE "
  1426       execute_process(COMMAND ${CMAKE_COMMAND} -E create_symlink
  1427       \"libSDL2-2.0.so\" \"libSDL2.so\")")
  1428     install(FILES ${SDL2_BINARY_DIR}/libSDL2.so DESTINATION "lib${LIB_SUFFIX}")
  1429   endif()
  1430   if(FREEBSD)
  1431     # FreeBSD uses ${PREFIX}/libdata/pkgconfig
  1432     install(FILES ${SDL2_BINARY_DIR}/sdl2.pc DESTINATION "libdata/pkgconfig")
  1433   else()
  1434     install(FILES ${SDL2_BINARY_DIR}/sdl2.pc
  1435       DESTINATION "lib${LIB_SUFFIX}/pkgconfig")
  1436   endif()
  1437   install(PROGRAMS ${SDL2_BINARY_DIR}/sdl2-config DESTINATION bin)
  1438   # TODO: what about the .spec file? Is it only needed for RPM creation?
  1439   install(FILES "${SDL2_SOURCE_DIR}/sdl2.m4" DESTINATION "share/aclocal")
  1440 endif()
  1441 
  1442 ##### Uninstall target #####
  1443 
  1444 configure_file(
  1445     "${CMAKE_CURRENT_SOURCE_DIR}/cmake_uninstall.cmake.in"
  1446     "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
  1447     IMMEDIATE @ONLY)
  1448 
  1449 add_custom_target(uninstall
  1450     COMMAND ${CMAKE_COMMAND} -P ${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake)