CMakeLists.txt
author Alex Szpakowski
Mon, 05 Aug 2019 12:35:32 -0300
changeset 12998 b87ba0fad17e
parent 12974 0fef4b21fa1d
child 13001 1353fb9be62b
permissions -rw-r--r--
Add public APIs for creating a Metal view attached to an SDL window. Add SDL_metal.h.
     1 if(${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
     2   message(FATAL_ERROR "Prevented in-tree built. Please create a build directory outside of the SDL source code and call cmake from there")
     3 endif()
     4 
     5 cmake_minimum_required(VERSION 2.8.11)
     6 project(SDL2 C CXX)
     7 
     8 # !!! FIXME: this should probably do "MACOSX_RPATH ON" as a target property
     9 # !!! FIXME:  for the SDL2 shared library (so you get an
    10 # !!! FIXME:  install_name ("soname") of "@rpath/libSDL-whatever.dylib"
    11 # !!! FIXME:  instead of "/usr/local/lib/libSDL-whatever.dylib"), but I'm
    12 # !!! FIXME:  punting for now and leaving the existing behavior. Until this
    13 # !!! FIXME:  properly resolved, this line silences a warning in CMake 3.0+.
    14 # !!! FIXME:  remove it and this comment entirely once the problem is
    15 # !!! FIXME:  properly resolved.
    16 #cmake_policy(SET CMP0042 OLD)
    17 
    18 include(CheckFunctionExists)
    19 include(CheckLibraryExists)
    20 include(CheckIncludeFiles)
    21 include(CheckIncludeFile)
    22 include(CheckSymbolExists)
    23 include(CheckCSourceCompiles)
    24 include(CheckCSourceRuns)
    25 include(CheckCCompilerFlag)
    26 include(CheckTypeSize)
    27 include(CheckStructHasMember)
    28 include(CMakeDependentOption)
    29 include(FindPkgConfig)
    30 include(GNUInstallDirs)
    31 set(CMAKE_MODULE_PATH "${SDL2_SOURCE_DIR}/cmake")
    32 include(${SDL2_SOURCE_DIR}/cmake/macros.cmake)
    33 include(${SDL2_SOURCE_DIR}/cmake/sdlchecks.cmake)
    34 
    35 # General settings
    36 # Edit include/SDL_version.h and change the version, then:
    37 #   SDL_MICRO_VERSION += 1;
    38 #   SDL_INTERFACE_AGE += 1;
    39 #   SDL_BINARY_AGE += 1;
    40 # if any functions have been added, set SDL_INTERFACE_AGE to 0.
    41 # if backwards compatibility has been broken,
    42 # set SDL_BINARY_AGE and SDL_INTERFACE_AGE to 0.
    43 set(SDL_MAJOR_VERSION 2)
    44 set(SDL_MINOR_VERSION 0)
    45 set(SDL_MICRO_VERSION 10)
    46 set(SDL_INTERFACE_AGE 0)
    47 set(SDL_BINARY_AGE 10)
    48 set(SDL_VERSION "${SDL_MAJOR_VERSION}.${SDL_MINOR_VERSION}.${SDL_MICRO_VERSION}")
    49 # the following should match the versions in Xcode project file:
    50 set(DYLIB_CURRENT_VERSION 10.0.0)
    51 set(DYLIB_COMPATIBILITY_VERSION 1.0.0)
    52 
    53 # Set defaults preventing destination file conflicts
    54 set(SDL_CMAKE_DEBUG_POSTFIX "d"
    55     CACHE STRING "Name suffix for debug builds")
    56 
    57 mark_as_advanced(CMAKE_IMPORT_LIBRARY_SUFFIX SDL_CMAKE_DEBUG_POSTFIX)
    58 
    59 # Calculate a libtool-like version number
    60 math(EXPR LT_CURRENT "${SDL_MICRO_VERSION} - ${SDL_INTERFACE_AGE}")
    61 math(EXPR LT_AGE "${SDL_BINARY_AGE} - ${SDL_INTERFACE_AGE}")
    62 math(EXPR LT_MAJOR "${LT_CURRENT}- ${LT_AGE}")
    63 set(LT_REVISION "${SDL_INTERFACE_AGE}")
    64 set(LT_RELEASE "${SDL_MAJOR_VERSION}.${SDL_MINOR_VERSION}")
    65 set(LT_VERSION "${LT_MAJOR}.${LT_AGE}.${LT_REVISION}")
    66 
    67 #message(STATUS "${LT_VERSION} :: ${LT_AGE} :: ${LT_REVISION} :: ${LT_CURRENT} :: ${LT_RELEASE}")
    68 
    69 # General settings & flags
    70 set(LIBRARY_OUTPUT_DIRECTORY "build")
    71 # Check for 64 or 32 bit
    72 set(SIZEOF_VOIDP ${CMAKE_SIZEOF_VOID_P})
    73 if(CMAKE_SIZEOF_VOID_P EQUAL 8)
    74   set(ARCH_64 TRUE)
    75   set(PROCESSOR_ARCH "x64")
    76 else()
    77   set(ARCH_64 FALSE)
    78   set(PROCESSOR_ARCH "x86")
    79 endif()
    80 set(LIBNAME SDL2)
    81 if(NOT LIBTYPE)
    82   set(LIBTYPE SHARED)
    83 endif()
    84 
    85 # Get the platform
    86 if(WIN32)
    87   if(NOT WINDOWS)
    88     set(WINDOWS TRUE)
    89   endif()
    90 elseif(UNIX AND NOT APPLE)
    91   if(CMAKE_SYSTEM_NAME MATCHES ".*Linux")
    92     set(LINUX TRUE)
    93   elseif(CMAKE_SYSTEM_NAME MATCHES "kFreeBSD.*")
    94     set(FREEBSD TRUE)
    95   elseif(CMAKE_SYSTEM_NAME MATCHES "kNetBSD.*|NetBSD.*")
    96     set(NETBSD TRUE)
    97   elseif(CMAKE_SYSTEM_NAME MATCHES "kOpenBSD.*|OpenBSD.*")
    98     set(OPENBSD TRUE)
    99   elseif(CMAKE_SYSTEM_NAME MATCHES ".*GNU.*")
   100     set(GNU TRUE)
   101   elseif(CMAKE_SYSTEM_NAME MATCHES ".*BSDI.*")
   102     set(BSDI TRUE)
   103   elseif(CMAKE_SYSTEM_NAME MATCHES "DragonFly.*|FreeBSD")
   104     set(FREEBSD TRUE)
   105   elseif(CMAKE_SYSTEM_NAME MATCHES "SYSV5.*")
   106     set(SYSV5 TRUE)
   107   elseif(CMAKE_SYSTEM_NAME MATCHES "Solaris.*")
   108     set(SOLARIS TRUE)
   109   elseif(CMAKE_SYSTEM_NAME MATCHES "HP-UX.*")
   110     set(HPUX TRUE)
   111   elseif(CMAKE_SYSTEM_NAME MATCHES "AIX.*")
   112     set(AIX TRUE)
   113   elseif(CMAKE_SYSTEM_NAME MATCHES "Minix.*")
   114     set(MINIX TRUE)
   115   endif()
   116 elseif(APPLE)
   117   if(CMAKE_SYSTEM_NAME MATCHES ".*Darwin.*")
   118     set(DARWIN TRUE)
   119   elseif(CMAKE_SYSTEM_NAME MATCHES ".*MacOS.*")
   120     set(MACOSX TRUE)
   121   endif()
   122   # TODO: iOS?
   123 elseif(CMAKE_SYSTEM_NAME MATCHES "BeOS.*")
   124   message_error("BeOS support has been removed as of SDL 2.0.2.")
   125 elseif(CMAKE_SYSTEM_NAME MATCHES "Haiku.*")
   126   set(HAIKU TRUE)
   127 endif()
   128 
   129 # Don't mistake osx for unix
   130 if(UNIX AND NOT APPLE)
   131   set(UNIX_SYS ON)
   132 else()
   133   set(UNIX_SYS OFF)
   134 endif()
   135 
   136 if(UNIX OR APPLE)
   137   set(UNIX_OR_MAC_SYS ON)
   138 else()
   139   set(UNIX_OR_MAC_SYS OFF)
   140 endif()
   141 
   142 if (UNIX_OR_MAC_SYS AND NOT EMSCRIPTEN) # JavaScript does not yet have threading support, so disable pthreads when building for Emscripten.
   143   set(SDL_PTHREADS_ENABLED_BY_DEFAULT ON)
   144 else()
   145   set(SDL_PTHREADS_ENABLED_BY_DEFAULT OFF)
   146 endif()
   147 
   148 # Default option knobs
   149 if(APPLE OR ARCH_64)
   150   if(NOT "${CMAKE_OSX_ARCHITECTURES}" MATCHES "arm")
   151     set(OPT_DEF_SSEMATH ON)
   152   endif()
   153 endif()
   154 if(UNIX OR MINGW OR MSYS)
   155   set(OPT_DEF_LIBC ON)
   156 endif()
   157 
   158 # The hidraw support doesn't catch Xbox, PS4 and Nintendo controllers,
   159 #  so we'll just use libusb when it's available. libusb does not support iOS,
   160 #  so we default to yes on iOS.
   161 #  TODO: Windows can support libusb, the hid.c file just depends on Unix APIs
   162 if(WINDOWS OR IOS OR ANDROID)
   163   set(HIDAPI_SKIP_LIBUSB TRUE)
   164 else()
   165   set(HIDAPI_SKIP_LIBUSB FALSE)
   166 endif()
   167 if (HIDAPI_SKIP_LIBUSB)
   168   set(OPT_DEF_HIDAPI ON)
   169 endif()
   170 
   171 # On the other hand, *BSD specifically uses libusb only, so we make a special
   172 #  case just for them.
   173 if(FREEBSD OR NETBSD OR OPENBSD OR BSDI)
   174   set(HIDAPI_ONLY_LIBUSB TRUE)
   175 else()
   176   set(HIDAPI_ONLY_LIBUSB FALSE)
   177 endif()
   178 
   179 # Compiler info
   180 if(CMAKE_COMPILER_IS_GNUCC)
   181   set(USE_GCC TRUE)
   182   set(OPT_DEF_ASM TRUE)
   183 elseif(CMAKE_C_COMPILER_ID MATCHES "Clang")
   184   set(USE_CLANG TRUE)
   185   set(OPT_DEF_ASM TRUE)
   186 elseif(MSVC_VERSION GREATER 1400) # VisualStudio 8.0+
   187   set(OPT_DEF_ASM TRUE)
   188   #set(CMAKE_C_FLAGS "/ZI /WX- /
   189 else()
   190   set(OPT_DEF_ASM FALSE)
   191 endif()
   192 
   193 if(USE_GCC OR USE_CLANG)
   194   set(OPT_DEF_GCC_ATOMICS ON)
   195 endif()
   196 
   197 # Default flags, if not set otherwise
   198 if("$ENV{CFLAGS}" STREQUAL "")
   199   if(CMAKE_BUILD_TYPE STREQUAL "")
   200     if(USE_GCC OR USE_CLANG)
   201       set(CMAKE_C_FLAGS "-g -O3")
   202     endif()
   203   endif()
   204 else()
   205   set(CMAKE_C_FLAGS "$ENV{CFLAGS}")
   206   list(APPEND EXTRA_CFLAGS "$ENV{CFLAGS}")
   207 endif()
   208 if(NOT ("$ENV{CFLAGS}" STREQUAL "")) # Hackish, but does the trick on Win32
   209   list(APPEND EXTRA_LDFLAGS "$ENV{LDFLAGS}")
   210 endif()
   211 
   212 if(MSVC)
   213   option(FORCE_STATIC_VCRT "Force /MT for static VC runtimes" OFF)
   214   if(FORCE_STATIC_VCRT)
   215     foreach(flag_var
   216         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
   217         CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO)
   218       if(${flag_var} MATCHES "/MD")
   219         string(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
   220       endif()
   221     endforeach()
   222   endif()
   223 
   224   # Make sure /RTC1 is disabled, otherwise it will use functions from the CRT
   225   foreach(flag_var
   226       CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
   227       CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO)
   228     string(REGEX REPLACE "/RTC(su|[1su])" "" ${flag_var} "${${flag_var}}")
   229   endforeach(flag_var)
   230 endif()
   231 
   232 # Those are used for pkg-config and friends, so that the SDL2.pc, sdl2-config,
   233 # etc. are created correctly.
   234 set(SDL_LIBS "-lSDL2")
   235 set(SDL_CFLAGS "")
   236 
   237 # When building shared lib for Windows with MinGW,
   238 # avoid the DLL having a "lib" prefix
   239 if(WINDOWS)
   240   set(CMAKE_SHARED_LIBRARY_PREFIX "")
   241 endif()
   242 
   243 # Emscripten toolchain has a nonempty default value for this, and the checks
   244 # in this file need to change that, so remember the original value, and
   245 # restore back to that afterwards. For check_function_exists() to work in
   246 # Emscripten, this value must be at its default value.
   247 set(ORIG_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
   248 
   249 if(CYGWIN)
   250   # We build SDL on cygwin without the UNIX emulation layer
   251   include_directories("-I/usr/include/mingw")
   252   set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -mno-cygwin")
   253   check_c_source_compiles("int main(int argc, char **argv) {}"
   254     HAVE_GCC_NO_CYGWIN)
   255   set(CMAKE_REQUIRED_FLAGS ${ORIG_CMAKE_REQUIRED_FLAGS})
   256   if(HAVE_GCC_NO_CYGWIN)
   257     list(APPEND EXTRA_LDFLAGS "-mno-cygwin")
   258     list(APPEND SDL_LIBS "-mno-cygwin")
   259   endif()
   260   set(SDL_CFLAGS "${SDL_CFLAGS} -I/usr/include/mingw")
   261 endif()
   262 
   263 add_definitions(-DUSING_GENERATED_CONFIG_H)
   264 # General includes
   265 include_directories(${SDL2_BINARY_DIR}/include ${SDL2_SOURCE_DIR}/include)
   266 if(USE_GCC OR USE_CLANG)
   267   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -idirafter ${SDL2_SOURCE_DIR}/src/video/khronos")
   268 else()
   269   include_directories(${SDL2_SOURCE_DIR}/src/video/khronos)
   270 endif()
   271 
   272 # All these ENABLED_BY_DEFAULT vars will default to ON if not specified, so
   273 #  you only need to have a platform override them if they are disabling.
   274 set(OPT_DEF_ASM TRUE)
   275 if(EMSCRIPTEN)
   276   # Set up default values for the currently supported set of subsystems:
   277   # Emscripten/Javascript does not have assembly support, a dynamic library
   278   # loading architecture, low-level CPU inspection or multithreading.
   279   set(OPT_DEF_ASM FALSE)
   280   set(SDL_SHARED_ENABLED_BY_DEFAULT OFF)
   281   set(SDL_ATOMIC_ENABLED_BY_DEFAULT OFF)
   282   set(SDL_THREADS_ENABLED_BY_DEFAULT OFF)
   283   set(SDL_LOADSO_ENABLED_BY_DEFAULT OFF)
   284   set(SDL_CPUINFO_ENABLED_BY_DEFAULT OFF)
   285   set(SDL_DLOPEN_ENABLED_BY_DEFAULT OFF)
   286 endif()
   287 
   288 # When defined, respect CMake's BUILD_SHARED_LIBS setting:
   289 set(SDL_STATIC_ENABLED_BY_DEFAULT ON)
   290 if (NOT DEFINED SDL_SHARED_ENABLED_BY_DEFAULT)
   291   # ...unless decided already (as for EMSCRIPTEN)
   292 
   293   set(SDL_SHARED_ENABLED_BY_DEFAULT OFF)
   294 
   295   if (NOT DEFINED BUILD_SHARED_LIBS)
   296     # No preference? Build both, just like the AC/AM configure
   297     set(SDL_SHARED_ENABLED_BY_DEFAULT ON)
   298 
   299   elseif (BUILD_SHARED_LIBS)
   300     # In this case, we assume the user wants a shared lib and don't build
   301     # the static one
   302     set(SDL_SHARED_ENABLED_BY_DEFAULT ON)
   303     set(SDL_STATIC_ENABLED_BY_DEFAULT OFF)
   304   endif()
   305 endif()
   306 
   307 set(SDL_SUBSYSTEMS
   308     Atomic Audio Video Render Events Joystick Haptic Power Threads Timers
   309     File Loadso CPUinfo Filesystem Dlopen Sensor)
   310 foreach(_SUB ${SDL_SUBSYSTEMS})
   311   string(TOUPPER ${_SUB} _OPT)
   312   if (NOT DEFINED SDL_${_OPT}_ENABLED_BY_DEFAULT)
   313     set(SDL_${_OPT}_ENABLED_BY_DEFAULT ON)
   314   endif()
   315   option(SDL_${_OPT} "Enable the ${_SUB} subsystem" ${SDL_${_OPT}_ENABLED_BY_DEFAULT})
   316 endforeach()
   317 
   318 option_string(ASSERTIONS "Enable internal sanity checks (auto/disabled/release/enabled/paranoid)" "auto")
   319 #set_option(DEPENDENCY_TRACKING "Use gcc -MMD -MT dependency tracking" ON)
   320 set_option(LIBC                "Use the system C library" ${OPT_DEF_LIBC})
   321 set_option(GCC_ATOMICS         "Use gcc builtin atomics" ${OPT_DEF_GCC_ATOMICS})
   322 set_option(ASSEMBLY            "Enable assembly routines" ${OPT_DEF_ASM})
   323 set_option(SSEMATH             "Allow GCC to use SSE floating point math" ${OPT_DEF_SSEMATH})
   324 set_option(MMX                 "Use MMX assembly routines" ${OPT_DEF_ASM})
   325 set_option(3DNOW               "Use 3Dnow! MMX assembly routines" ${OPT_DEF_ASM})
   326 set_option(SSE                 "Use SSE assembly routines" ${OPT_DEF_ASM})
   327 set_option(SSE2                "Use SSE2 assembly routines" ${OPT_DEF_SSEMATH})
   328 set_option(SSE3                "Use SSE3 assembly routines" ${OPT_DEF_SSEMATH})
   329 set_option(ALTIVEC             "Use Altivec assembly routines" ${OPT_DEF_ASM})
   330 set_option(DISKAUDIO           "Support the disk writer audio driver" ON)
   331 set_option(DUMMYAUDIO          "Support the dummy audio driver" ON)
   332 set_option(VIDEO_DIRECTFB      "Use DirectFB video driver" OFF)
   333 dep_option(DIRECTFB_SHARED     "Dynamically load directfb support" ON "VIDEO_DIRECTFB" OFF)
   334 set_option(VIDEO_DUMMY         "Use dummy video driver" ON)
   335 set_option(VIDEO_OPENGL        "Include OpenGL support" ON)
   336 set_option(VIDEO_OPENGLES      "Include OpenGL ES support" ON)
   337 set_option(PTHREADS            "Use POSIX threads for multi-threading" ${SDL_PTHREADS_ENABLED_BY_DEFAULT})
   338 dep_option(PTHREADS_SEM        "Use pthread semaphores" ON "PTHREADS" OFF)
   339 set_option(SDL_DLOPEN          "Use dlopen for shared object loading" ${SDL_DLOPEN_ENABLED_BY_DEFAULT})
   340 set_option(OSS                 "Support the OSS audio API" ${UNIX_SYS})
   341 set_option(ALSA                "Support the ALSA audio API" ${UNIX_SYS})
   342 dep_option(ALSA_SHARED         "Dynamically load ALSA audio support" ON "ALSA" OFF)
   343 set_option(JACK                "Support the JACK audio API" ${UNIX_SYS})
   344 dep_option(JACK_SHARED         "Dynamically load JACK audio support" ON "JACK" OFF)
   345 set_option(ESD                 "Support the Enlightened Sound Daemon" ${UNIX_SYS})
   346 dep_option(ESD_SHARED          "Dynamically load ESD audio support" ON "ESD" OFF)
   347 set_option(PULSEAUDIO          "Use PulseAudio" ${UNIX_SYS})
   348 dep_option(PULSEAUDIO_SHARED   "Dynamically load PulseAudio support" ON "PULSEAUDIO" OFF)
   349 set_option(ARTS                "Support the Analog Real Time Synthesizer" ${UNIX_SYS})
   350 dep_option(ARTS_SHARED         "Dynamically load aRts audio support" ON "ARTS" OFF)
   351 set_option(NAS                 "Support the NAS audio API" ${UNIX_SYS})
   352 set_option(NAS_SHARED          "Dynamically load NAS audio API" ${UNIX_SYS})
   353 set_option(SNDIO               "Support the sndio audio API" ${UNIX_SYS})
   354 set_option(FUSIONSOUND         "Use FusionSound audio driver" OFF)
   355 dep_option(FUSIONSOUND_SHARED  "Dynamically load fusionsound audio support" ON "FUSIONSOUND" OFF)
   356 set_option(LIBSAMPLERATE       "Use libsamplerate for audio rate conversion" ${UNIX_SYS})
   357 dep_option(LIBSAMPLERATE_SHARED "Dynamically load libsamplerate" ON "LIBSAMPLERATE" OFF)
   358 set_option(RPATH               "Use an rpath when linking SDL" ${UNIX_SYS})
   359 set_option(CLOCK_GETTIME       "Use clock_gettime() instead of gettimeofday()" OFF)
   360 set_option(INPUT_TSLIB         "Use the Touchscreen library for input" ${UNIX_SYS})
   361 set_option(VIDEO_X11           "Use X11 video driver" ${UNIX_SYS})
   362 set_option(VIDEO_WAYLAND       "Use Wayland video driver" ${UNIX_SYS})
   363 dep_option(WAYLAND_SHARED      "Dynamically load Wayland support" ON "VIDEO_WAYLAND" OFF)
   364 dep_option(VIDEO_WAYLAND_QT_TOUCH  "QtWayland server support for Wayland video driver" ON "VIDEO_WAYLAND" OFF)
   365 set_option(VIDEO_RPI           "Use Raspberry Pi video driver" ${UNIX_SYS})
   366 dep_option(X11_SHARED          "Dynamically load X11 support" ON "VIDEO_X11" OFF)
   367 set(SDL_X11_OPTIONS Xcursor Xinerama XInput Xrandr Xscrnsaver XShape Xvm)
   368 foreach(_SUB ${SDL_X11_OPTIONS})
   369   string(TOUPPER "VIDEO_X11_${_SUB}" _OPT)
   370   dep_option(${_OPT}           "Enable ${_SUB} support" ON "VIDEO_X11" OFF)
   371 endforeach()
   372 set_option(VIDEO_COCOA         "Use Cocoa video driver" ${APPLE})
   373 set_option(DIRECTX             "Use DirectX for Windows audio/video" ${WINDOWS})
   374 set_option(WASAPI              "Use the Windows WASAPI audio driver" ${WINDOWS})
   375 set_option(RENDER_D3D          "Enable the Direct3D render driver" ${WINDOWS})
   376 set_option(RENDER_METAL        "Enable the Metal render driver" ${APPLE})
   377 set_option(VIDEO_VIVANTE       "Use Vivante EGL video driver" ${UNIX_SYS})
   378 dep_option(VIDEO_VULKAN        "Enable Vulkan support" ON "ANDROID OR APPLE OR LINUX OR WINDOWS" OFF)
   379 set_option(VIDEO_METAL         "Enable Metal support" ${APPLE})
   380 set_option(VIDEO_KMSDRM        "Use KMS DRM video driver" ${UNIX_SYS})
   381 dep_option(KMSDRM_SHARED       "Dynamically load KMS DRM support" ON "VIDEO_KMSDRM" OFF)
   382 option_string(BACKGROUNDING_SIGNAL "number to use for magic backgrounding signal or 'OFF'" "OFF")
   383 option_string(FOREGROUNDING_SIGNAL "number to use for magic foregrounding signal or 'OFF'" "OFF")
   384 set_option(HIDAPI              "Use HIDAPI for low level joystick drivers" ${OPT_DEF_HIDAPI})
   385 
   386 set(SDL_SHARED ${SDL_SHARED_ENABLED_BY_DEFAULT} CACHE BOOL "Build a shared version of the library")
   387 set(SDL_STATIC ${SDL_STATIC_ENABLED_BY_DEFAULT} CACHE BOOL "Build a static version of the library")
   388 
   389 dep_option(SDL_STATIC_PIC      "Static version of the library should be built with Position Independent Code" OFF "SDL_STATIC" OFF)
   390 set_option(SDL_TEST            "Build the test directory" OFF)
   391 
   392 # General source files
   393 file(GLOB SOURCE_FILES
   394   ${SDL2_SOURCE_DIR}/src/*.c
   395   ${SDL2_SOURCE_DIR}/src/atomic/*.c
   396   ${SDL2_SOURCE_DIR}/src/audio/*.c
   397   ${SDL2_SOURCE_DIR}/src/cpuinfo/*.c
   398   ${SDL2_SOURCE_DIR}/src/dynapi/*.c
   399   ${SDL2_SOURCE_DIR}/src/events/*.c
   400   ${SDL2_SOURCE_DIR}/src/file/*.c
   401   ${SDL2_SOURCE_DIR}/src/libm/*.c
   402   ${SDL2_SOURCE_DIR}/src/render/*.c
   403   ${SDL2_SOURCE_DIR}/src/render/*/*.c
   404   ${SDL2_SOURCE_DIR}/src/stdlib/*.c
   405   ${SDL2_SOURCE_DIR}/src/thread/*.c
   406   ${SDL2_SOURCE_DIR}/src/timer/*.c
   407   ${SDL2_SOURCE_DIR}/src/video/*.c
   408   ${SDL2_SOURCE_DIR}/src/video/yuv2rgb/*.c)
   409 
   410 
   411 if(ASSERTIONS STREQUAL "auto")
   412   # Do nada - use optimization settings to determine the assertion level
   413 elseif(ASSERTIONS STREQUAL "disabled")
   414   set(SDL_DEFAULT_ASSERT_LEVEL 0)
   415 elseif(ASSERTIONS STREQUAL "release")
   416   set(SDL_DEFAULT_ASSERT_LEVEL 1)
   417 elseif(ASSERTIONS STREQUAL "enabled")
   418   set(SDL_DEFAULT_ASSERT_LEVEL 2)
   419 elseif(ASSERTIONS STREQUAL "paranoid")
   420   set(SDL_DEFAULT_ASSERT_LEVEL 3)
   421 else()
   422   message_error("unknown assertion level")
   423 endif()
   424 set(HAVE_ASSERTIONS ${ASSERTIONS})
   425 
   426 if(NOT BACKGROUNDING_SIGNAL STREQUAL "OFF")
   427   add_definitions("-DSDL_BACKGROUNDING_SIGNAL=${BACKGROUNDING_SIGNAL}")
   428 endif()
   429 
   430 if(NOT FOREGROUNDING_SIGNAL STREQUAL "OFF")
   431   add_definitions("-DSDL_FOREGROUNDING_SIGNAL=${FOREGROUNDING_SIGNAL}")
   432 endif()
   433 
   434 # Compiler option evaluation
   435 if(USE_GCC OR USE_CLANG)
   436   # Check for -Wall first, so later things can override pieces of it.
   437   check_c_compiler_flag(-Wall HAVE_GCC_WALL)
   438   if(HAVE_GCC_WALL)
   439     list(APPEND EXTRA_CFLAGS "-Wall")
   440     if(HAIKU)
   441       set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-multichar")
   442     endif()
   443   endif()
   444 
   445   check_c_compiler_flag(-fno-strict-aliasing HAVE_GCC_NO_STRICT_ALIASING)
   446   if(HAVE_GCC_NO_STRICT_ALIASING)
   447     list(APPEND EXTRA_CFLAGS "-fno-strict-aliasing")
   448   endif()
   449 
   450   check_c_compiler_flag(-Wdeclaration-after-statement HAVE_GCC_WDECLARATION_AFTER_STATEMENT)
   451   if(HAVE_GCC_WDECLARATION_AFTER_STATEMENT)
   452     check_c_compiler_flag(-Werror=declaration-after-statement HAVE_GCC_WERROR_DECLARATION_AFTER_STATEMENT)
   453     if(HAVE_GCC_WERROR_DECLARATION_AFTER_STATEMENT)
   454       list(APPEND EXTRA_CFLAGS "-Werror=declaration-after-statement")
   455     endif()
   456     list(APPEND EXTRA_CFLAGS "-Wdeclaration-after-statement")
   457   endif()
   458 
   459   if(DEPENDENCY_TRACKING)
   460     check_c_source_compiles("
   461         #if !defined(__GNUC__) || __GNUC__ < 3
   462         #error Dependency tracking requires GCC 3.0 or newer
   463         #endif
   464         int main(int argc, char **argv) { }" HAVE_DEPENDENCY_TRACKING)
   465   endif()
   466 
   467   if(GCC_ATOMICS)
   468     check_c_source_compiles("int main(int argc, char **argv) {
   469         int a;
   470         void *x, *y, *z;
   471         __sync_lock_test_and_set(&a, 4);
   472         __sync_lock_test_and_set(&x, y);
   473         __sync_fetch_and_add(&a, 1);
   474         __sync_bool_compare_and_swap(&a, 5, 10);
   475         __sync_bool_compare_and_swap(&x, y, z); }" HAVE_GCC_ATOMICS)
   476     if(NOT HAVE_GCC_ATOMICS)
   477       check_c_source_compiles("int main(int argc, char **argv) {
   478           int a;
   479           __sync_lock_test_and_set(&a, 1);
   480           __sync_lock_release(&a); }" HAVE_GCC_SYNC_LOCK_TEST_AND_SET)
   481     endif()
   482   endif()
   483 
   484   set(CMAKE_REQUIRED_FLAGS "-mpreferred-stack-boundary=2")
   485   check_c_source_compiles("int x = 0; int main(int argc, char **argv) {}"
   486     HAVE_GCC_PREFERRED_STACK_BOUNDARY)
   487   set(CMAKE_REQUIRED_FLAGS ${ORIG_CMAKE_REQUIRED_FLAGS})
   488 
   489   set(CMAKE_REQUIRED_FLAGS "-fvisibility=hidden -Werror")
   490   check_c_source_compiles("
   491       #if !defined(__GNUC__) || __GNUC__ < 4
   492       #error SDL only uses visibility attributes in GCC 4 or newer
   493       #endif
   494       int main(int argc, char **argv) {}" HAVE_GCC_FVISIBILITY)
   495   if(HAVE_GCC_FVISIBILITY)
   496     list(APPEND EXTRA_CFLAGS "-fvisibility=hidden")
   497   endif()
   498   set(CMAKE_REQUIRED_FLAGS ${ORIG_CMAKE_REQUIRED_FLAGS})
   499 
   500   check_c_compiler_flag(-Wshadow HAVE_GCC_WSHADOW)
   501   if(HAVE_GCC_WSHADOW)
   502     list(APPEND EXTRA_CFLAGS "-Wshadow")
   503   endif()
   504 
   505   if(APPLE)
   506     list(APPEND EXTRA_LDFLAGS "-Wl,-undefined,error")
   507     list(APPEND EXTRA_LDFLAGS "-Wl,-compatibility_version,${DYLIB_COMPATIBILITY_VERSION}")
   508     list(APPEND EXTRA_LDFLAGS "-Wl,-current_version,${DYLIB_CURRENT_VERSION}")
   509   else()
   510     set(CMAKE_REQUIRED_FLAGS "-Wl,--no-undefined")
   511     check_c_compiler_flag("" HAVE_NO_UNDEFINED)
   512     set(CMAKE_REQUIRED_FLAGS ${ORIG_CMAKE_REQUIRED_FLAGS})
   513     if(HAVE_NO_UNDEFINED)
   514       list(APPEND EXTRA_LDFLAGS "-Wl,--no-undefined")
   515     endif()
   516   endif()
   517 endif()
   518 
   519 if(ASSEMBLY)
   520   if(USE_GCC OR USE_CLANG)
   521     set(SDL_ASSEMBLY_ROUTINES 1)
   522     # TODO: Those all seem to be quite GCC specific - needs to be
   523     # reworked for better compiler support
   524     set(HAVE_ASSEMBLY TRUE)
   525     if(MMX)
   526       set(CMAKE_REQUIRED_FLAGS "-mmmx")
   527       check_c_source_compiles("
   528           #ifdef __MINGW32__
   529           #include <_mingw.h>
   530           #ifdef __MINGW64_VERSION_MAJOR
   531           #include <intrin.h>
   532           #else
   533           #include <mmintrin.h>
   534           #endif
   535           #else
   536           #include <mmintrin.h>
   537           #endif
   538           #ifndef __MMX__
   539           #error Assembler CPP flag not enabled
   540           #endif
   541           int main(int argc, char **argv) { }" HAVE_MMX)
   542       if(HAVE_MMX)
   543         list(APPEND EXTRA_CFLAGS "-mmmx")
   544       endif()
   545       set(CMAKE_REQUIRED_FLAGS ${ORIG_CMAKE_REQUIRED_FLAGS})
   546     endif()
   547 
   548     if(3DNOW)
   549       set(CMAKE_REQUIRED_FLAGS "-m3dnow")
   550       check_c_source_compiles("
   551           #include <mm3dnow.h>
   552           #ifndef __3dNOW__
   553           #error Assembler CPP flag not enabled
   554           #endif
   555           int main(int argc, char **argv) {
   556             void *p = 0;
   557             _m_prefetch(p);
   558           }" HAVE_3DNOW)
   559       if(HAVE_3DNOW)
   560         list(APPEND EXTRA_CFLAGS "-m3dnow")
   561       endif()
   562       set(CMAKE_REQUIRED_FLAGS ${ORIG_CMAKE_REQUIRED_FLAGS})
   563     endif()
   564 
   565     if(SSE)
   566       set(CMAKE_REQUIRED_FLAGS "-msse")
   567       check_c_source_compiles("
   568           #ifdef __MINGW32__
   569           #include <_mingw.h>
   570           #ifdef __MINGW64_VERSION_MAJOR
   571           #include <intrin.h>
   572           #else
   573           #include <xmmintrin.h>
   574           #endif
   575           #else
   576           #include <xmmintrin.h>
   577           #endif
   578           #ifndef __SSE__
   579           #error Assembler CPP flag not enabled
   580           #endif
   581           int main(int argc, char **argv) { }" HAVE_SSE)
   582       if(HAVE_SSE)
   583         list(APPEND EXTRA_CFLAGS "-msse")
   584       endif()
   585       set(CMAKE_REQUIRED_FLAGS ${ORIG_CMAKE_REQUIRED_FLAGS})
   586     endif()
   587 
   588     if(SSE2)
   589       set(CMAKE_REQUIRED_FLAGS "-msse2")
   590       check_c_source_compiles("
   591           #ifdef __MINGW32__
   592           #include <_mingw.h>
   593           #ifdef __MINGW64_VERSION_MAJOR
   594           #include <intrin.h>
   595           #else
   596           #include <emmintrin.h>
   597           #endif
   598           #else
   599           #include <emmintrin.h>
   600           #endif
   601           #ifndef __SSE2__
   602           #error Assembler CPP flag not enabled
   603           #endif
   604           int main(int argc, char **argv) { }" HAVE_SSE2)
   605       if(HAVE_SSE2)
   606         list(APPEND EXTRA_CFLAGS "-msse2")
   607       endif()
   608       set(CMAKE_REQUIRED_FLAGS ${ORIG_CMAKE_REQUIRED_FLAGS})
   609     endif()
   610 
   611     if(SSE3)
   612       set(CMAKE_REQUIRED_FLAGS "-msse3")
   613       check_c_source_compiles("
   614           #ifdef __MINGW32__
   615           #include <_mingw.h>
   616           #ifdef __MINGW64_VERSION_MAJOR
   617           #include <intrin.h>
   618           #else
   619           #include <pmmintrin.h>
   620           #endif
   621           #else
   622           #include <pmmintrin.h>
   623           #endif
   624           #ifndef __SSE3__
   625           #error Assembler CPP flag not enabled
   626           #endif
   627           int main(int argc, char **argv) { }" HAVE_SSE3)
   628       if(HAVE_SSE3)
   629         list(APPEND EXTRA_CFLAGS "-msse3")
   630       endif()
   631       set(CMAKE_REQUIRED_FLAGS ${ORIG_CMAKE_REQUIRED_FLAGS})
   632     endif()
   633 
   634     if(NOT SSEMATH)
   635       if(SSE OR SSE2 OR SSE3)
   636         if(USE_GCC)
   637           check_c_compiler_flag(-mfpmath=387 HAVE_FP_387)
   638           if(HAVE_FP_387)
   639             list(APPEND EXTRA_CFLAGS "-mfpmath=387")
   640           endif()
   641         endif()
   642         set(HAVE_SSEMATH TRUE)
   643       endif()
   644     endif()
   645 
   646     check_include_file("immintrin.h" HAVE_IMMINTRIN_H)
   647 
   648     if(ALTIVEC)
   649       set(CMAKE_REQUIRED_FLAGS "-maltivec")
   650       check_c_source_compiles("
   651           #include <altivec.h>
   652           vector unsigned int vzero() {
   653               return vec_splat_u32(0);
   654           }
   655           int main(int argc, char **argv) { }" HAVE_ALTIVEC_H_HDR)
   656       check_c_source_compiles("
   657           vector unsigned int vzero() {
   658               return vec_splat_u32(0);
   659           }
   660           int main(int argc, char **argv) { }" HAVE_ALTIVEC)
   661       set(CMAKE_REQUIRED_FLAGS ${ORIG_CMAKE_REQUIRED_FLAGS})
   662       if(HAVE_ALTIVEC OR HAVE_ALTIVEC_H_HDR)
   663         set(HAVE_ALTIVEC TRUE) # if only HAVE_ALTIVEC_H_HDR is set
   664         list(APPEND EXTRA_CFLAGS "-maltivec")
   665         set(SDL_ALTIVEC_BLITTERS 1)
   666         if(HAVE_ALTIVEC_H_HDR)
   667           set(HAVE_ALTIVEC_H 1)
   668         endif()
   669       endif()
   670     endif()
   671   elseif(MSVC_VERSION GREATER 1500)
   672     # TODO: SDL_cpuinfo.h needs to support the user's configuration wish
   673     # for MSVC - right now it is always activated
   674     if(NOT ARCH_64)
   675       set(HAVE_MMX TRUE)
   676       set(HAVE_3DNOW TRUE)
   677     endif()
   678     set(HAVE_SSE TRUE)
   679     set(HAVE_SSE2 TRUE)
   680     set(HAVE_SSE3 TRUE)
   681     set(SDL_ASSEMBLY_ROUTINES 1)
   682   endif()
   683 # TODO:
   684 #else()
   685 #  if(USE_GCC OR USE_CLANG)
   686 #    list(APPEND EXTRA_CFLAGS "-mno-sse" "-mno-sse2" "-mno-sse3" "-mno-mmx")
   687 #  endif()
   688 endif()
   689 
   690 # TODO: Can't deactivate on FreeBSD? w/o LIBC, SDL_stdinc.h can't define
   691 # anything.
   692 if(LIBC)
   693   if(WINDOWS AND NOT MINGW)
   694     set(HAVE_LIBC TRUE)
   695     foreach(_HEADER stdio.h string.h wchar.h ctype.h math.h limits.h)
   696       string(TOUPPER "HAVE_${_HEADER}" _UPPER)
   697       string(REPLACE "." "_" _HAVE_H ${_UPPER})
   698       set(${_HAVE_H} 1)
   699     endforeach()
   700     set(HAVE_SIGNAL_H 1)
   701     foreach(_FN
   702             malloc calloc realloc free qsort abs memset memcpy memmove memcmp
   703             wcslen wcscmp
   704             strlen _strrev _strupr _strlwr strchr strrchr strstr itoa _ltoa
   705             _ultoa strtol strtoul strtoll strtod atoi atof strcmp strncmp
   706             _stricmp _strnicmp sscanf
   707             acos acosf asin asinf atan atanf atan2 atan2f ceil ceilf
   708             copysign copysignf cos cosf exp expf fabs fabsf floor floorf fmod fmodf
   709             log logf log10 log10f pow powf scalbn scalbnf sin sinf sqrt sqrtf tan tanf)
   710       string(TOUPPER ${_FN} _UPPER)
   711       set(HAVE_${_UPPER} 1)
   712     endforeach()
   713     if(NOT CYGWIN AND NOT MINGW)
   714       set(HAVE_ALLOCA 1)
   715     endif()
   716     set(HAVE_M_PI 1)
   717     add_definitions(-D_USE_MATH_DEFINES) # needed for M_PI
   718     set(STDC_HEADERS 1)
   719   else()
   720     set(HAVE_LIBC TRUE)
   721     check_include_file(sys/types.h HAVE_SYS_TYPES_H)
   722     foreach(_HEADER
   723             stdio.h stdlib.h stddef.h stdarg.h malloc.h memory.h string.h limits.h
   724             strings.h wchar.h inttypes.h stdint.h ctype.h math.h iconv.h signal.h libunwind.h)
   725       string(TOUPPER "HAVE_${_HEADER}" _UPPER)
   726       string(REPLACE "." "_" _HAVE_H ${_UPPER})
   727       check_include_file("${_HEADER}" ${_HAVE_H})
   728     endforeach()
   729 
   730     check_include_files("dlfcn.h;stdint.h;stddef.h;inttypes.h;stdlib.h;strings.h;string.h;float.h" STDC_HEADERS)
   731     check_type_size("size_t" SIZEOF_SIZE_T)
   732     check_symbol_exists(M_PI math.h HAVE_M_PI)
   733     # TODO: refine the mprotect check
   734     check_c_source_compiles("#include <sys/types.h>
   735                              #include <sys/mman.h>
   736                              int main() { }" HAVE_MPROTECT)
   737     foreach(_FN
   738             strtod malloc calloc realloc free getenv setenv putenv unsetenv
   739             qsort abs bcopy memset memcpy memmove memcmp strlen strlcpy strlcat
   740             _strrev _strupr _strlwr strchr strrchr strstr itoa _ltoa
   741             _uitoa _ultoa strtol strtoul _i64toa _ui64toa strtoll strtoull
   742             atoi atof strcmp strncmp _stricmp strcasecmp _strnicmp strncasecmp
   743             vsscanf vsnprintf fopen64 fseeko fseeko64 sigaction setjmp
   744             nanosleep sysconf sysctlbyname getauxval poll _Exit
   745             )
   746       string(TOUPPER ${_FN} _UPPER)
   747       set(_HAVEVAR "HAVE_${_UPPER}")
   748       check_function_exists("${_FN}" ${_HAVEVAR})
   749     endforeach()
   750 
   751     check_library_exists(m pow "" HAVE_LIBM)
   752     if(HAVE_LIBM)
   753       set(CMAKE_REQUIRED_LIBRARIES m)
   754       foreach(_FN
   755               atan atan2 ceil copysign cos cosf fabs floor log pow scalbn sin
   756               sinf sqrt sqrtf tan tanf acos asin)
   757         string(TOUPPER ${_FN} _UPPER)
   758         set(_HAVEVAR "HAVE_${_UPPER}")
   759         check_function_exists("${_FN}" ${_HAVEVAR})
   760       endforeach()
   761       set(CMAKE_REQUIRED_LIBRARIES)
   762       list(APPEND EXTRA_LIBS m)
   763     endif()
   764 
   765     check_library_exists(iconv iconv_open "" HAVE_LIBICONV)
   766     if(HAVE_LIBICONV)
   767       list(APPEND EXTRA_LIBS iconv)
   768       set(HAVE_ICONV 1)
   769     endif()
   770 
   771     if(NOT APPLE)
   772       check_include_file(alloca.h HAVE_ALLOCA_H)
   773       check_function_exists(alloca HAVE_ALLOCA)
   774     else()
   775       set(HAVE_ALLOCA_H 1)
   776       set(HAVE_ALLOCA 1)
   777     endif()
   778 
   779     check_struct_has_member("struct sigaction" "sa_sigaction" "signal.h" HAVE_SA_SIGACTION)
   780   endif()
   781 else()
   782   if(WINDOWS)
   783     set(HAVE_STDARG_H 1)
   784     set(HAVE_STDDEF_H 1)
   785   endif()
   786 endif()
   787 
   788 
   789 # Enable/disable various subsystems of the SDL library
   790 foreach(_SUB ${SDL_SUBSYSTEMS})
   791   string(TOUPPER ${_SUB} _OPT)
   792   if(NOT SDL_${_OPT})
   793     set(SDL_${_OPT}_DISABLED 1)
   794   endif()
   795 endforeach()
   796 if(SDL_JOYSTICK)
   797   file(GLOB JOYSTICK_SOURCES ${SDL2_SOURCE_DIR}/src/joystick/*.c)
   798   set(SOURCE_FILES ${SOURCE_FILES} ${JOYSTICK_SOURCES})
   799 endif()
   800 if(SDL_HAPTIC)
   801   if(NOT SDL_JOYSTICK)
   802     # Haptic requires some private functions from the joystick subsystem.
   803     message_error("SDL_HAPTIC requires SDL_JOYSTICK, which is not enabled")
   804   endif()
   805   file(GLOB HAPTIC_SOURCES ${SDL2_SOURCE_DIR}/src/haptic/*.c)
   806   set(SOURCE_FILES ${SOURCE_FILES} ${HAPTIC_SOURCES})
   807 endif()
   808 if(SDL_SENSOR)
   809   file(GLOB SENSOR_SOURCES ${SDL2_SOURCE_DIR}/src/sensor/*.c)
   810   set(SOURCE_FILES ${SOURCE_FILES} ${SENSOR_SOURCES})
   811 endif()
   812 if(SDL_POWER)
   813   file(GLOB POWER_SOURCES ${SDL2_SOURCE_DIR}/src/power/*.c)
   814   set(SOURCE_FILES ${SOURCE_FILES} ${POWER_SOURCES})
   815 endif()
   816 # TODO: in configure.ac, the test for LOADSO and SDL_DLOPEN is a bit weird:
   817 # if LOADSO is not wanted, SDL_LOADSO_DISABLED is set
   818 # If however on Unix or APPLE dlopen() is detected via CheckDLOPEN(),
   819 # SDL_LOADSO_DISABLED will not be set, regardless of the LOADSO settings
   820 
   821 # General SDL subsystem options, valid for all platforms
   822 if(SDL_AUDIO)
   823   # CheckDummyAudio/CheckDiskAudio - valid for all platforms
   824   if(DUMMYAUDIO)
   825     set(SDL_AUDIO_DRIVER_DUMMY 1)
   826     file(GLOB DUMMYAUDIO_SOURCES ${SDL2_SOURCE_DIR}/src/audio/dummy/*.c)
   827     set(SOURCE_FILES ${SOURCE_FILES} ${DUMMYAUDIO_SOURCES})
   828     set(HAVE_DUMMYAUDIO TRUE)
   829   endif()
   830   if(DISKAUDIO)
   831     set(SDL_AUDIO_DRIVER_DISK 1)
   832     file(GLOB DISKAUDIO_SOURCES ${SDL2_SOURCE_DIR}/src/audio/disk/*.c)
   833     set(SOURCE_FILES ${SOURCE_FILES} ${DISKAUDIO_SOURCES})
   834     set(HAVE_DISKAUDIO TRUE)
   835   endif()
   836 endif()
   837 
   838 if(SDL_DLOPEN)
   839   # Relevant for Unix/Darwin only
   840   if(UNIX OR APPLE)
   841     CheckDLOPEN()
   842   endif()
   843 endif()
   844 
   845 if(SDL_VIDEO)
   846   if(VIDEO_DUMMY)
   847     set(SDL_VIDEO_DRIVER_DUMMY 1)
   848     file(GLOB VIDEO_DUMMY_SOURCES ${SDL2_SOURCE_DIR}/src/video/dummy/*.c)
   849     set(SOURCE_FILES ${SOURCE_FILES} ${VIDEO_DUMMY_SOURCES})
   850     set(HAVE_VIDEO_DUMMY TRUE)
   851     set(HAVE_SDL_VIDEO TRUE)
   852   endif()
   853 endif()
   854 
   855 # Platform-specific options and settings
   856 if(ANDROID)
   857   file(GLOB ANDROID_CORE_SOURCES ${SDL2_SOURCE_DIR}/src/core/android/*.c)
   858   set(SOURCE_FILES ${SOURCE_FILES} ${ANDROID_CORE_SOURCES})
   859 
   860   # SDL_spinlock.c Needs to be compiled in ARM mode.
   861   # There seems to be no better way currently to set the ARM mode.
   862   # see: https://issuetracker.google.com/issues/62264618
   863   # Another option would be to set ARM mode to all compiled files
   864   check_c_compiler_flag(-marm HAVE_ARM_MODE)
   865   if(HAVE_ARM_MODE)
   866     set_source_files_properties(${SDL2_SOURCE_DIR}/src/atomic/SDL_spinlock.c PROPERTIES COMPILE_FLAGS -marm)
   867   endif()
   868 
   869   file(GLOB ANDROID_MAIN_SOURCES ${SDL2_SOURCE_DIR}/src/main/android/*.c)
   870   set(SDLMAIN_SOURCES ${SDLMAIN_SOURCES} ${ANDROID_MAIN_SOURCES})
   871 
   872   if(SDL_AUDIO)
   873     set(SDL_AUDIO_DRIVER_ANDROID 1)
   874     file(GLOB ANDROID_AUDIO_SOURCES ${SDL2_SOURCE_DIR}/src/audio/android/*.c)
   875     set(SOURCE_FILES ${SOURCE_FILES} ${ANDROID_AUDIO_SOURCES})
   876     set(HAVE_SDL_AUDIO TRUE)
   877   endif()
   878   if(SDL_FILESYSTEM)
   879     set(SDL_FILESYSTEM_ANDROID 1)
   880     file(GLOB ANDROID_FILESYSTEM_SOURCES ${SDL2_SOURCE_DIR}/src/filesystem/android/*.c)
   881     set(SOURCE_FILES ${SOURCE_FILES} ${ANDROID_FILESYSTEM_SOURCES})
   882     set(HAVE_SDL_FILESYSTEM TRUE)
   883   endif()
   884   if(SDL_HAPTIC)
   885     set(SDL_HAPTIC_ANDROID 1)
   886     file(GLOB ANDROID_HAPTIC_SOURCES ${SDL2_SOURCE_DIR}/src/haptic/android/*.c)
   887     set(SOURCE_FILES ${SOURCE_FILES} ${ANDROID_HAPTIC_SOURCES})
   888     set(HAVE_SDL_HAPTIC TRUE)
   889   endif()
   890   if(SDL_JOYSTICK)
   891     CheckHIDAPI()
   892     set(SDL_JOYSTICK_ANDROID 1)
   893     file(GLOB ANDROID_JOYSTICK_SOURCES ${SDL2_SOURCE_DIR}/src/joystick/android/*.c ${SDL2_SOURCE_DIR}/src/joystick/steam/*.c)
   894     set(SOURCE_FILES ${SOURCE_FILES} ${ANDROID_JOYSTICK_SOURCES})
   895     set(HAVE_SDL_JOYSTICK TRUE)
   896   endif()
   897   if(SDL_LOADSO)
   898     set(SDL_LOADSO_DLOPEN 1)
   899     file(GLOB LOADSO_SOURCES ${SDL2_SOURCE_DIR}/src/loadso/dlopen/*.c)
   900     set(SOURCE_FILES ${SOURCE_FILES} ${LOADSO_SOURCES})
   901     set(HAVE_SDL_LOADSO TRUE)
   902   endif()
   903   if(SDL_POWER)
   904     set(SDL_POWER_ANDROID 1)
   905     file(GLOB ANDROID_POWER_SOURCES ${SDL2_SOURCE_DIR}/src/power/android/*.c)
   906     set(SOURCE_FILES ${SOURCE_FILES} ${ANDROID_POWER_SOURCES})
   907     set(HAVE_SDL_POWER TRUE)
   908   endif()
   909   if(SDL_TIMERS)
   910     set(SDL_TIMER_UNIX 1)
   911     file(GLOB TIMER_SOURCES ${SDL2_SOURCE_DIR}/src/timer/unix/*.c)
   912     set(SOURCE_FILES ${SOURCE_FILES} ${TIMER_SOURCES})
   913     set(HAVE_SDL_TIMERS TRUE)
   914   endif()
   915   if(SDL_SENSOR)
   916     set(SDL_SENSOR_ANDROID 1)
   917     set(HAVE_SDL_SENSORS TRUE)
   918     file(GLOB ANDROID_SENSOR_SOURCES ${SDL2_SOURCE_DIR}/src/sensor/android/*.c)
   919     set(SOURCE_FILES ${SOURCE_FILES} ${ANDROID_SENSOR_SOURCES})
   920   endif()
   921   if(SDL_VIDEO)
   922     set(SDL_VIDEO_DRIVER_ANDROID 1)
   923     file(GLOB ANDROID_VIDEO_SOURCES ${SDL2_SOURCE_DIR}/src/video/android/*.c)
   924     set(SOURCE_FILES ${SOURCE_FILES} ${ANDROID_VIDEO_SOURCES})
   925     set(HAVE_SDL_VIDEO TRUE)
   926 
   927     # Core stuff
   928     find_library(ANDROID_DL_LIBRARY dl)
   929     find_library(ANDROID_LOG_LIBRARY log)
   930     find_library(ANDROID_LIBRARY_LIBRARY android)
   931     list(APPEND EXTRA_LIBS ${ANDROID_DL_LIBRARY} ${ANDROID_LOG_LIBRARY} ${ANDROID_LIBRARY_LIBRARY})
   932     add_definitions(-DGL_GLEXT_PROTOTYPES)
   933 
   934     #enable gles
   935     if(VIDEO_OPENGLES)
   936       set(SDL_VIDEO_OPENGL_EGL 1)
   937       set(HAVE_VIDEO_OPENGLES TRUE)
   938       set(SDL_VIDEO_OPENGL_ES 1)
   939       set(SDL_VIDEO_RENDER_OGL_ES 1)
   940       set(SDL_VIDEO_OPENGL_ES2 1)
   941       set(SDL_VIDEO_RENDER_OGL_ES2 1)
   942 
   943       find_library(OpenGLES1_LIBRARY GLESv1_CM)
   944       find_library(OpenGLES2_LIBRARY GLESv2)
   945       list(APPEND EXTRA_LIBS ${OpenGLES1_LIBRARY} ${OpenGLES2_LIBRARY})
   946     endif()
   947 
   948     CHECK_C_SOURCE_COMPILES("
   949     #if defined(__ARM_ARCH) && __ARM_ARCH < 7
   950     #error Vulkan doesn't work on this configuration
   951     #endif
   952     int main()
   953     {
   954         return 0;
   955     }
   956     " VULKAN_PASSED_ANDROID_CHECKS)
   957     if(NOT VULKAN_PASSED_ANDROID_CHECKS)
   958       set(VIDEO_VULKAN OFF)
   959       message(STATUS "Vulkan doesn't work on this configuration")
   960     endif()
   961   endif()
   962 
   963   CheckPTHREAD()
   964 
   965 elseif(EMSCRIPTEN)
   966   # Hide noisy warnings that intend to aid mostly during initial stages of porting a new
   967   # project. Uncomment at will for verbose cross-compiling -I/../ path info.
   968   add_definitions(-Wno-warn-absolute-paths)
   969   if(SDL_AUDIO)
   970     set(SDL_AUDIO_DRIVER_EMSCRIPTEN 1)
   971     file(GLOB EM_AUDIO_SOURCES ${SDL2_SOURCE_DIR}/src/audio/emscripten/*.c)
   972     set(SOURCE_FILES ${SOURCE_FILES} ${EM_AUDIO_SOURCES})
   973     set(HAVE_SDL_AUDIO TRUE)
   974   endif()
   975   if(SDL_FILESYSTEM)
   976     set(SDL_FILESYSTEM_EMSCRIPTEN 1)
   977     file(GLOB EM_FILESYSTEM_SOURCES ${SDL2_SOURCE_DIR}/src/filesystem/emscripten/*.c)
   978     set(SOURCE_FILES ${SOURCE_FILES} ${EM_FILESYSTEM_SOURCES})
   979     set(HAVE_SDL_FILESYSTEM TRUE)
   980   endif()
   981   if(SDL_JOYSTICK)
   982     set(SDL_JOYSTICK_EMSCRIPTEN 1)
   983     file(GLOB EM_JOYSTICK_SOURCES ${SDL2_SOURCE_DIR}/src/joystick/emscripten/*.c)
   984     set(SOURCE_FILES ${SOURCE_FILES} ${EM_JOYSTICK_SOURCES})
   985     set(HAVE_SDL_JOYSTICK TRUE)
   986   endif()
   987   if(SDL_POWER)
   988     set(SDL_POWER_EMSCRIPTEN 1)
   989     file(GLOB EM_POWER_SOURCES ${SDL2_SOURCE_DIR}/src/power/emscripten/*.c)
   990     set(SOURCE_FILES ${SOURCE_FILES} ${EM_POWER_SOURCES})
   991     set(HAVE_SDL_POWER TRUE)
   992   endif()
   993   if(SDL_TIMERS)
   994     set(SDL_TIMER_UNIX 1)
   995     file(GLOB TIMER_SOURCES ${SDL2_SOURCE_DIR}/src/timer/unix/*.c)
   996     set(SOURCE_FILES ${SOURCE_FILES} ${TIMER_SOURCES})
   997     set(HAVE_SDL_TIMERS TRUE)
   998 
   999     if(CLOCK_GETTIME)
  1000       set(HAVE_CLOCK_GETTIME 1)
  1001     endif()
  1002   endif()
  1003   if(SDL_VIDEO)
  1004     set(SDL_VIDEO_DRIVER_EMSCRIPTEN 1)
  1005     file(GLOB EM_VIDEO_SOURCES ${SDL2_SOURCE_DIR}/src/video/emscripten/*.c)
  1006     set(SOURCE_FILES ${SOURCE_FILES} ${EM_VIDEO_SOURCES})
  1007     set(HAVE_SDL_VIDEO TRUE)
  1008 
  1009     #enable gles
  1010     if(VIDEO_OPENGLES)
  1011       set(SDL_VIDEO_OPENGL_EGL 1)
  1012       set(HAVE_VIDEO_OPENGLES TRUE)
  1013       set(SDL_VIDEO_OPENGL_ES2 1)
  1014       set(SDL_VIDEO_RENDER_OGL_ES2 1)
  1015     endif()
  1016   endif()
  1017 
  1018 elseif(UNIX AND NOT APPLE AND NOT ANDROID)
  1019   if(SDL_AUDIO)
  1020     if(SYSV5 OR SOLARIS OR HPUX)
  1021         set(SDL_AUDIO_DRIVER_SUNAUDIO 1)
  1022         file(GLOB SUN_AUDIO_SOURCES ${SDL2_SOURCE_DIR}/src/audio/sun/*.c)
  1023         set(SOURCE_FILES ${SOURCE_FILES} ${SUN_AUDIO_SOURCES})
  1024         set(HAVE_SDL_AUDIO TRUE)
  1025     elseif(NETBSD)
  1026         set(SDL_AUDIO_DRIVER_NETBSD 1)
  1027         file(GLOB NETBSD_AUDIO_SOURCES ${SDL2_SOURCE_DIR}/src/audio/netbsd/*.c)
  1028         set(SOURCE_FILES ${SOURCE_FILES} ${NETBSD_AUDIO_SOURCES})
  1029         set(HAVE_SDL_AUDIO TRUE)
  1030     elseif(AIX)
  1031         set(SDL_AUDIO_DRIVER_PAUDIO 1)
  1032         file(GLOB AIX_AUDIO_SOURCES ${SDL2_SOURCE_DIR}/src/audio/paudio/*.c)
  1033         set(SOURCE_FILES ${SOURCE_FILES} ${AIX_AUDIO_SOURCES})
  1034         set(HAVE_SDL_AUDIO TRUE)
  1035     endif()
  1036     CheckOSS()
  1037     CheckALSA()
  1038     CheckJACK()
  1039     CheckPulseAudio()
  1040     CheckESD()
  1041     CheckARTS()
  1042     CheckNAS()
  1043     CheckSNDIO()
  1044     CheckFusionSound()
  1045     CheckLibSampleRate()
  1046   endif()
  1047 
  1048   if(SDL_VIDEO)
  1049     # Need to check for Raspberry PI first and add platform specific compiler flags, otherwise the test for GLES fails!
  1050     CheckRPI()
  1051     CheckX11()
  1052     CheckDirectFB()
  1053     CheckOpenGLX11()
  1054     CheckOpenGLESX11()
  1055     CheckWayland()
  1056     CheckVivante()
  1057     CheckKMSDRM()
  1058   endif()
  1059 
  1060   if(UNIX)
  1061     file(GLOB CORE_UNIX_SOURCES ${SDL2_SOURCE_DIR}/src/core/unix/*.c)
  1062     set(SOURCE_FILES ${SOURCE_FILES} ${CORE_UNIX_SOURCES})
  1063   endif()
  1064 
  1065   if(LINUX)
  1066     check_c_source_compiles("
  1067         #include <linux/input.h>
  1068         #ifndef EVIOCGNAME
  1069         #error EVIOCGNAME() ioctl not available
  1070         #endif
  1071         int main(int argc, char** argv) {}" HAVE_INPUT_EVENTS)
  1072 
  1073     check_c_source_compiles("
  1074         #include <linux/kd.h>
  1075         #include <linux/keyboard.h>
  1076 
  1077         int main(int argc, char **argv)
  1078         {
  1079             struct kbentry kbe;
  1080             kbe.kb_table = KG_CTRL;
  1081             ioctl(0, KDGKBENT, &kbe);
  1082         }" HAVE_INPUT_KD)
  1083 
  1084     file(GLOB CORE_LINUX_SOURCES ${SDL2_SOURCE_DIR}/src/core/linux/*.c)
  1085     set(SOURCE_FILES ${SOURCE_FILES} ${CORE_LINUX_SOURCES})
  1086 
  1087     if(HAVE_INPUT_EVENTS)
  1088       set(SDL_INPUT_LINUXEV 1)
  1089     endif()
  1090 
  1091     if(SDL_HAPTIC AND HAVE_INPUT_EVENTS)
  1092       set(SDL_HAPTIC_LINUX 1)
  1093       file(GLOB HAPTIC_SOURCES ${SDL2_SOURCE_DIR}/src/haptic/linux/*.c)
  1094       set(SOURCE_FILES ${SOURCE_FILES} ${HAPTIC_SOURCES})
  1095       set(HAVE_SDL_HAPTIC TRUE)
  1096     endif()
  1097 
  1098     if(HAVE_INPUT_KD)
  1099       set(SDL_INPUT_LINUXKD 1)
  1100     endif()
  1101 
  1102     check_include_file("libudev.h" HAVE_LIBUDEV_H)
  1103 
  1104     if(PKG_CONFIG_FOUND)
  1105       pkg_search_module(DBUS dbus-1 dbus)
  1106       if(DBUS_FOUND)
  1107         set(HAVE_DBUS_DBUS_H TRUE)
  1108         include_directories(${DBUS_INCLUDE_DIRS})
  1109         list(APPEND EXTRA_LIBS ${DBUS_LIBRARIES})
  1110       endif()
  1111 
  1112       pkg_search_module(IBUS ibus-1.0 ibus)
  1113       if(IBUS_FOUND)
  1114         set(HAVE_IBUS_IBUS_H TRUE)
  1115         include_directories(${IBUS_INCLUDE_DIRS})
  1116         list(APPEND EXTRA_LIBS ${IBUS_LIBRARIES})
  1117       endif()
  1118       if(HAVE_LIBUNWIND_H)
  1119         # We've already found the header, so REQUIRE the lib to be present
  1120         pkg_search_module(UNWIND REQUIRED libunwind)
  1121         pkg_search_module(UNWIND_GENERIC REQUIRED libunwind-generic)
  1122         list(APPEND EXTRA_LIBS ${UNWIND_LIBRARIES} ${UNWIND_GENERIC_LIBRARIES})
  1123       endif()
  1124     endif()
  1125 
  1126     check_include_file("fcitx/frontend.h" HAVE_FCITX_FRONTEND_H)
  1127   endif()
  1128 
  1129   if(INPUT_TSLIB)
  1130     check_c_source_compiles("
  1131         #include \"tslib.h\"
  1132         int main(int argc, char** argv) { }" HAVE_INPUT_TSLIB)
  1133     if(HAVE_INPUT_TSLIB)
  1134       set(SDL_INPUT_TSLIB 1)
  1135       list(APPEND EXTRA_LIBS ts)
  1136     endif()
  1137   endif()
  1138 
  1139   if(SDL_JOYSTICK)
  1140     if(FREEBSD OR NETBSD OR OPENBSD OR BSDI)
  1141       CheckUSBHID()
  1142     endif()
  1143     CheckHIDAPI()
  1144     if(LINUX AND NOT ANDROID)
  1145       set(SDL_JOYSTICK_LINUX 1)
  1146       file(GLOB JOYSTICK_SOURCES ${SDL2_SOURCE_DIR}/src/joystick/linux/*.c ${SDL2_SOURCE_DIR}/src/joystick/steam/*.c)
  1147       set(SOURCE_FILES ${SOURCE_FILES} ${JOYSTICK_SOURCES})
  1148       set(HAVE_SDL_JOYSTICK TRUE)
  1149     endif()
  1150   endif()
  1151 
  1152   CheckPTHREAD()
  1153 
  1154   if(CLOCK_GETTIME)
  1155     check_library_exists(rt clock_gettime "" FOUND_CLOCK_GETTIME)
  1156     if(FOUND_CLOCK_GETTIME)
  1157       list(APPEND EXTRA_LIBS rt)
  1158       set(HAVE_CLOCK_GETTIME 1)
  1159     else()
  1160       check_library_exists(c clock_gettime "" FOUND_CLOCK_GETTIME)
  1161       if(FOUND_CLOCK_GETTIME)
  1162         set(HAVE_CLOCK_GETTIME 1)
  1163       endif()
  1164     endif()
  1165   endif()
  1166 
  1167   check_include_file(linux/version.h HAVE_LINUX_VERSION_H)
  1168   if(HAVE_LINUX_VERSION_H)
  1169     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -DHAVE_LINUX_VERSION_H")
  1170   endif()
  1171 
  1172   if(SDL_POWER)
  1173     if(LINUX)
  1174       set(SDL_POWER_LINUX 1)
  1175       file(GLOB POWER_SOURCES ${SDL2_SOURCE_DIR}/src/power/linux/*.c)
  1176       set(SOURCE_FILES ${SOURCE_FILES} ${POWER_SOURCES})
  1177       set(HAVE_SDL_POWER TRUE)
  1178     endif()
  1179   endif()
  1180 
  1181   if(SDL_FILESYSTEM)
  1182     set(SDL_FILESYSTEM_UNIX 1)
  1183     file(GLOB FILESYSTEM_SOURCES ${SDL2_SOURCE_DIR}/src/filesystem/unix/*.c)
  1184     set(SOURCE_FILES ${SOURCE_FILES} ${FILESYSTEM_SOURCES})
  1185     set(HAVE_SDL_FILESYSTEM TRUE)
  1186   endif()
  1187 
  1188   if(SDL_TIMERS)
  1189     set(SDL_TIMER_UNIX 1)
  1190     file(GLOB TIMER_SOURCES ${SDL2_SOURCE_DIR}/src/timer/unix/*.c)
  1191     set(SOURCE_FILES ${SOURCE_FILES} ${TIMER_SOURCES})
  1192     set(HAVE_SDL_TIMERS TRUE)
  1193   endif()
  1194 
  1195   if(RPATH)
  1196     set(SDL_RLD_FLAGS "")
  1197     if(BSDI OR FREEBSD OR LINUX OR NETBSD)
  1198       set(CMAKE_REQUIRED_FLAGS "-Wl,--enable-new-dtags")
  1199       check_c_compiler_flag("" HAVE_ENABLE_NEW_DTAGS)
  1200       set(CMAKE_REQUIRED_FLAGS ${ORIG_CMAKE_REQUIRED_FLAGS})
  1201       if(HAVE_ENABLE_NEW_DTAGS)
  1202         set(SDL_RLD_FLAGS "-Wl,-rpath,\${libdir} -Wl,--enable-new-dtags")
  1203       else()
  1204         set(SDL_RLD_FLAGS "-Wl,-rpath,\${libdir}")
  1205       endif()
  1206     elseif(SOLARIS)
  1207       set(SDL_RLD_FLAGS "-R\${libdir}")
  1208     endif()
  1209     set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
  1210     set(HAVE_RPATH TRUE)
  1211   endif()
  1212 
  1213 elseif(WINDOWS)
  1214   find_program(WINDRES windres)
  1215 
  1216   check_c_source_compiles("
  1217     #include <windows.h>
  1218     int main(int argc, char **argv) { }" HAVE_WIN32_CC)
  1219 
  1220   file(GLOB CORE_SOURCES ${SDL2_SOURCE_DIR}/src/core/windows/*.c)
  1221   set(SOURCE_FILES ${SOURCE_FILES} ${CORE_SOURCES})
  1222 
  1223   if(MSVC)
  1224     # Prevent codegen that would use the VC runtime libraries.
  1225     set_property(DIRECTORY . APPEND PROPERTY COMPILE_OPTIONS "/GS-")
  1226     if(NOT ARCH_64)
  1227       set_property(DIRECTORY . APPEND PROPERTY COMPILE_OPTIONS "/arch:SSE")
  1228     endif()
  1229   endif()
  1230 
  1231   # Check for DirectX
  1232   if(DIRECTX)
  1233     if(DEFINED MSVC_VERSION AND NOT ${MSVC_VERSION} LESS 1700)
  1234         set(USE_WINSDK_DIRECTX TRUE)
  1235     endif()
  1236     if(NOT CMAKE_COMPILER_IS_MINGW AND NOT USE_WINSDK_DIRECTX)
  1237       if("$ENV{DXSDK_DIR}" STREQUAL "")
  1238         message_error("DIRECTX requires the \$DXSDK_DIR environment variable to be set")
  1239       endif()
  1240       set(CMAKE_REQUIRED_FLAGS "/I\"$ENV{DXSDK_DIR}\\Include\"")
  1241     endif()
  1242 
  1243     if(HAVE_WIN32_CC)
  1244       # xinput.h may need windows.h, but doesn't include it itself.
  1245       check_c_source_compiles("
  1246         #include <windows.h>
  1247         #include <xinput.h>
  1248         int main(int argc, char **argv) { }" HAVE_XINPUT_H)
  1249       check_c_source_compiles("
  1250         #include <windows.h>
  1251         #include <xinput.h>
  1252         XINPUT_GAMEPAD_EX x1;
  1253         int main(int argc, char **argv) { }" HAVE_XINPUT_GAMEPAD_EX)
  1254       check_c_source_compiles("
  1255         #include <windows.h>
  1256         #include <xinput.h>
  1257         XINPUT_STATE_EX s1;
  1258         int main(int argc, char **argv) { }" HAVE_XINPUT_STATE_EX)
  1259     else()
  1260       check_include_file(xinput.h HAVE_XINPUT_H)
  1261     endif()
  1262 
  1263     check_include_file(d3d9.h HAVE_D3D_H)
  1264     check_include_file(d3d11_1.h HAVE_D3D11_H)
  1265     check_include_file(ddraw.h HAVE_DDRAW_H)
  1266     check_include_file(dsound.h HAVE_DSOUND_H)
  1267     check_include_file(dinput.h HAVE_DINPUT_H)
  1268     check_include_file(dxgi.h HAVE_DXGI_H)
  1269     if(HAVE_D3D_H OR HAVE_D3D11_H OR HAVE_DDRAW_H OR HAVE_DSOUND_H OR HAVE_DINPUT_H)
  1270       set(HAVE_DIRECTX TRUE)
  1271       if(NOT CMAKE_COMPILER_IS_MINGW AND NOT USE_WINSDK_DIRECTX)
  1272       # TODO: change $ENV{DXSDL_DIR} to get the path from the include checks
  1273         link_directories($ENV{DXSDK_DIR}\\lib\\${PROCESSOR_ARCH})
  1274         include_directories($ENV{DXSDK_DIR}\\Include)
  1275       endif()
  1276     endif()
  1277     set(CMAKE_REQUIRED_FLAGS ${ORIG_CMAKE_REQUIRED_FLAGS})
  1278   endif()
  1279 
  1280   # headers needed elsewhere ...
  1281   check_include_file(mmdeviceapi.h HAVE_MMDEVICEAPI_H)
  1282   check_include_file(audioclient.h HAVE_AUDIOCLIENT_H)
  1283   check_include_file(endpointvolume.h HAVE_ENDPOINTVOLUME_H)
  1284 
  1285   if(SDL_AUDIO)
  1286     set(SDL_AUDIO_DRIVER_WINMM 1)
  1287     file(GLOB WINMM_AUDIO_SOURCES ${SDL2_SOURCE_DIR}/src/audio/winmm/*.c)
  1288     set(SOURCE_FILES ${SOURCE_FILES} ${WINMM_AUDIO_SOURCES})
  1289     set(HAVE_SDL_AUDIO TRUE)
  1290 
  1291     if(HAVE_DSOUND_H)
  1292       set(SDL_AUDIO_DRIVER_DSOUND 1)
  1293       file(GLOB DSOUND_AUDIO_SOURCES ${SDL2_SOURCE_DIR}/src/audio/directsound/*.c)
  1294       set(SOURCE_FILES ${SOURCE_FILES} ${DSOUND_AUDIO_SOURCES})
  1295     endif()
  1296 
  1297     if(WASAPI AND HAVE_AUDIOCLIENT_H AND HAVE_MMDEVICEAPI_H)
  1298       set(SDL_AUDIO_DRIVER_WASAPI 1)
  1299       file(GLOB WASAPI_AUDIO_SOURCES ${SDL2_SOURCE_DIR}/src/audio/wasapi/*.c)
  1300       set(SOURCE_FILES ${SOURCE_FILES} ${WASAPI_AUDIO_SOURCES})
  1301     endif()
  1302   endif()
  1303 
  1304   if(SDL_VIDEO)
  1305     # requires SDL_LOADSO on Windows (IME, DX, etc.)
  1306     if(NOT SDL_LOADSO)
  1307       message_error("SDL_VIDEO requires SDL_LOADSO, which is not enabled")
  1308     endif()
  1309     set(SDL_VIDEO_DRIVER_WINDOWS 1)
  1310     file(GLOB WIN_VIDEO_SOURCES ${SDL2_SOURCE_DIR}/src/video/windows/*.c)
  1311     set(SOURCE_FILES ${SOURCE_FILES} ${WIN_VIDEO_SOURCES})
  1312 
  1313     if(RENDER_D3D AND HAVE_D3D_H)
  1314       set(SDL_VIDEO_RENDER_D3D 1)
  1315       set(HAVE_RENDER_D3D TRUE)
  1316     endif()
  1317     if(RENDER_D3D AND HAVE_D3D11_H)
  1318       set(SDL_VIDEO_RENDER_D3D11 1)
  1319       set(HAVE_RENDER_D3D TRUE)
  1320     endif()
  1321     set(HAVE_SDL_VIDEO TRUE)
  1322   endif()
  1323 
  1324   if(SDL_THREADS)
  1325     set(SDL_THREAD_WINDOWS 1)
  1326     set(SOURCE_FILES ${SOURCE_FILES}
  1327       ${SDL2_SOURCE_DIR}/src/thread/windows/SDL_sysmutex.c
  1328       ${SDL2_SOURCE_DIR}/src/thread/windows/SDL_syssem.c
  1329       ${SDL2_SOURCE_DIR}/src/thread/windows/SDL_systhread.c
  1330       ${SDL2_SOURCE_DIR}/src/thread/windows/SDL_systls.c
  1331       ${SDL2_SOURCE_DIR}/src/thread/generic/SDL_syscond.c)
  1332     set(HAVE_SDL_THREADS TRUE)
  1333   endif()
  1334 
  1335   if(SDL_POWER)
  1336     set(SDL_POWER_WINDOWS 1)
  1337     set(SOURCE_FILES ${SOURCE_FILES} ${SDL2_SOURCE_DIR}/src/power/windows/SDL_syspower.c)
  1338     set(HAVE_SDL_POWER TRUE)
  1339   endif()
  1340 
  1341   if(SDL_FILESYSTEM)
  1342     set(SDL_FILESYSTEM_WINDOWS 1)
  1343     file(GLOB FILESYSTEM_SOURCES ${SDL2_SOURCE_DIR}/src/filesystem/windows/*.c)
  1344     set(SOURCE_FILES ${SOURCE_FILES} ${FILESYSTEM_SOURCES})
  1345     set(HAVE_SDL_FILESYSTEM TRUE)
  1346   endif()
  1347 
  1348   # Libraries for Win32 native and MinGW
  1349   list(APPEND EXTRA_LIBS user32 gdi32 winmm imm32 ole32 oleaut32 version uuid advapi32 setupapi shell32)
  1350 
  1351   # TODO: in configure.ac the check for timers is set on
  1352   # cygwin | mingw32* - does this include mingw32CE?
  1353   if(SDL_TIMERS)
  1354     set(SDL_TIMER_WINDOWS 1)
  1355     file(GLOB TIMER_SOURCES ${SDL2_SOURCE_DIR}/src/timer/windows/*.c)
  1356     set(SOURCE_FILES ${SOURCE_FILES} ${TIMER_SOURCES})
  1357     set(HAVE_SDL_TIMERS TRUE)
  1358   endif()
  1359 
  1360   if(SDL_LOADSO)
  1361     set(SDL_LOADSO_WINDOWS 1)
  1362     file(GLOB LOADSO_SOURCES ${SDL2_SOURCE_DIR}/src/loadso/windows/*.c)
  1363     set(SOURCE_FILES ${SOURCE_FILES} ${LOADSO_SOURCES})
  1364     set(HAVE_SDL_LOADSO TRUE)
  1365   endif()
  1366 
  1367   file(GLOB CORE_SOURCES ${SDL2_SOURCE_DIR}/src/core/windows/*.c)
  1368   set(SOURCE_FILES ${SOURCE_FILES} ${CORE_SOURCES})
  1369 
  1370   if(SDL_VIDEO)
  1371     if(VIDEO_OPENGL)
  1372       set(SDL_VIDEO_OPENGL 1)
  1373       set(SDL_VIDEO_OPENGL_WGL 1)
  1374       set(SDL_VIDEO_RENDER_OGL 1)
  1375       set(HAVE_VIDEO_OPENGL TRUE)
  1376     endif()
  1377 
  1378     if(VIDEO_OPENGLES)
  1379       set(SDL_VIDEO_OPENGL_EGL 1)
  1380       set(SDL_VIDEO_OPENGL_ES2 1)
  1381       set(SDL_VIDEO_RENDER_OGL_ES2 1)
  1382       set(HAVE_VIDEO_OPENGLES TRUE)
  1383     endif()
  1384   endif()
  1385 
  1386   if(SDL_JOYSTICK)
  1387     CheckHIDAPI()
  1388     # TODO: Remove this hid.c block when SDL_hidapi.c is supported on Windows!
  1389     if(HAVE_HIDAPI)
  1390       set(SOURCE_FILES ${SOURCE_FILES} ${SDL2_SOURCE_DIR}/src/hidapi/windows/hid.c)
  1391     endif()
  1392     file(GLOB JOYSTICK_SOURCES ${SDL2_SOURCE_DIR}/src/joystick/windows/*.c)
  1393     set(SOURCE_FILES ${SOURCE_FILES} ${JOYSTICK_SOURCES})
  1394     if(HAVE_DINPUT_H)
  1395       set(SDL_JOYSTICK_DINPUT 1)
  1396       list(APPEND EXTRA_LIBS dinput8)
  1397       if(CMAKE_COMPILER_IS_MINGW)
  1398         list(APPEND EXTRA_LIBS dxerr8)
  1399       elseif (NOT USE_WINSDK_DIRECTX)
  1400         list(APPEND EXTRA_LIBS dxerr)
  1401       endif()
  1402     endif()
  1403     if(HAVE_XINPUT_H)
  1404       set(SDL_JOYSTICK_XINPUT 1)
  1405     endif()
  1406     if(NOT HAVE_DINPUT_H AND NOT HAVE_XINPUT_H)
  1407       set(SDL_JOYSTICK_WINMM 1)
  1408     endif()
  1409     set(HAVE_SDL_JOYSTICK TRUE)
  1410 
  1411     if(SDL_HAPTIC)
  1412       if(HAVE_DINPUT_H OR HAVE_XINPUT_H)
  1413         file(GLOB HAPTIC_SOURCES ${SDL2_SOURCE_DIR}/src/haptic/windows/*.c)
  1414         if(HAVE_DINPUT_H)
  1415           set(SDL_HAPTIC_DINPUT 1)
  1416         endif()
  1417         if(HAVE_XINPUT_H)
  1418           set(SDL_HAPTIC_XINPUT 1)
  1419         endif()
  1420       else()
  1421         file(GLOB HAPTIC_SOURCES ${SDL2_SOURCE_DIR}/src/haptic/dummy/*.c)
  1422         set(SDL_HAPTIC_DUMMY 1)
  1423       endif()
  1424       set(SOURCE_FILES ${SOURCE_FILES} ${HAPTIC_SOURCES})
  1425       set(HAVE_SDL_HAPTIC TRUE)
  1426     endif()
  1427   endif()
  1428 
  1429   file(GLOB VERSION_SOURCES ${SDL2_SOURCE_DIR}/src/main/windows/*.rc)
  1430   file(GLOB SDLMAIN_SOURCES ${SDL2_SOURCE_DIR}/src/main/windows/*.c)
  1431   if(MINGW OR CYGWIN)
  1432     list(APPEND EXTRA_LIBS mingw32)
  1433     list(APPEND EXTRA_LDFLAGS "-mwindows")
  1434     set(SDL_CFLAGS "${SDL_CFLAGS} -Dmain=SDL_main")
  1435     list(APPEND SDL_LIBS "-lmingw32" "-lSDL2main" "-mwindows")
  1436   endif()
  1437 
  1438 elseif(APPLE)
  1439   # TODO: rework this all for proper MacOS X, iOS and Darwin support
  1440 
  1441   # We always need these libs on macOS at the moment.
  1442   # !!! FIXME: we need Carbon for some very old API calls in
  1443   # !!! FIXME:  src/video/cocoa/SDL_cocoakeyboard.c, but we should figure out
  1444   # !!! FIXME:  how to dump those.
  1445   if(NOT IOS)
  1446     set(SDL_FRAMEWORK_COCOA 1)
  1447     set(SDL_FRAMEWORK_CARBON 1)
  1448   endif()
  1449 
  1450   # Requires the darwin file implementation
  1451   if(SDL_FILE)
  1452     file(GLOB EXTRA_SOURCES ${SDL2_SOURCE_DIR}/src/file/cocoa/*.m)
  1453     set(SOURCE_FILES ${EXTRA_SOURCES} ${SOURCE_FILES})
  1454     # !!! FIXME: modern CMake doesn't need "LANGUAGE C" for Objective-C.
  1455     set_source_files_properties(${EXTRA_SOURCES} PROPERTIES LANGUAGE C)
  1456     set(HAVE_SDL_FILE TRUE)
  1457     # !!! FIXME: why is COREVIDEO inside this if() block?
  1458     set(SDL_FRAMEWORK_COREVIDEO 1)
  1459   else()
  1460     message_error("SDL_FILE must be enabled to build on MacOS X")
  1461   endif()
  1462 
  1463   if(SDL_AUDIO)
  1464     set(SDL_AUDIO_DRIVER_COREAUDIO 1)
  1465     file(GLOB AUDIO_SOURCES ${SDL2_SOURCE_DIR}/src/audio/coreaudio/*.m)
  1466     # !!! FIXME: modern CMake doesn't need "LANGUAGE C" for Objective-C.
  1467     set_source_files_properties(${AUDIO_SOURCES} PROPERTIES LANGUAGE C)
  1468     set(SOURCE_FILES ${SOURCE_FILES} ${AUDIO_SOURCES})
  1469     set(HAVE_SDL_AUDIO TRUE)
  1470     set(SDL_FRAMEWORK_COREAUDIO 1)
  1471     set(SDL_FRAMEWORK_AUDIOTOOLBOX 1)
  1472   endif()
  1473 
  1474   if(SDL_JOYSTICK)
  1475     CheckHIDAPI()
  1476     if(HAVE_HIDAPI)
  1477       if(IOS)
  1478         set(SOURCE_FILES ${SOURCE_FILES} ${SDL2_SOURCE_DIR}/src/hidapi/ios/hid.m)
  1479       endif()
  1480     endif()
  1481     set(SDL_JOYSTICK_IOKIT 1)
  1482     if (IOS)
  1483       file(GLOB JOYSTICK_SOURCES ${SDL2_SOURCE_DIR}/src/joystick/iphoneos/*.m ${SDL2_SOURCE_DIR}/src/joystick/steam/*.c)
  1484     else()
  1485       file(GLOB JOYSTICK_SOURCES ${SDL2_SOURCE_DIR}/src/joystick/darwin/*.c)
  1486     endif()
  1487     set(SOURCE_FILES ${SOURCE_FILES} ${JOYSTICK_SOURCES})
  1488     set(HAVE_SDL_JOYSTICK TRUE)
  1489     set(SDL_FRAMEWORK_IOKIT 1)
  1490     set(SDL_FRAMEWORK_FF 1)
  1491   endif()
  1492 
  1493   if(SDL_HAPTIC)
  1494     set(SDL_HAPTIC_IOKIT 1)
  1495     if (IOS)
  1496       file(GLOB HAPTIC_SOURCES ${SDL2_SOURCE_DIR}/src/haptic/dummy/*.c)
  1497       set(SDL_HAPTIC_DUMMY 1)
  1498     else()
  1499       file(GLOB HAPTIC_SOURCES ${SDL2_SOURCE_DIR}/src/haptic/darwin/*.c)
  1500     endif()
  1501     set(SOURCE_FILES ${SOURCE_FILES} ${HAPTIC_SOURCES})
  1502     set(HAVE_SDL_HAPTIC TRUE)
  1503     set(SDL_FRAMEWORK_IOKIT 1)
  1504     set(SDL_FRAMEWORK_FF 1)
  1505     if(NOT SDL_JOYSTICK)
  1506       message(FATAL_ERROR "SDL_HAPTIC requires SDL_JOYSTICK to be enabled")
  1507     endif()
  1508   endif()
  1509 
  1510   if(SDL_POWER)
  1511     set(SDL_POWER_MACOSX 1)
  1512     if (IOS)
  1513       file(GLOB POWER_SOURCES ${SDL2_SOURCE_DIR}/src/power/uikit/*.m)
  1514     else()
  1515       file(GLOB POWER_SOURCES ${SDL2_SOURCE_DIR}/src/power/macosx/*.c)
  1516     endif()
  1517     set(SOURCE_FILES ${SOURCE_FILES} ${POWER_SOURCES})
  1518     set(HAVE_SDL_POWER TRUE)
  1519     set(SDL_FRAMEWORK_IOKIT 1)
  1520   endif()
  1521 
  1522   if(SDL_TIMERS)
  1523     set(SDL_TIMER_UNIX 1)
  1524     file(GLOB TIMER_SOURCES ${SDL2_SOURCE_DIR}/src/timer/unix/*.c)
  1525     set(SOURCE_FILES ${SOURCE_FILES} ${TIMER_SOURCES})
  1526     set(HAVE_SDL_TIMERS TRUE)
  1527   endif(SDL_TIMERS)
  1528 
  1529   if(SDL_FILESYSTEM)
  1530     set(SDL_FILESYSTEM_COCOA 1)
  1531     file(GLOB FILESYSTEM_SOURCES ${SDL2_SOURCE_DIR}/src/filesystem/cocoa/*.m)
  1532     # !!! FIXME: modern CMake doesn't need "LANGUAGE C" for Objective-C.
  1533     set_source_files_properties(${FILESYSTEM_SOURCES} PROPERTIES LANGUAGE C)
  1534     set(SOURCE_FILES ${SOURCE_FILES} ${FILESYSTEM_SOURCES})
  1535     set(HAVE_SDL_FILESYSTEM TRUE)
  1536   endif()
  1537 
  1538   # iOS hack needed - http://code.google.com/p/ios-cmake/ ?
  1539   if(SDL_VIDEO)
  1540     if (IOS)
  1541       set(SDL_VIDEO_DRIVER_UIKIT 1)
  1542       file(GLOB UIKITVIDEO_SOURCES ${SDL2_SOURCE_DIR}/src/video/uikit/*.m)
  1543       set(SOURCE_FILES ${SOURCE_FILES} ${UIKITVIDEO_SOURCES})
  1544     else()
  1545       CheckCOCOA()
  1546       if(VIDEO_OPENGL)
  1547         set(SDL_VIDEO_OPENGL 1)
  1548         set(SDL_VIDEO_OPENGL_CGL 1)
  1549         set(SDL_VIDEO_RENDER_OGL 1)
  1550         set(HAVE_VIDEO_OPENGL TRUE)
  1551       endif()
  1552 
  1553       if(VIDEO_OPENGLES)
  1554         set(SDL_VIDEO_OPENGL_EGL 1)
  1555         set(SDL_VIDEO_OPENGL_ES2 1)
  1556         set(SDL_VIDEO_RENDER_OGL_ES2 1)
  1557         set(HAVE_VIDEO_OPENGLES TRUE)
  1558       endif()
  1559     endif()
  1560     
  1561     if(VIDEO_VULKAN OR VIDEO_METAL OR RENDER_METAL)
  1562       set(ORIG_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
  1563       set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -x objective-c")
  1564       check_c_source_compiles("
  1565         #include <AvailabilityMacros.h>
  1566         #import <Metal/Metal.h>
  1567         #import <QuartzCore/CAMetalLayer.h>
  1568 
  1569         #if TARGET_OS_SIMULATOR || (!TARGET_CPU_X86_64 && !TARGET_CPU_ARM64)
  1570         #error Metal doesn't work on this configuration
  1571         #endif
  1572         int main()
  1573         {
  1574             return 0;
  1575         }
  1576         " HAVE_FRAMEWORK_METAL)
  1577       set(CMAKE_REQUIRED_FLAGS ${ORIG_CMAKE_REQUIRED_FLAGS})
  1578       if(HAVE_FRAMEWORK_METAL)
  1579         set(SDL_FRAMEWORK_METAL 1)
  1580         set(SDL_FRAMEWORK_QUARTZCORE 1)
  1581       else()
  1582         set(VIDEO_VULKAN 0)
  1583         set(VIDEO_METAL 0)
  1584         set(RENDER_METAL 0)
  1585       endif()
  1586     endif()
  1587 
  1588     if(VIDEO_METAL)
  1589       set(SDL_VIDEO_METAL 1)
  1590       set(HAVE_VIDEO_METAL TRUE)
  1591     endif()
  1592 
  1593     if(RENDER_METAL)
  1594       file(GLOB RENDER_METAL_SOURCES ${SDL2_SOURCE_DIR}/src/render/metal/*.m)
  1595       set(SOURCE_FILES ${SOURCE_FILES} ${RENDER_METAL_SOURCES})
  1596       set(SDL_VIDEO_RENDER_METAL 1)
  1597       set(HAVE_RENDER_METAL TRUE)
  1598     endif()
  1599   endif()
  1600 
  1601   # Actually load the frameworks at the end so we don't duplicate include.
  1602   if(SDL_FRAMEWORK_COREVIDEO)
  1603     find_library(COREVIDEO CoreVideo)
  1604     list(APPEND EXTRA_LIBS ${COREVIDEO})
  1605   endif()
  1606   if(SDL_FRAMEWORK_COCOA)
  1607     find_library(COCOA_LIBRARY Cocoa)
  1608     list(APPEND EXTRA_LIBS ${COCOA_LIBRARY})
  1609   endif()
  1610   if(SDL_FRAMEWORK_IOKIT)
  1611     find_library(IOKIT IOKit)
  1612     list(APPEND EXTRA_LIBS ${IOKIT})
  1613   endif()
  1614   if(SDL_FRAMEWORK_FF)
  1615     find_library(FORCEFEEDBACK ForceFeedback)
  1616     list(APPEND EXTRA_LIBS ${FORCEFEEDBACK})
  1617   endif()
  1618   if(SDL_FRAMEWORK_CARBON)
  1619     find_library(CARBON_LIBRARY Carbon)
  1620     list(APPEND EXTRA_LIBS ${CARBON_LIBRARY})
  1621   endif()
  1622   if(SDL_FRAMEWORK_COREAUDIO)
  1623     find_library(COREAUDIO CoreAudio)
  1624     list(APPEND EXTRA_LIBS ${COREAUDIO})
  1625   endif()
  1626   if(SDL_FRAMEWORK_AUDIOTOOLBOX)
  1627     find_library(AUDIOTOOLBOX AudioToolbox)
  1628     list(APPEND EXTRA_LIBS ${AUDIOTOOLBOX})
  1629   endif()
  1630   if(SDL_FRAMEWORK_METAL)
  1631     if(IOS)
  1632       find_library(METAL Metal)
  1633       list(APPEND EXTRA_LIBS ${METAL})
  1634     else()
  1635       list(APPEND EXTRA_LDFLAGS "-Wl,-weak_framework,Metal")
  1636     endif()
  1637   endif()
  1638   if(SDL_FRAMEWORK_QUARTZCORE)
  1639     if(IOS)
  1640       find_library(QUARTZCORE QuartzCore)
  1641       list(APPEND EXTRA_LIBS ${QUARTZCORE})
  1642     else()
  1643       list(APPEND EXTRA_LDFLAGS "-Wl,-weak_framework,QuartzCore")
  1644     endif()
  1645   endif()
  1646 
  1647   CheckPTHREAD()
  1648 
  1649 elseif(HAIKU)
  1650   if(SDL_VIDEO)
  1651     set(SDL_VIDEO_DRIVER_HAIKU 1)
  1652     file(GLOB HAIKUVIDEO_SOURCES ${SDL2_SOURCE_DIR}/src/video/haiku/*.c)
  1653     set(SOURCE_FILES ${SOURCE_FILES} ${HAIKUVIDEO_SOURCES})
  1654     set(HAVE_SDL_VIDEO TRUE)
  1655 
  1656     set(SDL_FILESYSTEM_HAIKU 1)
  1657     file(GLOB FILESYSTEM_SOURCES ${SDL2_SOURCE_DIR}/src/filesystem/haiku/*.cc)
  1658     set(SOURCE_FILES ${SOURCE_FILES} ${FILESYSTEM_SOURCES})
  1659     set(HAVE_SDL_FILESYSTEM TRUE)
  1660 
  1661     if(SDL_TIMERS)
  1662       set(SDL_TIMER_HAIKU 1)
  1663       file(GLOB TIMER_SOURCES ${SDL2_SOURCE_DIR}/src/timer/haiku/*.c)
  1664       set(SOURCE_FILES ${SOURCE_FILES} ${TIMER_SOURCES})
  1665       set(HAVE_SDL_TIMERS TRUE)
  1666     endif(SDL_TIMERS)
  1667 
  1668     if(VIDEO_OPENGL)
  1669       # TODO: Use FIND_PACKAGE(OpenGL) instead
  1670       set(SDL_VIDEO_OPENGL 1)
  1671       set(SDL_VIDEO_OPENGL_BGL 1)
  1672       set(SDL_VIDEO_RENDER_OGL 1)
  1673       list(APPEND EXTRA_LIBS GL)
  1674       set(HAVE_VIDEO_OPENGL TRUE)
  1675     endif()
  1676   endif()
  1677 
  1678   CheckPTHREAD()
  1679 endif()
  1680 
  1681 if(VIDEO_VULKAN)
  1682   set(SDL_VIDEO_VULKAN 1)
  1683   set(HAVE_VIDEO_VULKAN TRUE)
  1684 endif()
  1685 
  1686 # Dummies
  1687 # configure.ac does it differently:
  1688 # if not have X
  1689 #   if enable_X {  SDL_X_DISABLED = 1 }
  1690 #   [add dummy sources]
  1691 # so it always adds a dummy, without checking, if it was actually requested.
  1692 # This leads to missing internal references on building, since the
  1693 # src/X/*.c does not get included.
  1694 if(NOT HAVE_SDL_JOYSTICK)
  1695   set(SDL_JOYSTICK_DUMMY 1)
  1696   if(SDL_JOYSTICK AND NOT APPLE) # results in unresolved symbols on OSX
  1697 
  1698     file(GLOB JOYSTICK_SOURCES ${SDL2_SOURCE_DIR}/src/joystick/dummy/*.c)
  1699     set(SOURCE_FILES ${SOURCE_FILES} ${JOYSTICK_SOURCES})
  1700   endif()
  1701 endif()
  1702 if(NOT HAVE_SDL_HAPTIC)
  1703   set(SDL_HAPTIC_DUMMY 1)
  1704   file(GLOB HAPTIC_SOURCES ${SDL2_SOURCE_DIR}/src/haptic/dummy/*.c)
  1705   set(SOURCE_FILES ${SOURCE_FILES} ${HAPTIC_SOURCES})
  1706 endif()
  1707 if(NOT HAVE_SDL_SENSORS)
  1708   set(SDL_SENSOR_DUMMY 1)
  1709   file(GLOB SENSORS_SOURCES ${SDL2_SOURCE_DIR}/src/sensor/dummy/*.c)
  1710   set(SOURCE_FILES ${SOURCE_FILES} ${SENSORS_SOURCES})
  1711 endif()
  1712 if(NOT HAVE_SDL_LOADSO)
  1713   set(SDL_LOADSO_DISABLED 1)
  1714   file(GLOB LOADSO_SOURCES ${SDL2_SOURCE_DIR}/src/loadso/dummy/*.c)
  1715   set(SOURCE_FILES ${SOURCE_FILES} ${LOADSO_SOURCES})
  1716 endif()
  1717 if(NOT HAVE_SDL_FILESYSTEM)
  1718   set(SDL_FILESYSTEM_DISABLED 1)
  1719   file(GLOB FILESYSTEM_SOURCES ${SDL2_SOURCE_DIR}/src/filesystem/dummy/*.c)
  1720   set(SOURCE_FILES ${SOURCE_FILES} ${FILESYSTEM_SOURCES})
  1721 endif()
  1722 
  1723 # We always need to have threads and timers around
  1724 if(NOT HAVE_SDL_THREADS)
  1725   set(SDL_THREADS_DISABLED 1)
  1726   file(GLOB THREADS_SOURCES ${SDL2_SOURCE_DIR}/src/thread/generic/*.c)
  1727   set(SOURCE_FILES ${SOURCE_FILES} ${THREADS_SOURCES})
  1728 endif()
  1729 if(NOT HAVE_SDL_TIMERS)
  1730   set(SDL_TIMERS_DISABLED 1)
  1731   file(GLOB TIMER_SOURCES ${SDL2_SOURCE_DIR}/src/timer/dummy/*.c)
  1732   set(SOURCE_FILES ${SOURCE_FILES} ${TIMER_SOURCES})
  1733 endif()
  1734 
  1735 if(NOT SDLMAIN_SOURCES)
  1736   file(GLOB SDLMAIN_SOURCES ${SDL2_SOURCE_DIR}/src/main/dummy/*.c)
  1737 endif()
  1738 
  1739 # Append the -MMD -MT flags
  1740 # if(DEPENDENCY_TRACKING)
  1741 #   if(COMPILER_IS_GNUCC)
  1742 #     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -MMD -MT \$@")
  1743 #   endif()
  1744 # endif()
  1745 
  1746 configure_file("${SDL2_SOURCE_DIR}/include/SDL_config.h.cmake"
  1747   "${SDL2_BINARY_DIR}/include/SDL_config.h")
  1748 
  1749 # Prepare the flags and remove duplicates
  1750 if(EXTRA_LDFLAGS)
  1751   list(REMOVE_DUPLICATES EXTRA_LDFLAGS)
  1752 endif()
  1753 if(EXTRA_LIBS)
  1754   list(REMOVE_DUPLICATES EXTRA_LIBS)
  1755 endif()
  1756 if(EXTRA_CFLAGS)
  1757   list(REMOVE_DUPLICATES EXTRA_CFLAGS)
  1758 endif()
  1759 listtostr(EXTRA_CFLAGS _EXTRA_CFLAGS)
  1760 set(EXTRA_CFLAGS ${_EXTRA_CFLAGS})
  1761 
  1762 # Compat helpers for the configuration files
  1763 if(NOT WINDOWS OR CYGWIN)
  1764   # TODO: we need a Windows script, too
  1765   execute_process(COMMAND sh ${SDL2_SOURCE_DIR}/build-scripts/updaterev.sh)
  1766 
  1767   set(prefix ${CMAKE_INSTALL_PREFIX})
  1768   set(exec_prefix "\${prefix}")
  1769   set(libdir "\${exec_prefix}/lib${LIB_SUFFIX}")
  1770   set(bindir "\${exec_prefix}/bin")
  1771   set(includedir "\${prefix}/include")
  1772   if(SDL_STATIC)
  1773     set(ENABLE_STATIC_TRUE "")
  1774     set(ENABLE_STATIC_FALSE "#")
  1775   else()
  1776     set(ENABLE_STATIC_TRUE "#")
  1777     set(ENABLE_STATIC_FALSE "")
  1778   endif()
  1779   if(SDL_SHARED)
  1780     set(ENABLE_SHARED_TRUE "")
  1781     set(ENABLE_SHARED_FALSE "#")
  1782   else()
  1783     set(ENABLE_SHARED_TRUE "#")
  1784     set(ENABLE_SHARED_FALSE "")
  1785   endif()
  1786 
  1787   # Clean up the different lists
  1788   listtostr(EXTRA_LIBS _EXTRA_LIBS "-l")
  1789   set(SDL_STATIC_LIBS ${SDL_LIBS} ${EXTRA_LDFLAGS} ${_EXTRA_LIBS})
  1790   list(REMOVE_DUPLICATES SDL_STATIC_LIBS)
  1791   listtostr(SDL_STATIC_LIBS _SDL_STATIC_LIBS)
  1792   set(SDL_STATIC_LIBS ${_SDL_STATIC_LIBS})
  1793   listtostr(SDL_LIBS _SDL_LIBS)
  1794   set(SDL_LIBS ${_SDL_LIBS})
  1795 
  1796   # MESSAGE(STATUS "SDL_LIBS: ${SDL_LIBS}")
  1797   # MESSAGE(STATUS "SDL_STATIC_LIBS: ${SDL_STATIC_LIBS}")
  1798 
  1799   configure_file("${SDL2_SOURCE_DIR}/sdl2.pc.in"
  1800     "${SDL2_BINARY_DIR}/sdl2.pc" @ONLY)
  1801   configure_file("${SDL2_SOURCE_DIR}/sdl2-config.in"
  1802     "${SDL2_BINARY_DIR}/sdl2-config")
  1803   configure_file("${SDL2_SOURCE_DIR}/sdl2-config.in"
  1804     "${SDL2_BINARY_DIR}/sdl2-config" @ONLY)
  1805   configure_file("${SDL2_SOURCE_DIR}/SDL2.spec.in"
  1806     "${SDL2_BINARY_DIR}/SDL2.spec" @ONLY)
  1807 endif()
  1808 
  1809 ##### Info output #####
  1810 message(STATUS "")
  1811 message(STATUS "SDL2 was configured with the following options:")
  1812 message(STATUS "")
  1813 message(STATUS "Platform: ${CMAKE_SYSTEM}")
  1814 message(STATUS "64-bit:   ${ARCH_64}")
  1815 message(STATUS "Compiler: ${CMAKE_C_COMPILER}")
  1816 message(STATUS "")
  1817 message(STATUS "Subsystems:")
  1818 foreach(_SUB ${SDL_SUBSYSTEMS})
  1819   string(TOUPPER ${_SUB} _OPT)
  1820   message_bool_option(${_SUB} SDL_${_OPT})
  1821 endforeach()
  1822 message(STATUS "")
  1823 message(STATUS "Options:")
  1824 list(SORT ALLOPTIONS)
  1825 foreach(_OPT ${ALLOPTIONS})
  1826   # Longest option is VIDEO_X11_XSCREENSAVER = 22 characters
  1827   # Get the padding
  1828   string(LENGTH ${_OPT} _OPTLEN)
  1829   math(EXPR _PADLEN "23 - ${_OPTLEN}")
  1830   string(RANDOM LENGTH ${_PADLEN} ALPHABET " " _PADDING)
  1831   message_tested_option(${_OPT} ${_PADDING})
  1832 endforeach()
  1833 message(STATUS "")
  1834 message(STATUS " CFLAGS:        ${CMAKE_C_FLAGS}")
  1835 message(STATUS " EXTRA_CFLAGS:  ${EXTRA_CFLAGS}")
  1836 message(STATUS " EXTRA_LDFLAGS: ${EXTRA_LDFLAGS}")
  1837 message(STATUS " EXTRA_LIBS:    ${EXTRA_LIBS}")
  1838 message(STATUS "")
  1839 message(STATUS " Build Shared Library: ${SDL_SHARED}")
  1840 message(STATUS " Build Static Library: ${SDL_STATIC}")
  1841 if(SDL_STATIC)
  1842     message(STATUS " Build Static Library with Position Independent Code: ${SDL_STATIC_PIC}")
  1843 endif()
  1844 message(STATUS "")
  1845 if(UNIX)
  1846   message(STATUS "If something was not detected, although the libraries")
  1847   message(STATUS "were installed, then make sure you have set the")
  1848   message(STATUS "CFLAGS and LDFLAGS environment variables correctly.")
  1849   message(STATUS "")
  1850 endif()
  1851 
  1852 # Ensure that the extra cflags are used at compile time
  1853 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${EXTRA_CFLAGS}")
  1854 
  1855 # Always build SDLmain
  1856 add_library(SDL2main STATIC ${SDLMAIN_SOURCES})
  1857 target_include_directories(SDL2main PUBLIC "$<BUILD_INTERFACE:${SDL2_SOURCE_DIR}/include>" $<INSTALL_INTERFACE:include/SDL2>)
  1858 set(_INSTALL_LIBS "SDL2main")
  1859 if (NOT ANDROID)
  1860   set_target_properties(SDL2main PROPERTIES DEBUG_POSTFIX ${SDL_CMAKE_DEBUG_POSTFIX})
  1861 endif()
  1862 
  1863 if(SDL_SHARED)
  1864   add_library(SDL2 SHARED ${SOURCE_FILES} ${VERSION_SOURCES})
  1865   if(APPLE)
  1866     set_target_properties(SDL2 PROPERTIES
  1867       MACOSX_RPATH 1
  1868       OUTPUT_NAME "SDL2-${LT_RELEASE}")
  1869   elseif(UNIX AND NOT ANDROID)
  1870     set_target_properties(SDL2 PROPERTIES
  1871       VERSION ${LT_VERSION}
  1872       SOVERSION ${LT_REVISION}
  1873       OUTPUT_NAME "SDL2-${LT_RELEASE}")
  1874   else()
  1875     set_target_properties(SDL2 PROPERTIES
  1876       VERSION ${SDL_VERSION}
  1877       SOVERSION ${LT_REVISION}
  1878       OUTPUT_NAME "SDL2")
  1879   endif()
  1880   if(MSVC AND NOT LIBC)
  1881     # Don't try to link with the default set of libraries.
  1882     set_target_properties(SDL2 PROPERTIES LINK_FLAGS_RELEASE "/NODEFAULTLIB")
  1883     set_target_properties(SDL2 PROPERTIES LINK_FLAGS_DEBUG "/NODEFAULTLIB")
  1884     set_target_properties(SDL2 PROPERTIES STATIC_LIBRARY_FLAGS "/NODEFAULTLIB")
  1885   endif()
  1886   set(_INSTALL_LIBS "SDL2" ${_INSTALL_LIBS})
  1887   target_link_libraries(SDL2 ${EXTRA_LIBS} ${EXTRA_LDFLAGS})
  1888   target_include_directories(SDL2 PUBLIC "$<BUILD_INTERFACE:${SDL2_SOURCE_DIR}/include>" $<INSTALL_INTERFACE:include/SDL2>)
  1889   if (NOT ANDROID)
  1890     set_target_properties(SDL2 PROPERTIES DEBUG_POSTFIX ${SDL_CMAKE_DEBUG_POSTFIX})
  1891   endif()
  1892 endif()
  1893 
  1894 if(ANDROID)
  1895   if(HAVE_HIDAPI)
  1896     add_library(hidapi SHARED ${SDL2_SOURCE_DIR}/src/hidapi/android/hid.cpp)
  1897   endif()
  1898 
  1899   if(MSVC AND NOT LIBC)
  1900     # Don't try to link with the default set of libraries.
  1901     set_target_properties(hidapi PROPERTIES LINK_FLAGS_RELEASE "/NODEFAULTLIB")
  1902     set_target_properties(hidapi PROPERTIES LINK_FLAGS_DEBUG "/NODEFAULTLIB")
  1903     set_target_properties(hidapi PROPERTIES STATIC_LIBRARY_FLAGS "/NODEFAULTLIB")
  1904   endif()
  1905   target_link_libraries(hidapi log)
  1906 endif()
  1907 
  1908 if(SDL_STATIC)
  1909   set (BUILD_SHARED_LIBS FALSE)
  1910   add_library(SDL2-static STATIC ${SOURCE_FILES})
  1911   if (NOT SDL_SHARED OR NOT WIN32)
  1912     set_target_properties(SDL2-static PROPERTIES OUTPUT_NAME "SDL2")
  1913     # Note: Apparently, OUTPUT_NAME must really be unique; even when
  1914     # CMAKE_IMPORT_LIBRARY_SUFFIX or the like are given. Otherwise
  1915     # the static build may race with the import lib and one will get
  1916     # clobbered, when the suffix is realized via subsequent rename.
  1917   endif()
  1918   set_target_properties(SDL2-static PROPERTIES POSITION_INDEPENDENT_CODE ${SDL_STATIC_PIC})
  1919   if(MSVC AND NOT LIBC)
  1920     set_target_properties(SDL2-static PROPERTIES LINK_FLAGS_RELEASE "/NODEFAULTLIB")
  1921     set_target_properties(SDL2-static PROPERTIES LINK_FLAGS_DEBUG "/NODEFAULTLIB")
  1922     set_target_properties(SDL2-static PROPERTIES STATIC_LIBRARY_FLAGS "/NODEFAULTLIB")
  1923   endif()
  1924   # TODO: Win32 platforms keep the same suffix .lib for import and static
  1925   # libraries - do we need to consider this?
  1926   set(_INSTALL_LIBS "SDL2-static" ${_INSTALL_LIBS})
  1927   target_link_libraries(SDL2-static ${EXTRA_LIBS} ${EXTRA_LDFLAGS})
  1928   target_include_directories(SDL2-static PUBLIC "$<BUILD_INTERFACE:${SDL2_SOURCE_DIR}/include>" $<INSTALL_INTERFACE:include/SDL2>)
  1929   if (NOT ANDROID)
  1930     set_target_properties(SDL2-static PROPERTIES DEBUG_POSTFIX ${SDL_CMAKE_DEBUG_POSTFIX})
  1931   endif()
  1932 endif()
  1933 
  1934 ##### Tests #####
  1935 
  1936 if(SDL_TEST)
  1937   file(GLOB TEST_SOURCES ${SDL2_SOURCE_DIR}/src/test/*.c)
  1938   add_library(SDL2_test STATIC ${TEST_SOURCES})
  1939 
  1940   add_subdirectory(test)
  1941 endif()
  1942 
  1943 ##### Installation targets #####
  1944 install(TARGETS ${_INSTALL_LIBS} EXPORT SDL2Targets
  1945   LIBRARY DESTINATION "lib${LIB_SUFFIX}"
  1946   ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
  1947   RUNTIME DESTINATION bin)
  1948 
  1949 ##### Export files #####
  1950 if (WINDOWS)
  1951   set(PKG_PREFIX "cmake")
  1952 else ()
  1953   set(PKG_PREFIX "lib/cmake/SDL2")
  1954 endif ()
  1955 
  1956 include(CMakePackageConfigHelpers)
  1957 write_basic_package_version_file("${CMAKE_BINARY_DIR}/SDL2ConfigVersion.cmake"
  1958   VERSION ${SDL_VERSION}
  1959   COMPATIBILITY AnyNewerVersion
  1960 )
  1961 
  1962 install(EXPORT SDL2Targets
  1963   FILE SDL2Targets.cmake
  1964   NAMESPACE SDL2::
  1965   DESTINATION ${PKG_PREFIX}
  1966 )
  1967 install(
  1968   FILES
  1969     ${CMAKE_CURRENT_SOURCE_DIR}/SDL2Config.cmake
  1970     ${CMAKE_BINARY_DIR}/SDL2ConfigVersion.cmake
  1971   DESTINATION ${PKG_PREFIX}
  1972   COMPONENT Devel
  1973 )
  1974 
  1975 file(GLOB INCLUDE_FILES ${SDL2_SOURCE_DIR}/include/*.h)
  1976 file(GLOB BIN_INCLUDE_FILES ${SDL2_BINARY_DIR}/include/*.h)
  1977 foreach(_FNAME ${BIN_INCLUDE_FILES})
  1978   get_filename_component(_INCNAME ${_FNAME} NAME)
  1979   list(REMOVE_ITEM INCLUDE_FILES ${SDL2_SOURCE_DIR}/include/${_INCNAME})
  1980 endforeach()
  1981 list(APPEND INCLUDE_FILES ${BIN_INCLUDE_FILES})
  1982 install(FILES ${INCLUDE_FILES} DESTINATION include/SDL2)
  1983 
  1984 string(TOUPPER "${CMAKE_BUILD_TYPE}" UPPER_BUILD_TYPE)
  1985 if (UPPER_BUILD_TYPE MATCHES DEBUG)
  1986   set(SOPOSTFIX "${SDL_CMAKE_DEBUG_POSTFIX}")
  1987 else()
  1988   set(SOPOSTFIX "")
  1989 endif()
  1990 
  1991 if(NOT (WINDOWS OR CYGWIN))
  1992   if(SDL_SHARED)
  1993     set(SOEXT ${CMAKE_SHARED_LIBRARY_SUFFIX}) # ".so", ".dylib", etc.
  1994     get_target_property(SONAME SDL2 OUTPUT_NAME)
  1995     if(NOT ANDROID)
  1996         install(CODE "
  1997           execute_process(COMMAND ${CMAKE_COMMAND} -E create_symlink
  1998             \"lib${SONAME}${SOPOSTFIX}${SOEXT}\" \"libSDL2${SOPOSTFIX}${SOEXT}\"
  1999             WORKING_DIRECTORY \"${SDL2_BINARY_DIR}\")")
  2000         install(FILES ${SDL2_BINARY_DIR}/libSDL2${SOPOSTFIX}${SOEXT} DESTINATION "lib${LIB_SUFFIX}")
  2001     endif()
  2002   endif()
  2003   if(FREEBSD)
  2004     # FreeBSD uses ${PREFIX}/libdata/pkgconfig
  2005     install(FILES ${SDL2_BINARY_DIR}/sdl2.pc DESTINATION "libdata/pkgconfig")
  2006   else()
  2007     install(FILES ${SDL2_BINARY_DIR}/sdl2.pc
  2008       DESTINATION "lib${LIB_SUFFIX}/pkgconfig")
  2009   endif()
  2010   install(PROGRAMS ${SDL2_BINARY_DIR}/sdl2-config DESTINATION bin)
  2011   # TODO: what about the .spec file? Is it only needed for RPM creation?
  2012   install(FILES "${SDL2_SOURCE_DIR}/sdl2.m4" DESTINATION "${CMAKE_INSTALL_FULL_DATAROOTDIR}/aclocal")
  2013 endif()
  2014 
  2015 ##### Uninstall target #####
  2016 
  2017 if(NOT TARGET uninstall)
  2018   configure_file(
  2019       "${CMAKE_CURRENT_SOURCE_DIR}/cmake_uninstall.cmake.in"
  2020       "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
  2021       IMMEDIATE @ONLY)
  2022 
  2023   add_custom_target(uninstall
  2024       COMMAND ${CMAKE_COMMAND} -P ${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake)
  2025 endif()