CMakeLists.txt
author Sam Lantinga <slouken@libsdl.org>
Tue, 21 Aug 2018 12:11:34 -0700
changeset 12130 24142c5073a4
parent 12072 1e46699fa470
child 12149 e037e9c2bc00
permissions -rw-r--r--
First pass on the new SDL sensor API
     1 if(${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
     2   message(FATAL_ERROR "Prevented in-tree built. Please create a build directory outside of the SDL source code and call cmake from there")
     3 endif()
     4 
     5 cmake_minimum_required(VERSION 2.8.11)
     6 project(SDL2 C)
     7 
     8 # !!! FIXME: this should probably do "MACOSX_RPATH ON" as a target property
     9 # !!! FIXME:  for the SDL2 shared library (so you get an
    10 # !!! FIXME:  install_name ("soname") of "@rpath/libSDL-whatever.dylib"
    11 # !!! FIXME:  instead of "/usr/local/lib/libSDL-whatever.dylib"), but I'm
    12 # !!! FIXME:  punting for now and leaving the existing behavior. Until this
    13 # !!! FIXME:  properly resolved, this line silences a warning in CMake 3.0+.
    14 # !!! FIXME:  remove it and this comment entirely once the problem is
    15 # !!! FIXME:  properly resolved.
    16 #cmake_policy(SET CMP0042 OLD)
    17 
    18 include(CheckFunctionExists)
    19 include(CheckLibraryExists)
    20 include(CheckIncludeFiles)
    21 include(CheckIncludeFile)
    22 include(CheckSymbolExists)
    23 include(CheckCSourceCompiles)
    24 include(CheckCSourceRuns)
    25 include(CheckCCompilerFlag)
    26 include(CheckTypeSize)
    27 include(CheckStructHasMember)
    28 include(CMakeDependentOption)
    29 include(FindPkgConfig)
    30 include(GNUInstallDirs)
    31 set(CMAKE_MODULE_PATH "${SDL2_SOURCE_DIR}/cmake")
    32 include(${SDL2_SOURCE_DIR}/cmake/macros.cmake)
    33 include(${SDL2_SOURCE_DIR}/cmake/sdlchecks.cmake)
    34 
    35 # General settings
    36 # Edit include/SDL_version.h and change the version, then:
    37 #   SDL_MICRO_VERSION += 1;
    38 #   SDL_INTERFACE_AGE += 1;
    39 #   SDL_BINARY_AGE += 1;
    40 # if any functions have been added, set SDL_INTERFACE_AGE to 0.
    41 # if backwards compatibility has been broken,
    42 # set SDL_BINARY_AGE and SDL_INTERFACE_AGE to 0.
    43 set(SDL_MAJOR_VERSION 2)
    44 set(SDL_MINOR_VERSION 0)
    45 set(SDL_MICRO_VERSION 8)
    46 set(SDL_INTERFACE_AGE 0)
    47 set(SDL_BINARY_AGE 8)
    48 set(SDL_VERSION "${SDL_MAJOR_VERSION}.${SDL_MINOR_VERSION}.${SDL_MICRO_VERSION}")
    49 
    50 # Set defaults preventing destination file conflicts
    51 set(SDL_CMAKE_DEBUG_POSTFIX "d"
    52     CACHE STRING "Name suffix for debug builds")
    53 
    54 mark_as_advanced(CMAKE_IMPORT_LIBRARY_SUFFIX SDL_CMAKE_DEBUG_POSTFIX)
    55 
    56 # Calculate a libtool-like version number
    57 math(EXPR LT_CURRENT "${SDL_MICRO_VERSION} - ${SDL_INTERFACE_AGE}")
    58 math(EXPR LT_AGE "${SDL_BINARY_AGE} - ${SDL_INTERFACE_AGE}")
    59 math(EXPR LT_MAJOR "${LT_CURRENT}- ${LT_AGE}")
    60 set(LT_REVISION "${SDL_INTERFACE_AGE}")
    61 set(LT_RELEASE "${SDL_MAJOR_VERSION}.${SDL_MINOR_VERSION}")
    62 set(LT_VERSION "${LT_MAJOR}.${LT_AGE}.${LT_REVISION}")
    63 
    64 message(STATUS "${LT_VERSION} :: ${LT_AGE} :: ${LT_REVISION} :: ${LT_CURRENT} :: ${LT_RELEASE}")
    65 
    66 # General settings & flags
    67 set(LIBRARY_OUTPUT_DIRECTORY "build")
    68 # Check for 64 or 32 bit
    69 set(SIZEOF_VOIDP ${CMAKE_SIZEOF_VOID_P})
    70 if(CMAKE_SIZEOF_VOID_P EQUAL 8)
    71   set(ARCH_64 TRUE)
    72   set(PROCESSOR_ARCH "x64")
    73 else()
    74   set(ARCH_64 FALSE)
    75   set(PROCESSOR_ARCH "x86")
    76 endif()
    77 set(LIBNAME SDL2)
    78 if(NOT LIBTYPE)
    79   set(LIBTYPE SHARED)
    80 endif()
    81 
    82 # Get the platform
    83 if(WIN32)
    84   if(NOT WINDOWS)
    85     set(WINDOWS TRUE)
    86   endif()
    87 elseif(UNIX AND NOT APPLE)
    88   if(CMAKE_SYSTEM_NAME MATCHES ".*Linux")
    89     set(LINUX TRUE)
    90   elseif(CMAKE_SYSTEM_NAME MATCHES "kFreeBSD.*")
    91     set(FREEBSD TRUE)
    92   elseif(CMAKE_SYSTEM_NAME MATCHES "kNetBSD.*|NetBSD.*")
    93     set(NETBSD TRUE)
    94   elseif(CMAKE_SYSTEM_NAME MATCHES "kOpenBSD.*|OpenBSD.*")
    95     set(OPENBSD TRUE)
    96   elseif(CMAKE_SYSTEM_NAME MATCHES ".*GNU.*")
    97     set(GNU TRUE)
    98   elseif(CMAKE_SYSTEM_NAME MATCHES ".*BSDI.*")
    99     set(BSDI TRUE)
   100   elseif(CMAKE_SYSTEM_NAME MATCHES "DragonFly.*|FreeBSD")
   101     set(FREEBSD TRUE)
   102   elseif(CMAKE_SYSTEM_NAME MATCHES "SYSV5.*")
   103     set(SYSV5 TRUE)
   104   elseif(CMAKE_SYSTEM_NAME MATCHES "Solaris.*")
   105     set(SOLARIS TRUE)
   106   elseif(CMAKE_SYSTEM_NAME MATCHES "HP-UX.*")
   107     set(HPUX TRUE)
   108   elseif(CMAKE_SYSTEM_NAME MATCHES "AIX.*")
   109     set(AIX TRUE)
   110   elseif(CMAKE_SYSTEM_NAME MATCHES "Minix.*")
   111     set(MINIX TRUE)
   112   endif()
   113 elseif(APPLE)
   114   if(CMAKE_SYSTEM_NAME MATCHES ".*Darwin.*")
   115     set(DARWIN TRUE)
   116   elseif(CMAKE_SYSTEM_NAME MATCHES ".*MacOS.*")
   117     set(MACOSX TRUE)
   118   endif()
   119   # TODO: iOS?
   120 elseif(CMAKE_SYSTEM_NAME MATCHES "BeOS.*")
   121   message_error("BeOS support has been removed as of SDL 2.0.2.")
   122 elseif(CMAKE_SYSTEM_NAME MATCHES "Haiku.*")
   123   set(HAIKU TRUE)
   124 endif()
   125 
   126 # Don't mistake osx for unix
   127 if(UNIX AND NOT APPLE)
   128   set(UNIX_SYS ON)
   129 else()
   130   set(UNIX_SYS OFF)
   131 endif()
   132 
   133 if(UNIX OR APPLE)
   134   set(UNIX_OR_MAC_SYS ON)
   135 else()
   136   set(UNIX_OR_MAC_SYS OFF)
   137 endif()
   138 
   139 if (UNIX_OR_MAC_SYS AND NOT EMSCRIPTEN) # JavaScript does not yet have threading support, so disable pthreads when building for Emscripten.
   140   set(SDL_PTHREADS_ENABLED_BY_DEFAULT ON)
   141 else()
   142   set(SDL_PTHREADS_ENABLED_BY_DEFAULT OFF)
   143 endif()
   144 
   145 # Default option knobs
   146 if(APPLE OR ARCH_64)
   147   if(NOT "${CMAKE_OSX_ARCHITECTURES}" MATCHES "arm")
   148     set(OPT_DEF_SSEMATH ON)
   149   endif()
   150 endif()
   151 if(UNIX OR MINGW OR MSYS)
   152   set(OPT_DEF_LIBC ON)
   153 endif()
   154 
   155 # Compiler info
   156 if(CMAKE_COMPILER_IS_GNUCC)
   157   set(USE_GCC TRUE)
   158   set(OPT_DEF_ASM TRUE)
   159 elseif(CMAKE_C_COMPILER_ID MATCHES "Clang")
   160   set(USE_CLANG TRUE)
   161   set(OPT_DEF_ASM TRUE)
   162 elseif(MSVC_VERSION GREATER 1400) # VisualStudio 8.0+
   163   set(OPT_DEF_ASM TRUE)
   164   #set(CMAKE_C_FLAGS "/ZI /WX- /
   165 else()
   166   set(OPT_DEF_ASM FALSE)
   167 endif()
   168 
   169 if(USE_GCC OR USE_CLANG)
   170   set(OPT_DEF_GCC_ATOMICS ON)
   171 endif()
   172 
   173 # Default flags, if not set otherwise
   174 if("$ENV{CFLAGS}" STREQUAL "")
   175   if(CMAKE_BUILD_TYPE STREQUAL "")
   176     if(USE_GCC OR USE_CLANG)
   177       set(CMAKE_C_FLAGS "-g -O3")
   178     endif()
   179   endif()
   180 else()
   181   set(CMAKE_C_FLAGS "$ENV{CFLAGS}")
   182   list(APPEND EXTRA_CFLAGS "$ENV{CFLAGS}")
   183 endif()
   184 if(NOT ("$ENV{CFLAGS}" STREQUAL "")) # Hackish, but does the trick on Win32
   185   list(APPEND EXTRA_LDFLAGS "$ENV{LDFLAGS}")
   186 endif()
   187 
   188 if(MSVC)
   189   option(FORCE_STATIC_VCRT "Force /MT for static VC runtimes" OFF)
   190   if(FORCE_STATIC_VCRT)
   191     foreach(flag_var
   192         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
   193         CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO)
   194       if(${flag_var} MATCHES "/MD")
   195         string(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
   196       endif()
   197     endforeach()
   198   endif()
   199 
   200   # Make sure /RTC1 is disabled, otherwise it will use functions from the CRT
   201   foreach(flag_var
   202       CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
   203       CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO)
   204     string(REGEX REPLACE "/RTC(su|[1su])" "" ${flag_var} "${${flag_var}}")
   205   endforeach(flag_var)
   206 endif()
   207 
   208 # Those are used for pkg-config and friends, so that the SDL2.pc, sdl2-config,
   209 # etc. are created correctly.
   210 set(SDL_LIBS "-lSDL2")
   211 set(SDL_CFLAGS "")
   212 
   213 # When building shared lib for Windows with MinGW,
   214 # avoid the DLL having a "lib" prefix
   215 if(WINDOWS)
   216   set(CMAKE_SHARED_LIBRARY_PREFIX "")
   217 endif()
   218 
   219 # Emscripten toolchain has a nonempty default value for this, and the checks
   220 # in this file need to change that, so remember the original value, and
   221 # restore back to that afterwards. For check_function_exists() to work in
   222 # Emscripten, this value must be at its default value.
   223 set(ORIG_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
   224 
   225 if(CYGWIN)
   226   # We build SDL on cygwin without the UNIX emulation layer
   227   include_directories("-I/usr/include/mingw")
   228   set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -mno-cygwin")
   229   check_c_source_compiles("int main(int argc, char **argv) {}"
   230     HAVE_GCC_NO_CYGWIN)
   231   set(CMAKE_REQUIRED_FLAGS ${ORIG_CMAKE_REQUIRED_FLAGS})
   232   if(HAVE_GCC_NO_CYGWIN)
   233     list(APPEND EXTRA_LDFLAGS "-mno-cygwin")
   234     list(APPEND SDL_LIBS "-mno-cygwin")
   235   endif()
   236   set(SDL_CFLAGS "${SDL_CFLAGS} -I/usr/include/mingw")
   237 endif()
   238 
   239 add_definitions(-DUSING_GENERATED_CONFIG_H)
   240 # General includes
   241 include_directories(${SDL2_BINARY_DIR}/include ${SDL2_SOURCE_DIR}/include)
   242 if(USE_GCC OR USE_CLANG)
   243   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -idirafter ${SDL2_SOURCE_DIR}/src/video/khronos")
   244 else()
   245   include_directories(${SDL2_SOURCE_DIR}/src/video/khronos)
   246 endif()
   247 
   248 # All these ENABLED_BY_DEFAULT vars will default to ON if not specified, so
   249 #  you only need to have a platform override them if they are disabling.
   250 set(OPT_DEF_ASM TRUE)
   251 if(EMSCRIPTEN)
   252   # Set up default values for the currently supported set of subsystems:
   253   # Emscripten/Javascript does not have assembly support, a dynamic library
   254   # loading architecture, low-level CPU inspection or multithreading.
   255   set(OPT_DEF_ASM FALSE)
   256   set(SDL_SHARED_ENABLED_BY_DEFAULT OFF)
   257   set(SDL_ATOMIC_ENABLED_BY_DEFAULT OFF)
   258   set(SDL_THREADS_ENABLED_BY_DEFAULT OFF)
   259   set(SDL_LOADSO_ENABLED_BY_DEFAULT OFF)
   260   set(SDL_CPUINFO_ENABLED_BY_DEFAULT OFF)
   261   set(SDL_DLOPEN_ENABLED_BY_DEFAULT OFF)
   262 endif()
   263 
   264 if (NOT DEFINED SDL_SHARED_ENABLED_BY_DEFAULT)
   265     set(SDL_SHARED_ENABLED_BY_DEFAULT ON)
   266 endif()
   267 
   268 set(SDL_SUBSYSTEMS
   269     Atomic Audio Video Render Events Joystick Haptic Power Threads Timers
   270     File Loadso CPUinfo Filesystem Dlopen)
   271 foreach(_SUB ${SDL_SUBSYSTEMS})
   272   string(TOUPPER ${_SUB} _OPT)
   273   if (NOT DEFINED SDL_${_OPT}_ENABLED_BY_DEFAULT)
   274     set(SDL_${_OPT}_ENABLED_BY_DEFAULT ON)
   275   endif()
   276   option(SDL_${_OPT} "Enable the ${_SUB} subsystem" ${SDL_${_OPT}_ENABLED_BY_DEFAULT})
   277 endforeach()
   278 
   279 option_string(ASSERTIONS "Enable internal sanity checks (auto/disabled/release/enabled/paranoid)" "auto")
   280 #set_option(DEPENDENCY_TRACKING "Use gcc -MMD -MT dependency tracking" ON)
   281 set_option(LIBC                "Use the system C library" ${OPT_DEF_LIBC})
   282 set_option(GCC_ATOMICS         "Use gcc builtin atomics" ${OPT_DEF_GCC_ATOMICS})
   283 set_option(ASSEMBLY            "Enable assembly routines" ${OPT_DEF_ASM})
   284 set_option(SSEMATH             "Allow GCC to use SSE floating point math" ${OPT_DEF_SSEMATH})
   285 set_option(MMX                 "Use MMX assembly routines" ${OPT_DEF_ASM})
   286 set_option(3DNOW               "Use 3Dnow! MMX assembly routines" ${OPT_DEF_ASM})
   287 set_option(SSE                 "Use SSE assembly routines" ${OPT_DEF_ASM})
   288 set_option(SSE2                "Use SSE2 assembly routines" ${OPT_DEF_SSEMATH})
   289 set_option(SSE3                "Use SSE3 assembly routines" ${OPT_DEF_SSEMATH})
   290 set_option(ALTIVEC             "Use Altivec assembly routines" ${OPT_DEF_ASM})
   291 set_option(DISKAUDIO           "Support the disk writer audio driver" ON)
   292 set_option(DUMMYAUDIO          "Support the dummy audio driver" ON)
   293 set_option(VIDEO_DIRECTFB      "Use DirectFB video driver" OFF)
   294 dep_option(DIRECTFB_SHARED     "Dynamically load directfb support" ON "VIDEO_DIRECTFB" OFF)
   295 set_option(VIDEO_DUMMY         "Use dummy video driver" ON)
   296 set_option(VIDEO_OPENGL        "Include OpenGL support" ON)
   297 set_option(VIDEO_OPENGLES      "Include OpenGL ES support" ON)
   298 set_option(PTHREADS            "Use POSIX threads for multi-threading" ${SDL_PTHREADS_ENABLED_BY_DEFAULT})
   299 dep_option(PTHREADS_SEM        "Use pthread semaphores" ON "PTHREADS" OFF)
   300 set_option(SDL_DLOPEN          "Use dlopen for shared object loading" ${SDL_DLOPEN_ENABLED_BY_DEFAULT})
   301 set_option(OSS                 "Support the OSS audio API" ${UNIX_SYS})
   302 set_option(ALSA                "Support the ALSA audio API" ${UNIX_SYS})
   303 dep_option(ALSA_SHARED         "Dynamically load ALSA audio support" ON "ALSA" OFF)
   304 set_option(JACK                "Support the JACK audio API" ${UNIX_SYS})
   305 dep_option(JACK_SHARED         "Dynamically load JACK audio support" ON "JACK" OFF)
   306 set_option(ESD                 "Support the Enlightened Sound Daemon" ${UNIX_SYS})
   307 dep_option(ESD_SHARED          "Dynamically load ESD audio support" ON "ESD" OFF)
   308 set_option(PULSEAUDIO          "Use PulseAudio" ${UNIX_SYS})
   309 dep_option(PULSEAUDIO_SHARED   "Dynamically load PulseAudio support" ON "PULSEAUDIO" OFF)
   310 set_option(ARTS                "Support the Analog Real Time Synthesizer" ${UNIX_SYS})
   311 dep_option(ARTS_SHARED         "Dynamically load aRts audio support" ON "ARTS" OFF)
   312 set_option(NAS                 "Support the NAS audio API" ${UNIX_SYS})
   313 set_option(NAS_SHARED          "Dynamically load NAS audio API" ${UNIX_SYS})
   314 set_option(SNDIO               "Support the sndio audio API" ${UNIX_SYS})
   315 set_option(FUSIONSOUND         "Use FusionSound audio driver" OFF)
   316 dep_option(FUSIONSOUND_SHARED  "Dynamically load fusionsound audio support" ON "FUSIONSOUND" OFF)
   317 set_option(LIBSAMPLERATE       "Use libsamplerate for audio rate conversion" ${UNIX_SYS})
   318 dep_option(LIBSAMPLERATE_SHARED "Dynamically load libsamplerate" ON "LIBSAMPLERATE" OFF)
   319 set_option(RPATH               "Use an rpath when linking SDL" ${UNIX_SYS})
   320 set_option(CLOCK_GETTIME       "Use clock_gettime() instead of gettimeofday()" OFF)
   321 set_option(INPUT_TSLIB         "Use the Touchscreen library for input" ${UNIX_SYS})
   322 set_option(VIDEO_X11           "Use X11 video driver" ${UNIX_SYS})
   323 set_option(VIDEO_WAYLAND       "Use Wayland video driver" ${UNIX_SYS})
   324 dep_option(WAYLAND_SHARED      "Dynamically load Wayland support" ON "VIDEO_WAYLAND" OFF)
   325 dep_option(VIDEO_WAYLAND_QT_TOUCH  "QtWayland server support for Wayland video driver" ON "VIDEO_WAYLAND" OFF)
   326 set_option(VIDEO_MIR           "Use Mir video driver" ${UNIX_SYS})
   327 dep_option(MIR_SHARED          "Dynamically load Mir support" ON "VIDEO_MIR" OFF)
   328 set_option(VIDEO_RPI           "Use Raspberry Pi video driver" ${UNIX_SYS})
   329 dep_option(X11_SHARED          "Dynamically load X11 support" ON "VIDEO_X11" OFF)
   330 set(SDL_X11_OPTIONS Xcursor Xinerama XInput Xrandr Xscrnsaver XShape Xvm)
   331 foreach(_SUB ${SDL_X11_OPTIONS})
   332   string(TOUPPER "VIDEO_X11_${_SUB}" _OPT)
   333   dep_option(${_OPT}           "Enable ${_SUB} support" ON "VIDEO_X11" OFF)
   334 endforeach()
   335 set_option(VIDEO_COCOA         "Use Cocoa video driver" ${APPLE})
   336 set_option(DIRECTX             "Use DirectX for Windows audio/video" ${WINDOWS})
   337 dep_option(WASAPI              "Use the Windows WASAPI audio driver" ON "DIRECTX" OFF)
   338 set_option(RENDER_D3D          "Enable the Direct3D render driver" ${WINDOWS})
   339 set_option(VIDEO_VIVANTE       "Use Vivante EGL video driver" ${UNIX_SYS})
   340 dep_option(VIDEO_VULKAN        "Enable Vulkan support" ON "ANDROID OR APPLE OR LINUX OR WINDOWS" OFF)
   341 set_option(VIDEO_KMSDRM        "Use KMS DRM video driver" ${UNIX_SYS})
   342 dep_option(KMSDRM_SHARED       "Dynamically load KMS DRM support" ON "VIDEO_KMSDRM" OFF)
   343 
   344 # TODO: We should (should we?) respect cmake's ${BUILD_SHARED_LIBS} flag here
   345 # The options below are for compatibility to configure's default behaviour.
   346 set(SDL_SHARED ${SDL_SHARED_ENABLED_BY_DEFAULT} CACHE BOOL "Build a shared version of the library")
   347 set(SDL_STATIC ON CACHE BOOL "Build a static version of the library")
   348 
   349 dep_option(SDL_STATIC_PIC      "Static version of the library should be built with Position Independent Code" OFF "SDL_STATIC" OFF)
   350 set_option(SDL_TEST            "Build the test directory" OFF)
   351 
   352 # General source files
   353 file(GLOB SOURCE_FILES
   354   ${SDL2_SOURCE_DIR}/src/*.c
   355   ${SDL2_SOURCE_DIR}/src/atomic/*.c
   356   ${SDL2_SOURCE_DIR}/src/audio/*.c
   357   ${SDL2_SOURCE_DIR}/src/cpuinfo/*.c
   358   ${SDL2_SOURCE_DIR}/src/dynapi/*.c
   359   ${SDL2_SOURCE_DIR}/src/events/*.c
   360   ${SDL2_SOURCE_DIR}/src/file/*.c
   361   ${SDL2_SOURCE_DIR}/src/libm/*.c
   362   ${SDL2_SOURCE_DIR}/src/render/*.c
   363   ${SDL2_SOURCE_DIR}/src/render/*/*.c
   364   ${SDL2_SOURCE_DIR}/src/stdlib/*.c
   365   ${SDL2_SOURCE_DIR}/src/thread/*.c
   366   ${SDL2_SOURCE_DIR}/src/timer/*.c
   367   ${SDL2_SOURCE_DIR}/src/video/*.c
   368   ${SDL2_SOURCE_DIR}/src/video/yuv2rgb/*.c)
   369 
   370 
   371 if(ASSERTIONS STREQUAL "auto")
   372   # Do nada - use optimization settings to determine the assertion level
   373 elseif(ASSERTIONS STREQUAL "disabled")
   374   set(SDL_DEFAULT_ASSERT_LEVEL 0)
   375 elseif(ASSERTIONS STREQUAL "release")
   376   set(SDL_DEFAULT_ASSERT_LEVEL 1)
   377 elseif(ASSERTIONS STREQUAL "enabled")
   378   set(SDL_DEFAULT_ASSERT_LEVEL 2)
   379 elseif(ASSERTIONS STREQUAL "paranoid")
   380   set(SDL_DEFAULT_ASSERT_LEVEL 3)
   381 else()
   382   message_error("unknown assertion level")
   383 endif()
   384 set(HAVE_ASSERTIONS ${ASSERTIONS})
   385 
   386 # Compiler option evaluation
   387 if(USE_GCC OR USE_CLANG)
   388   # Check for -Wall first, so later things can override pieces of it.
   389   check_c_compiler_flag(-Wall HAVE_GCC_WALL)
   390   if(HAVE_GCC_WALL)
   391     list(APPEND EXTRA_CFLAGS "-Wall")
   392     if(HAIKU)
   393       set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-multichar")
   394     endif()
   395   endif()
   396 
   397   check_c_compiler_flag(-Wdeclaration-after-statement HAVE_GCC_WDECLARATION_AFTER_STATEMENT)
   398   if(HAVE_GCC_WDECLARATION_AFTER_STATEMENT)
   399     check_c_compiler_flag(-Werror=declaration-after-statement HAVE_GCC_WERROR_DECLARATION_AFTER_STATEMENT)
   400     if(HAVE_GCC_WERROR_DECLARATION_AFTER_STATEMENT)
   401       list(APPEND EXTRA_CFLAGS "-Werror=declaration-after-statement")
   402     endif()
   403     list(APPEND EXTRA_CFLAGS "-Wdeclaration-after-statement")
   404   endif()
   405 
   406   if(DEPENDENCY_TRACKING)
   407     check_c_source_compiles("
   408         #if !defined(__GNUC__) || __GNUC__ < 3
   409         #error Dependency tracking requires GCC 3.0 or newer
   410         #endif
   411         int main(int argc, char **argv) { }" HAVE_DEPENDENCY_TRACKING)
   412   endif()
   413 
   414   if(GCC_ATOMICS)
   415     check_c_source_compiles("int main(int argc, char **argv) {
   416         int a;
   417         void *x, *y, *z;
   418         __sync_lock_test_and_set(&a, 4);
   419         __sync_lock_test_and_set(&x, y);
   420         __sync_fetch_and_add(&a, 1);
   421         __sync_bool_compare_and_swap(&a, 5, 10);
   422         __sync_bool_compare_and_swap(&x, y, z); }" HAVE_GCC_ATOMICS)
   423     if(NOT HAVE_GCC_ATOMICS)
   424       check_c_source_compiles("int main(int argc, char **argv) {
   425           int a;
   426           __sync_lock_test_and_set(&a, 1);
   427           __sync_lock_release(&a); }" HAVE_GCC_SYNC_LOCK_TEST_AND_SET)
   428     endif()
   429   endif()
   430 
   431   set(CMAKE_REQUIRED_FLAGS "-mpreferred-stack-boundary=2")
   432   check_c_source_compiles("int x = 0; int main(int argc, char **argv) {}"
   433     HAVE_GCC_PREFERRED_STACK_BOUNDARY)
   434   set(CMAKE_REQUIRED_FLAGS ${ORIG_CMAKE_REQUIRED_FLAGS})
   435 
   436   set(CMAKE_REQUIRED_FLAGS "-fvisibility=hidden -Werror")
   437   check_c_source_compiles("
   438       #if !defined(__GNUC__) || __GNUC__ < 4
   439       #error SDL only uses visibility attributes in GCC 4 or newer
   440       #endif
   441       int main(int argc, char **argv) {}" HAVE_GCC_FVISIBILITY)
   442   if(HAVE_GCC_FVISIBILITY)
   443     list(APPEND EXTRA_CFLAGS "-fvisibility=hidden")
   444   endif()
   445   set(CMAKE_REQUIRED_FLAGS ${ORIG_CMAKE_REQUIRED_FLAGS})
   446 
   447   check_c_compiler_flag(-Wshadow HAVE_GCC_WSHADOW)
   448   if(HAVE_GCC_WSHADOW)
   449     list(APPEND EXTRA_CFLAGS "-Wshadow")
   450   endif()
   451 
   452   if(APPLE)
   453     list(APPEND EXTRA_LDFLAGS "-Wl,-undefined,error")
   454   else()
   455     set(CMAKE_REQUIRED_FLAGS "-Wl,--no-undefined")
   456     check_c_compiler_flag("" HAVE_NO_UNDEFINED)
   457     set(CMAKE_REQUIRED_FLAGS ${ORIG_CMAKE_REQUIRED_FLAGS})
   458     if(HAVE_NO_UNDEFINED)
   459       list(APPEND EXTRA_LDFLAGS "-Wl,--no-undefined")
   460     endif()
   461   endif()
   462 endif()
   463 
   464 if(ASSEMBLY)
   465   if(USE_GCC OR USE_CLANG)
   466     set(SDL_ASSEMBLY_ROUTINES 1)
   467     # TODO: Those all seem to be quite GCC specific - needs to be
   468     # reworked for better compiler support
   469     set(HAVE_ASSEMBLY TRUE)
   470     if(MMX)
   471       set(CMAKE_REQUIRED_FLAGS "-mmmx")
   472       check_c_source_compiles("
   473           #ifdef __MINGW32__
   474           #include <_mingw.h>
   475           #ifdef __MINGW64_VERSION_MAJOR
   476           #include <intrin.h>
   477           #else
   478           #include <mmintrin.h>
   479           #endif
   480           #else
   481           #include <mmintrin.h>
   482           #endif
   483           #ifndef __MMX__
   484           #error Assembler CPP flag not enabled
   485           #endif
   486           int main(int argc, char **argv) { }" HAVE_MMX)
   487       if(HAVE_MMX)
   488         list(APPEND EXTRA_CFLAGS "-mmmx")
   489       endif()
   490       set(CMAKE_REQUIRED_FLAGS ${ORIG_CMAKE_REQUIRED_FLAGS})
   491     endif()
   492 
   493     if(3DNOW)
   494       set(CMAKE_REQUIRED_FLAGS "-m3dnow")
   495       check_c_source_compiles("
   496           #include <mm3dnow.h>
   497           #ifndef __3dNOW__
   498           #error Assembler CPP flag not enabled
   499           #endif
   500           int main(int argc, char **argv) {
   501             void *p = 0;
   502             _m_prefetch(p);
   503           }" HAVE_3DNOW)
   504       if(HAVE_3DNOW)
   505         list(APPEND EXTRA_CFLAGS "-m3dnow")
   506       endif()
   507       set(CMAKE_REQUIRED_FLAGS ${ORIG_CMAKE_REQUIRED_FLAGS})
   508     endif()
   509 
   510     if(SSE)
   511       set(CMAKE_REQUIRED_FLAGS "-msse")
   512       check_c_source_compiles("
   513           #ifdef __MINGW32__
   514           #include <_mingw.h>
   515           #ifdef __MINGW64_VERSION_MAJOR
   516           #include <intrin.h>
   517           #else
   518           #include <xmmintrin.h>
   519           #endif
   520           #else
   521           #include <xmmintrin.h>
   522           #endif
   523           #ifndef __SSE__
   524           #error Assembler CPP flag not enabled
   525           #endif
   526           int main(int argc, char **argv) { }" HAVE_SSE)
   527       if(HAVE_SSE)
   528         list(APPEND EXTRA_CFLAGS "-msse")
   529       endif()
   530       set(CMAKE_REQUIRED_FLAGS ${ORIG_CMAKE_REQUIRED_FLAGS})
   531     endif()
   532 
   533     if(SSE2)
   534       set(CMAKE_REQUIRED_FLAGS "-msse2")
   535       check_c_source_compiles("
   536           #ifdef __MINGW32__
   537           #include <_mingw.h>
   538           #ifdef __MINGW64_VERSION_MAJOR
   539           #include <intrin.h>
   540           #else
   541           #include <emmintrin.h>
   542           #endif
   543           #else
   544           #include <emmintrin.h>
   545           #endif
   546           #ifndef __SSE2__
   547           #error Assembler CPP flag not enabled
   548           #endif
   549           int main(int argc, char **argv) { }" HAVE_SSE2)
   550       if(HAVE_SSE2)
   551         list(APPEND EXTRA_CFLAGS "-msse2")
   552       endif()
   553       set(CMAKE_REQUIRED_FLAGS ${ORIG_CMAKE_REQUIRED_FLAGS})
   554     endif()
   555 
   556     if(SSE3)
   557       set(CMAKE_REQUIRED_FLAGS "-msse3")
   558       check_c_source_compiles("
   559           #ifdef __MINGW32__
   560           #include <_mingw.h>
   561           #ifdef __MINGW64_VERSION_MAJOR
   562           #include <intrin.h>
   563           #else
   564           #include <pmmintrin.h>
   565           #endif
   566           #else
   567           #include <pmmintrin.h>
   568           #endif
   569           #ifndef __SSE3__
   570           #error Assembler CPP flag not enabled
   571           #endif
   572           int main(int argc, char **argv) { }" HAVE_SSE3)
   573       if(HAVE_SSE3)
   574         list(APPEND EXTRA_CFLAGS "-msse3")
   575       endif()
   576       set(CMAKE_REQUIRED_FLAGS ${ORIG_CMAKE_REQUIRED_FLAGS})
   577     endif()
   578 
   579     if(NOT SSEMATH)
   580       if(SSE OR SSE2 OR SSE3)
   581         if(USE_GCC)
   582           check_c_compiler_flag(-mfpmath=387 HAVE_FP_387)
   583           if(HAVE_FP_387)
   584             list(APPEND EXTRA_CFLAGS "-mfpmath=387")
   585           endif()
   586         endif()
   587         set(HAVE_SSEMATH TRUE)
   588       endif()
   589     endif()
   590 
   591     check_include_file("immintrin.h" HAVE_IMMINTRIN_H)
   592 
   593     if(ALTIVEC)
   594       set(CMAKE_REQUIRED_FLAGS "-maltivec")
   595       check_c_source_compiles("
   596           #include <altivec.h>
   597           vector unsigned int vzero() {
   598               return vec_splat_u32(0);
   599           }
   600           int main(int argc, char **argv) { }" HAVE_ALTIVEC_H_HDR)
   601       check_c_source_compiles("
   602           vector unsigned int vzero() {
   603               return vec_splat_u32(0);
   604           }
   605           int main(int argc, char **argv) { }" HAVE_ALTIVEC)
   606       set(CMAKE_REQUIRED_FLAGS ${ORIG_CMAKE_REQUIRED_FLAGS})
   607       if(HAVE_ALTIVEC OR HAVE_ALTIVEC_H_HDR)
   608         set(HAVE_ALTIVEC TRUE) # if only HAVE_ALTIVEC_H_HDR is set
   609         list(APPEND EXTRA_CFLAGS "-maltivec")
   610         set(SDL_ALTIVEC_BLITTERS 1)
   611         if(HAVE_ALTIVEC_H_HDR)
   612           set(HAVE_ALTIVEC_H 1)
   613         endif()
   614       endif()
   615     endif()
   616   elseif(MSVC_VERSION GREATER 1500)
   617     # TODO: SDL_cpuinfo.h needs to support the user's configuration wish
   618     # for MSVC - right now it is always activated
   619     if(NOT ARCH_64)
   620       set(HAVE_MMX TRUE)
   621       set(HAVE_3DNOW TRUE)
   622     endif()
   623     set(HAVE_SSE TRUE)
   624     set(HAVE_SSE2 TRUE)
   625     set(HAVE_SSE3 TRUE)
   626     set(SDL_ASSEMBLY_ROUTINES 1)
   627   endif()
   628 # TODO:
   629 #else()
   630 #  if(USE_GCC OR USE_CLANG)
   631 #    list(APPEND EXTRA_CFLAGS "-mno-sse" "-mno-sse2" "-mno-sse3" "-mno-mmx")
   632 #  endif()
   633 endif()
   634 
   635 # TODO: Can't deactivate on FreeBSD? w/o LIBC, SDL_stdinc.h can't define
   636 # anything.
   637 if(LIBC)
   638   if(WINDOWS AND NOT MINGW)
   639     set(HAVE_LIBC TRUE)
   640     foreach(_HEADER stdio.h string.h wchar.h ctype.h math.h limits.h)
   641       string(TOUPPER "HAVE_${_HEADER}" _UPPER)
   642       string(REPLACE "." "_" _HAVE_H ${_UPPER})
   643       set(${_HAVE_H} 1)
   644     endforeach()
   645     set(HAVE_SIGNAL_H 1)
   646     foreach(_FN
   647             malloc calloc realloc free qsort abs memset memcpy memmove memcmp
   648             wcslen wcscmp
   649             strlen _strrev _strupr _strlwr strchr strrchr strstr itoa _ltoa
   650             _ultoa strtol strtoul strtoll strtod atoi atof strcmp strncmp
   651             _stricmp _strnicmp sscanf
   652             acos acosf asin asinf atan atanf atan2 atan2f ceil ceilf
   653             copysign copysignf cos cosf exp expf fabs fabsf floor floorf fmod fmodf
   654             log logf log10 log10f pow powf scalbn scalbnf sin sinf sqrt sqrtf tan tanf)
   655       string(TOUPPER ${_FN} _UPPER)
   656       set(HAVE_${_UPPER} 1)
   657     endforeach()
   658     if(NOT CYGWIN AND NOT MINGW)
   659       set(HAVE_ALLOCA 1)
   660     endif()
   661     set(HAVE_M_PI 1)
   662     add_definitions(-D_USE_MATH_DEFINES) # needed for M_PI
   663     set(STDC_HEADERS 1)
   664   else()
   665     set(HAVE_LIBC TRUE)
   666     check_include_file(sys/types.h HAVE_SYS_TYPES_H)
   667     foreach(_HEADER
   668             stdio.h stdlib.h stddef.h stdarg.h malloc.h memory.h string.h limits.h
   669             strings.h wchar.h inttypes.h stdint.h ctype.h math.h iconv.h signal.h libunwind.h)
   670       string(TOUPPER "HAVE_${_HEADER}" _UPPER)
   671       string(REPLACE "." "_" _HAVE_H ${_UPPER})
   672       check_include_file("${_HEADER}" ${_HAVE_H})
   673     endforeach()
   674 
   675     check_include_files("dlfcn.h;stdint.h;stddef.h;inttypes.h;stdlib.h;strings.h;string.h;float.h" STDC_HEADERS)
   676     check_type_size("size_t" SIZEOF_SIZE_T)
   677     check_symbol_exists(M_PI math.h HAVE_M_PI)
   678     # TODO: refine the mprotect check
   679     check_c_source_compiles("#include <sys/types.h>
   680                              #include <sys/mman.h>
   681                              int main() { }" HAVE_MPROTECT)
   682     foreach(_FN
   683             strtod malloc calloc realloc free getenv setenv putenv unsetenv
   684             qsort abs bcopy memset memcpy memmove memcmp strlen strlcpy strlcat
   685             _strrev _strupr _strlwr strchr strrchr strstr itoa _ltoa
   686             _uitoa _ultoa strtol strtoul _i64toa _ui64toa strtoll strtoull
   687             atoi atof strcmp strncmp _stricmp strcasecmp _strnicmp strncasecmp
   688             vsscanf vsnprintf fopen64 fseeko fseeko64 sigaction setjmp
   689             nanosleep sysconf sysctlbyname getauxval poll
   690             )
   691       string(TOUPPER ${_FN} _UPPER)
   692       set(_HAVEVAR "HAVE_${_UPPER}")
   693       check_function_exists("${_FN}" ${_HAVEVAR})
   694     endforeach()
   695 
   696     check_library_exists(m pow "" HAVE_LIBM)
   697     if(HAVE_LIBM)
   698       set(CMAKE_REQUIRED_LIBRARIES m)
   699       foreach(_FN
   700               atan atan2 ceil copysign cos cosf fabs floor log pow scalbn sin
   701               sinf sqrt sqrtf tan tanf acos asin)
   702         string(TOUPPER ${_FN} _UPPER)
   703         set(_HAVEVAR "HAVE_${_UPPER}")
   704         check_function_exists("${_FN}" ${_HAVEVAR})
   705       endforeach()
   706       set(CMAKE_REQUIRED_LIBRARIES)
   707       list(APPEND EXTRA_LIBS m)
   708     endif()
   709 
   710     check_library_exists(iconv iconv_open "" HAVE_LIBICONV)
   711     if(HAVE_LIBICONV)
   712       list(APPEND EXTRA_LIBS iconv)
   713       set(HAVE_ICONV 1)
   714     endif()
   715 
   716     if(NOT APPLE)
   717       check_include_file(alloca.h HAVE_ALLOCA_H)
   718       check_function_exists(alloca HAVE_ALLOCA)
   719     else()
   720       set(HAVE_ALLOCA_H 1)
   721       set(HAVE_ALLOCA 1)
   722     endif()
   723 
   724     check_struct_has_member("struct sigaction" "sa_sigaction" "signal.h" HAVE_SA_SIGACTION)
   725   endif()
   726 else()
   727   if(WINDOWS)
   728     set(HAVE_STDARG_H 1)
   729     set(HAVE_STDDEF_H 1)
   730   endif()
   731 endif()
   732 
   733 
   734 # Enable/disable various subsystems of the SDL library
   735 foreach(_SUB ${SDL_SUBSYSTEMS})
   736   string(TOUPPER ${_SUB} _OPT)
   737   if(NOT SDL_${_OPT})
   738     set(SDL_${_OPT}_DISABLED 1)
   739   endif()
   740 endforeach()
   741 if(SDL_JOYSTICK)
   742   file(GLOB JOYSTICK_SOURCES ${SDL2_SOURCE_DIR}/src/joystick/*.c)
   743   set(SOURCE_FILES ${SOURCE_FILES} ${JOYSTICK_SOURCES})
   744 endif()
   745 if(SDL_HAPTIC)
   746   if(NOT SDL_JOYSTICK)
   747     # Haptic requires some private functions from the joystick subsystem.
   748     message_error("SDL_HAPTIC requires SDL_JOYSTICK, which is not enabled")
   749   endif()
   750   file(GLOB HAPTIC_SOURCES ${SDL2_SOURCE_DIR}/src/haptic/*.c)
   751   set(SOURCE_FILES ${SOURCE_FILES} ${HAPTIC_SOURCES})
   752 endif()
   753 if(SDL_SENSOR)
   754   file(GLOB SENSOR_SOURCES ${SDL2_SOURCE_DIR}/src/sensor/*.c)
   755   set(SOURCE_FILES ${SOURCE_FILES} ${SENSOR_SOURCES})
   756 endif()
   757 if(SDL_POWER)
   758   file(GLOB POWER_SOURCES ${SDL2_SOURCE_DIR}/src/power/*.c)
   759   set(SOURCE_FILES ${SOURCE_FILES} ${POWER_SOURCES})
   760 endif()
   761 # TODO: in configure.in, the test for LOADSO and SDL_DLOPEN is a bit weird:
   762 # if LOADSO is not wanted, SDL_LOADSO_DISABLED is set
   763 # If however on Unix or APPLE dlopen() is detected via CheckDLOPEN(),
   764 # SDL_LOADSO_DISABLED will not be set, regardless of the LOADSO settings
   765 
   766 # General SDL subsystem options, valid for all platforms
   767 if(SDL_AUDIO)
   768   # CheckDummyAudio/CheckDiskAudio - valid for all platforms
   769   if(DUMMYAUDIO)
   770     set(SDL_AUDIO_DRIVER_DUMMY 1)
   771     file(GLOB DUMMYAUDIO_SOURCES ${SDL2_SOURCE_DIR}/src/audio/dummy/*.c)
   772     set(SOURCE_FILES ${SOURCE_FILES} ${DUMMYAUDIO_SOURCES})
   773     set(HAVE_DUMMYAUDIO TRUE)
   774   endif()
   775   if(DISKAUDIO)
   776     set(SDL_AUDIO_DRIVER_DISK 1)
   777     file(GLOB DISKAUDIO_SOURCES ${SDL2_SOURCE_DIR}/src/audio/disk/*.c)
   778     set(SOURCE_FILES ${SOURCE_FILES} ${DISKAUDIO_SOURCES})
   779     set(HAVE_DISKAUDIO TRUE)
   780   endif()
   781 endif()
   782 
   783 if(SDL_DLOPEN)
   784   # Relevant for Unix/Darwin only
   785   if(UNIX OR APPLE)
   786     CheckDLOPEN()
   787   endif()
   788 endif()
   789 
   790 if(SDL_VIDEO)
   791   if(VIDEO_DUMMY)
   792     set(SDL_VIDEO_DRIVER_DUMMY 1)
   793     file(GLOB VIDEO_DUMMY_SOURCES ${SDL2_SOURCE_DIR}/src/video/dummy/*.c)
   794     set(SOURCE_FILES ${SOURCE_FILES} ${VIDEO_DUMMY_SOURCES})
   795     set(HAVE_VIDEO_DUMMY TRUE)
   796     set(HAVE_SDL_VIDEO TRUE)
   797   endif()
   798 endif()
   799 
   800 if(ANDROID)
   801   file(GLOB ANDROID_CORE_SOURCES ${SDL2_SOURCE_DIR}/src/core/android/*.c)
   802   set(SOURCE_FILES ${SOURCE_FILES} ${ANDROID_CORE_SOURCES})
   803 
   804   # SDL_spinlock.c Needs to be compiled in ARM mode.
   805   # There seems to be no better way currently to set the ARM mode.
   806   # see: https://issuetracker.google.com/issues/62264618
   807   # Another option would be to set ARM mode to all compiled files
   808   check_c_compiler_flag(-marm HAVE_ARM_MODE)
   809   if(HAVE_ARM_MODE)
   810     set_source_files_properties(${SDL2_SOURCE_DIR}/src/atomic/SDL_spinlock.c PROPERTIES COMPILE_FLAGS -marm)
   811   endif()
   812 
   813   file(GLOB ANDROID_MAIN_SOURCES ${SDL2_SOURCE_DIR}/src/main/android/*.c)
   814   set(SDLMAIN_SOURCES ${SDLMAIN_SOURCES} ${ANDROID_MAIN_SOURCES})
   815 
   816   if(SDL_AUDIO)
   817     set(SDL_AUDIO_DRIVER_ANDROID 1)
   818     file(GLOB ANDROID_AUDIO_SOURCES ${SDL2_SOURCE_DIR}/src/audio/android/*.c)
   819     set(SOURCE_FILES ${SOURCE_FILES} ${ANDROID_AUDIO_SOURCES})
   820     set(HAVE_SDL_AUDIO TRUE)
   821   endif()
   822   if(SDL_FILESYSTEM)
   823     set(SDL_FILESYSTEM_ANDROID 1)
   824     file(GLOB ANDROID_FILESYSTEM_SOURCES ${SDL2_SOURCE_DIR}/src/filesystem/android/*.c)
   825     set(SOURCE_FILES ${SOURCE_FILES} ${ANDROID_FILESYSTEM_SOURCES})
   826     set(HAVE_SDL_FILESYSTEM TRUE)
   827   endif()
   828   if(SDL_HAPTIC)
   829     set(SDL_HAPTIC_ANDROID 1)
   830     file(GLOB ANDROID_HAPTIC_SOURCES ${SDL2_SOURCE_DIR}/src/haptic/android/*.c)
   831     set(SOURCE_FILES ${SOURCE_FILES} ${ANDROID_HAPTIC_SOURCES})
   832     set(HAVE_SDL_HAPTIC TRUE)
   833   endif()
   834   if(SDL_JOYSTICK)
   835     set(SDL_JOYSTICK_ANDROID 1)
   836     file(GLOB ANDROID_JOYSTICK_SOURCES ${SDL2_SOURCE_DIR}/src/joystick/android/*.c ${SDL2_SOURCE_DIR}/src/joystick/steam/*.c)
   837     set(SOURCE_FILES ${SOURCE_FILES} ${ANDROID_JOYSTICK_SOURCES})
   838     set(HAVE_SDL_JOYSTICK TRUE)
   839   endif()
   840   if(SDL_LOADSO)
   841     set(SDL_LOADSO_DLOPEN 1)
   842     file(GLOB LOADSO_SOURCES ${SDL2_SOURCE_DIR}/src/loadso/dlopen/*.c)
   843     set(SOURCE_FILES ${SOURCE_FILES} ${LOADSO_SOURCES})
   844     set(HAVE_SDL_LOADSO TRUE)
   845   endif()
   846   if(SDL_POWER)
   847     set(SDL_POWER_ANDROID 1)
   848     file(GLOB ANDROID_POWER_SOURCES ${SDL2_SOURCE_DIR}/src/power/android/*.c)
   849     set(SOURCE_FILES ${SOURCE_FILES} ${ANDROID_POWER_SOURCES})
   850     set(HAVE_SDL_POWER TRUE)
   851   endif()
   852   if(SDL_TIMERS)
   853     set(SDL_TIMER_UNIX 1)
   854     file(GLOB TIMER_SOURCES ${SDL2_SOURCE_DIR}/src/timer/unix/*.c)
   855     set(SOURCE_FILES ${SOURCE_FILES} ${TIMER_SOURCES})
   856     set(HAVE_SDL_TIMERS TRUE)
   857   endif()
   858   if(SDL_VIDEO)
   859     set(SDL_VIDEO_DRIVER_ANDROID 1)
   860     file(GLOB ANDROID_VIDEO_SOURCES ${SDL2_SOURCE_DIR}/src/video/android/*.c)
   861     set(SOURCE_FILES ${SOURCE_FILES} ${ANDROID_VIDEO_SOURCES})
   862     set(HAVE_SDL_VIDEO TRUE)
   863 
   864     # Core stuff
   865     find_library(ANDROID_DL_LIBRARY dl)
   866     find_library(ANDROID_LOG_LIBRARY log)
   867     find_library(ANDROID_LIBRARY_LIBRARY android)
   868     list(APPEND EXTRA_LIBS ${ANDROID_DL_LIBRARY} ${ANDROID_LOG_LIBRARY} ${ANDROID_LIBRARY_LIBRARY})
   869     add_definitions(-DGL_GLEXT_PROTOTYPES)
   870 
   871     #enable gles
   872     if(VIDEO_OPENGLES)
   873       set(SDL_VIDEO_OPENGL_EGL 1)
   874       set(HAVE_VIDEO_OPENGLES TRUE)
   875       set(SDL_VIDEO_OPENGL_ES2 1)
   876       set(SDL_VIDEO_RENDER_OGL_ES2 1)
   877 
   878       find_library(OpenGLES1_LIBRARY GLESv1_CM)
   879       find_library(OpenGLES2_LIBRARY GLESv2)
   880       list(APPEND EXTRA_LIBS ${OpenGLES1_LIBRARY} ${OpenGLES2_LIBRARY})
   881     endif()
   882 
   883     CHECK_C_SOURCE_COMPILES("
   884     #if defined(__ARM_ARCH) && __ARM_ARCH < 7
   885     #error Vulkan doesn't work on this configuration
   886     #endif
   887     int main()
   888     {
   889         return 0;
   890     }
   891     " VULKAN_PASSED_ANDROID_CHECKS)
   892     if(NOT VULKAN_PASSED_ANDROID_CHECKS)
   893       set(VIDEO_VULKAN OFF)
   894       message(STATUS "Vulkan doesn't work on this configuration")
   895     endif()
   896   endif()
   897 
   898   CheckPTHREAD()
   899 
   900 endif()
   901 
   902 # Platform-specific options and settings
   903 if(EMSCRIPTEN)
   904   # Hide noisy warnings that intend to aid mostly during initial stages of porting a new
   905   # project. Uncomment at will for verbose cross-compiling -I/../ path info.
   906   add_definitions(-Wno-warn-absolute-paths)
   907   if(SDL_AUDIO)
   908     set(SDL_AUDIO_DRIVER_EMSCRIPTEN 1)
   909     file(GLOB EM_AUDIO_SOURCES ${SDL2_SOURCE_DIR}/src/audio/emscripten/*.c)
   910     set(SOURCE_FILES ${SOURCE_FILES} ${EM_AUDIO_SOURCES})
   911     set(HAVE_SDL_AUDIO TRUE)
   912   endif()
   913   if(SDL_FILESYSTEM)
   914     set(SDL_FILESYSTEM_EMSCRIPTEN 1)
   915     file(GLOB EM_FILESYSTEM_SOURCES ${SDL2_SOURCE_DIR}/src/filesystem/emscripten/*.c)
   916     set(SOURCE_FILES ${SOURCE_FILES} ${EM_FILESYSTEM_SOURCES})
   917     set(HAVE_SDL_FILESYSTEM TRUE)
   918   endif()
   919   if(SDL_JOYSTICK)
   920     set(SDL_JOYSTICK_EMSCRIPTEN 1)
   921     file(GLOB EM_JOYSTICK_SOURCES ${SDL2_SOURCE_DIR}/src/joystick/emscripten/*.c)
   922     set(SOURCE_FILES ${SOURCE_FILES} ${EM_JOYSTICK_SOURCES})
   923     set(HAVE_SDL_JOYSTICK TRUE)
   924   endif()
   925   if(SDL_POWER)
   926     set(SDL_POWER_EMSCRIPTEN 1)
   927     file(GLOB EM_POWER_SOURCES ${SDL2_SOURCE_DIR}/src/power/emscripten/*.c)
   928     set(SOURCE_FILES ${SOURCE_FILES} ${EM_POWER_SOURCES})
   929     set(HAVE_SDL_POWER TRUE)
   930   endif()
   931   if(SDL_TIMERS)
   932     set(SDL_TIMER_UNIX 1)
   933     file(GLOB TIMER_SOURCES ${SDL2_SOURCE_DIR}/src/timer/unix/*.c)
   934     set(SOURCE_FILES ${SOURCE_FILES} ${TIMER_SOURCES})
   935     set(HAVE_SDL_TIMERS TRUE)
   936 
   937     if(CLOCK_GETTIME)
   938       set(HAVE_CLOCK_GETTIME 1)
   939     endif()
   940   endif()
   941   if(SDL_VIDEO)
   942     set(SDL_VIDEO_DRIVER_EMSCRIPTEN 1)
   943     file(GLOB EM_VIDEO_SOURCES ${SDL2_SOURCE_DIR}/src/video/emscripten/*.c)
   944     set(SOURCE_FILES ${SOURCE_FILES} ${EM_VIDEO_SOURCES})
   945     set(HAVE_SDL_VIDEO TRUE)
   946 
   947     #enable gles
   948     if(VIDEO_OPENGLES)
   949       set(SDL_VIDEO_OPENGL_EGL 1)
   950       set(HAVE_VIDEO_OPENGLES TRUE)
   951       set(SDL_VIDEO_OPENGL_ES2 1)
   952       set(SDL_VIDEO_RENDER_OGL_ES2 1)
   953     endif()
   954   endif()
   955 elseif(UNIX AND NOT APPLE AND NOT ANDROID)
   956   if(SDL_AUDIO)
   957     if(SYSV5 OR SOLARIS OR HPUX)
   958         set(SDL_AUDIO_DRIVER_SUNAUDIO 1)
   959         file(GLOB SUN_AUDIO_SOURCES ${SDL2_SOURCE_DIR}/src/audio/sun/*.c)
   960         set(SOURCE_FILES ${SOURCE_FILES} ${SUN_AUDIO_SOURCES})
   961         set(HAVE_SDL_AUDIO TRUE)
   962     elseif(NETBSD)
   963         set(SDL_AUDIO_DRIVER_NETBSD 1)
   964         file(GLOB NETBSD_AUDIO_SOURCES ${SDL2_SOURCE_DIR}/src/audio/netbsd/*.c)
   965         set(SOURCE_FILES ${SOURCE_FILES} ${NETBSD_AUDIO_SOURCES})
   966         set(HAVE_SDL_AUDIO TRUE)
   967     elseif(AIX)
   968         set(SDL_AUDIO_DRIVER_PAUDIO 1)
   969         file(GLOB AIX_AUDIO_SOURCES ${SDL2_SOURCE_DIR}/src/audio/paudio/*.c)
   970         set(SOURCE_FILES ${SOURCE_FILES} ${AIX_AUDIO_SOURCES})
   971         set(HAVE_SDL_AUDIO TRUE)
   972     endif()
   973     CheckOSS()
   974     CheckALSA()
   975     CheckJACK()
   976     CheckPulseAudio()
   977     CheckESD()
   978     CheckARTS()
   979     CheckNAS()
   980     CheckSNDIO()
   981     CheckFusionSound()
   982     CheckLibSampleRate()
   983   endif()
   984 
   985   if(SDL_VIDEO)
   986     # Need to check for Raspberry PI first and add platform specific compiler flags, otherwise the test for GLES fails!
   987     CheckRPI()
   988     CheckX11()
   989     CheckMir()
   990     CheckDirectFB()
   991     CheckOpenGLX11()
   992     CheckOpenGLESX11()
   993     CheckWayland()
   994     CheckVivante()
   995     CheckKMSDRM()
   996   endif()
   997 
   998   if(UNIX)
   999     file(GLOB CORE_UNIX_SOURCES ${SDL2_SOURCE_DIR}/src/core/unix/*.c)
  1000     set(SOURCE_FILES ${SOURCE_FILES} ${CORE_UNIX_SOURCES})
  1001   endif()
  1002 
  1003   if(LINUX)
  1004     check_c_source_compiles("
  1005         #include <linux/input.h>
  1006         #ifndef EVIOCGNAME
  1007         #error EVIOCGNAME() ioctl not available
  1008         #endif
  1009         int main(int argc, char** argv) {}" HAVE_INPUT_EVENTS)
  1010 
  1011     check_c_source_compiles("
  1012         #include <linux/kd.h>
  1013         #include <linux/keyboard.h>
  1014 
  1015         int main(int argc, char **argv)
  1016         {
  1017             struct kbentry kbe;
  1018             kbe.kb_table = KG_CTRL;
  1019             ioctl(0, KDGKBENT, &kbe);
  1020         }" HAVE_INPUT_KD)
  1021 
  1022     file(GLOB CORE_LINUX_SOURCES ${SDL2_SOURCE_DIR}/src/core/linux/*.c)
  1023     set(SOURCE_FILES ${SOURCE_FILES} ${CORE_LINUX_SOURCES})
  1024 
  1025     if(HAVE_INPUT_EVENTS)
  1026       set(SDL_INPUT_LINUXEV 1)
  1027     endif()
  1028 
  1029     if(SDL_HAPTIC AND HAVE_INPUT_EVENTS)
  1030       set(SDL_HAPTIC_LINUX 1)
  1031       file(GLOB HAPTIC_SOURCES ${SDL2_SOURCE_DIR}/src/haptic/linux/*.c)
  1032       set(SOURCE_FILES ${SOURCE_FILES} ${HAPTIC_SOURCES})
  1033       set(HAVE_SDL_HAPTIC TRUE)
  1034     endif()
  1035 
  1036     if(HAVE_INPUT_KD)
  1037       set(SDL_INPUT_LINUXKD 1)
  1038     endif()
  1039 
  1040     check_include_file("libudev.h" HAVE_LIBUDEV_H)
  1041 
  1042     if(PKG_CONFIG_FOUND)
  1043       pkg_search_module(DBUS dbus-1 dbus)
  1044       if(DBUS_FOUND)
  1045         set(HAVE_DBUS_DBUS_H TRUE)
  1046         include_directories(${DBUS_INCLUDE_DIRS})
  1047         list(APPEND EXTRA_LIBS ${DBUS_LIBRARIES})
  1048       endif()
  1049 
  1050       pkg_search_module(IBUS ibus-1.0 ibus)
  1051       if(IBUS_FOUND)
  1052         set(HAVE_IBUS_IBUS_H TRUE)
  1053         include_directories(${IBUS_INCLUDE_DIRS})
  1054         list(APPEND EXTRA_LIBS ${IBUS_LIBRARIES})
  1055       endif()
  1056     endif()
  1057 
  1058     check_include_file("fcitx/frontend.h" HAVE_FCITX_FRONTEND_H)
  1059   endif()
  1060 
  1061   if(INPUT_TSLIB)
  1062     check_c_source_compiles("
  1063         #include \"tslib.h\"
  1064         int main(int argc, char** argv) { }" HAVE_INPUT_TSLIB)
  1065     if(HAVE_INPUT_TSLIB)
  1066       set(SDL_INPUT_TSLIB 1)
  1067       list(APPEND EXTRA_LIBS ts)
  1068     endif()
  1069   endif()
  1070 
  1071   if(SDL_JOYSTICK)
  1072     CheckUSBHID()   # seems to be BSD specific - limit the test to BSD only?
  1073     if(LINUX AND NOT ANDROID)
  1074       set(SDL_JOYSTICK_LINUX 1)
  1075       file(GLOB JOYSTICK_SOURCES ${SDL2_SOURCE_DIR}/src/joystick/linux/*.c ${SDL2_SOURCE_DIR}/src/joystick/steam/*.c)
  1076       set(SOURCE_FILES ${SOURCE_FILES} ${JOYSTICK_SOURCES})
  1077       set(HAVE_SDL_JOYSTICK TRUE)
  1078     endif()
  1079   endif()
  1080 
  1081   CheckPTHREAD()
  1082 
  1083   if(CLOCK_GETTIME)
  1084     check_library_exists(rt clock_gettime "" FOUND_CLOCK_GETTIME)
  1085     if(FOUND_CLOCK_GETTIME)
  1086       list(APPEND EXTRA_LIBS rt)
  1087       set(HAVE_CLOCK_GETTIME 1)
  1088     else()
  1089       check_library_exists(c clock_gettime "" FOUND_CLOCK_GETTIME)
  1090       if(FOUND_CLOCK_GETTIME)
  1091         set(HAVE_CLOCK_GETTIME 1)
  1092       endif()
  1093     endif()
  1094   endif()
  1095 
  1096   check_include_file(linux/version.h HAVE_LINUX_VERSION_H)
  1097   if(HAVE_LINUX_VERSION_H)
  1098     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -DHAVE_LINUX_VERSION_H")
  1099   endif()
  1100 
  1101   if(SDL_POWER)
  1102     if(LINUX)
  1103       set(SDL_POWER_LINUX 1)
  1104       file(GLOB POWER_SOURCES ${SDL2_SOURCE_DIR}/src/power/linux/*.c)
  1105       set(SOURCE_FILES ${SOURCE_FILES} ${POWER_SOURCES})
  1106       set(HAVE_SDL_POWER TRUE)
  1107     endif()
  1108   endif()
  1109 
  1110   if(SDL_FILESYSTEM)
  1111     set(SDL_FILESYSTEM_UNIX 1)
  1112     file(GLOB FILESYSTEM_SOURCES ${SDL2_SOURCE_DIR}/src/filesystem/unix/*.c)
  1113     set(SOURCE_FILES ${SOURCE_FILES} ${FILESYSTEM_SOURCES})
  1114     set(HAVE_SDL_FILESYSTEM TRUE)
  1115   endif()
  1116 
  1117   if(SDL_TIMERS)
  1118     set(SDL_TIMER_UNIX 1)
  1119     file(GLOB TIMER_SOURCES ${SDL2_SOURCE_DIR}/src/timer/unix/*.c)
  1120     set(SOURCE_FILES ${SOURCE_FILES} ${TIMER_SOURCES})
  1121     set(HAVE_SDL_TIMERS TRUE)
  1122   endif()
  1123 
  1124   if(RPATH)
  1125     set(SDL_RLD_FLAGS "")
  1126     if(BSDI OR FREEBSD OR LINUX OR NETBSD)
  1127       set(CMAKE_REQUIRED_FLAGS "-Wl,--enable-new-dtags")
  1128       check_c_compiler_flag("" HAVE_ENABLE_NEW_DTAGS)
  1129       set(CMAKE_REQUIRED_FLAGS ${ORIG_CMAKE_REQUIRED_FLAGS})
  1130       if(HAVE_ENABLE_NEW_DTAGS)
  1131         set(SDL_RLD_FLAGS "-Wl,-rpath,\${libdir} -Wl,--enable-new-dtags")
  1132       else()
  1133         set(SDL_RLD_FLAGS "-Wl,-rpath,\${libdir}")
  1134       endif()
  1135     elseif(SOLARIS)
  1136       set(SDL_RLD_FLAGS "-R\${libdir}")
  1137     endif()
  1138     set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
  1139     set(HAVE_RPATH TRUE)
  1140   endif()
  1141 
  1142 elseif(WINDOWS)
  1143   find_program(WINDRES windres)
  1144 
  1145   check_c_source_compiles("
  1146     #include <windows.h>
  1147     int main(int argc, char **argv) { }" HAVE_WIN32_CC)
  1148 
  1149   file(GLOB CORE_SOURCES ${SDL2_SOURCE_DIR}/src/core/windows/*.c)
  1150   set(SOURCE_FILES ${SOURCE_FILES} ${CORE_SOURCES})
  1151 
  1152   if(MSVC)
  1153     # Prevent codegen that would use the VC runtime libraries.
  1154     set_property(DIRECTORY . APPEND PROPERTY COMPILE_OPTIONS "/GS-")
  1155     if(NOT ARCH_64)
  1156       set_property(DIRECTORY . APPEND PROPERTY COMPILE_OPTIONS "/arch:SSE")
  1157     endif()
  1158   endif()
  1159 
  1160   # Check for DirectX
  1161   if(DIRECTX)
  1162     if(DEFINED MSVC_VERSION AND NOT ${MSVC_VERSION} LESS 1700)
  1163         set(USE_WINSDK_DIRECTX TRUE)
  1164     endif()
  1165     if(NOT CMAKE_COMPILER_IS_MINGW AND NOT USE_WINSDK_DIRECTX)
  1166       if("$ENV{DXSDK_DIR}" STREQUAL "")
  1167         message_error("DIRECTX requires the \$DXSDK_DIR environment variable to be set")
  1168       endif()
  1169       set(CMAKE_REQUIRED_FLAGS "/I\"$ENV{DXSDK_DIR}\\Include\"")
  1170     endif()
  1171 
  1172     if(HAVE_WIN32_CC)
  1173       # xinput.h may need windows.h, but doesn't include it itself.
  1174       check_c_source_compiles("
  1175         #include <windows.h>
  1176         #include <xinput.h>
  1177         int main(int argc, char **argv) { }" HAVE_XINPUT_H)
  1178       check_c_source_compiles("
  1179         #include <windows.h>
  1180         #include <xinput.h>
  1181         XINPUT_GAMEPAD_EX x1;
  1182         int main(int argc, char **argv) { }" HAVE_XINPUT_GAMEPAD_EX)
  1183       check_c_source_compiles("
  1184         #include <windows.h>
  1185         #include <xinput.h>
  1186         XINPUT_STATE_EX s1;
  1187         int main(int argc, char **argv) { }" HAVE_XINPUT_STATE_EX)
  1188     else()
  1189       check_include_file(xinput.h HAVE_XINPUT_H)
  1190     endif()
  1191 
  1192     check_include_file(d3d9.h HAVE_D3D_H)
  1193     check_include_file(d3d11_1.h HAVE_D3D11_H)
  1194     check_include_file(ddraw.h HAVE_DDRAW_H)
  1195     check_include_file(dsound.h HAVE_DSOUND_H)
  1196     check_include_file(dinput.h HAVE_DINPUT_H)
  1197     check_include_file(mmdeviceapi.h HAVE_MMDEVICEAPI_H)
  1198     check_include_file(audioclient.h HAVE_AUDIOCLIENT_H)
  1199     check_include_file(dxgi.h HAVE_DXGI_H)
  1200     if(HAVE_D3D_H OR HAVE_D3D11_H OR HAVE_DDRAW_H OR HAVE_DSOUND_H OR HAVE_DINPUT_H)
  1201       set(HAVE_DIRECTX TRUE)
  1202       if(NOT CMAKE_COMPILER_IS_MINGW AND NOT USE_WINSDK_DIRECTX)
  1203       # TODO: change $ENV{DXSDL_DIR} to get the path from the include checks
  1204         link_directories($ENV{DXSDK_DIR}\\lib\\${PROCESSOR_ARCH})
  1205         include_directories($ENV{DXSDK_DIR}\\Include)
  1206       endif()
  1207     endif()
  1208     set(CMAKE_REQUIRED_FLAGS ${ORIG_CMAKE_REQUIRED_FLAGS})
  1209   endif()
  1210 
  1211   if(SDL_AUDIO)
  1212     set(SDL_AUDIO_DRIVER_WINMM 1)
  1213     file(GLOB WINMM_AUDIO_SOURCES ${SDL2_SOURCE_DIR}/src/audio/winmm/*.c)
  1214     set(SOURCE_FILES ${SOURCE_FILES} ${WINMM_AUDIO_SOURCES})
  1215     set(HAVE_SDL_AUDIO TRUE)
  1216 
  1217     if(HAVE_DSOUND_H)
  1218       set(SDL_AUDIO_DRIVER_DSOUND 1)
  1219       file(GLOB DSOUND_AUDIO_SOURCES ${SDL2_SOURCE_DIR}/src/audio/directsound/*.c)
  1220       set(SOURCE_FILES ${SOURCE_FILES} ${DSOUND_AUDIO_SOURCES})
  1221     endif()
  1222 
  1223     if(WASAPI AND HAVE_AUDIOCLIENT_H AND HAVE_MMDEVICEAPI_H)
  1224       set(SDL_AUDIO_DRIVER_WASAPI 1)
  1225       file(GLOB WASAPI_AUDIO_SOURCES ${SDL2_SOURCE_DIR}/src/audio/wasapi/*.c)
  1226       set(SOURCE_FILES ${SOURCE_FILES} ${WASAPI_AUDIO_SOURCES})
  1227     endif()
  1228   endif()
  1229 
  1230   if(SDL_VIDEO)
  1231     # requires SDL_LOADSO on Windows (IME, DX, etc.)
  1232     if(NOT SDL_LOADSO)
  1233       message_error("SDL_VIDEO requires SDL_LOADSO, which is not enabled")
  1234     endif()
  1235     set(SDL_VIDEO_DRIVER_WINDOWS 1)
  1236     file(GLOB WIN_VIDEO_SOURCES ${SDL2_SOURCE_DIR}/src/video/windows/*.c)
  1237     set(SOURCE_FILES ${SOURCE_FILES} ${WIN_VIDEO_SOURCES})
  1238 
  1239     if(RENDER_D3D AND HAVE_D3D_H)
  1240       set(SDL_VIDEO_RENDER_D3D 1)
  1241       set(HAVE_RENDER_D3D TRUE)
  1242     endif()
  1243     if(RENDER_D3D AND HAVE_D3D11_H)
  1244       set(SDL_VIDEO_RENDER_D3D11 1)
  1245       set(HAVE_RENDER_D3D TRUE)
  1246     endif()
  1247     set(HAVE_SDL_VIDEO TRUE)
  1248   endif()
  1249 
  1250   if(SDL_THREADS)
  1251     set(SDL_THREAD_WINDOWS 1)
  1252     set(SOURCE_FILES ${SOURCE_FILES}
  1253       ${SDL2_SOURCE_DIR}/src/thread/windows/SDL_sysmutex.c
  1254       ${SDL2_SOURCE_DIR}/src/thread/windows/SDL_syssem.c
  1255       ${SDL2_SOURCE_DIR}/src/thread/windows/SDL_systhread.c
  1256       ${SDL2_SOURCE_DIR}/src/thread/windows/SDL_systls.c
  1257       ${SDL2_SOURCE_DIR}/src/thread/generic/SDL_syscond.c)
  1258     set(HAVE_SDL_THREADS TRUE)
  1259   endif()
  1260 
  1261   if(SDL_POWER)
  1262     set(SDL_POWER_WINDOWS 1)
  1263     set(SOURCE_FILES ${SOURCE_FILES} ${SDL2_SOURCE_DIR}/src/power/windows/SDL_syspower.c)
  1264     set(HAVE_SDL_POWER TRUE)
  1265   endif()
  1266 
  1267   if(SDL_FILESYSTEM)
  1268     set(SDL_FILESYSTEM_WINDOWS 1)
  1269     file(GLOB FILESYSTEM_SOURCES ${SDL2_SOURCE_DIR}/src/filesystem/windows/*.c)
  1270     set(SOURCE_FILES ${SOURCE_FILES} ${FILESYSTEM_SOURCES})
  1271     set(HAVE_SDL_FILESYSTEM TRUE)
  1272   endif()
  1273 
  1274   # Libraries for Win32 native and MinGW
  1275   list(APPEND EXTRA_LIBS user32 gdi32 winmm imm32 ole32 oleaut32 version uuid advapi32 shell32)
  1276 
  1277   # TODO: in configure.in the check for timers is set on
  1278   # cygwin | mingw32* - does this include mingw32CE?
  1279   if(SDL_TIMERS)
  1280     set(SDL_TIMER_WINDOWS 1)
  1281     file(GLOB TIMER_SOURCES ${SDL2_SOURCE_DIR}/src/timer/windows/*.c)
  1282     set(SOURCE_FILES ${SOURCE_FILES} ${TIMER_SOURCES})
  1283     set(HAVE_SDL_TIMERS TRUE)
  1284   endif()
  1285 
  1286   if(SDL_LOADSO)
  1287     set(SDL_LOADSO_WINDOWS 1)
  1288     file(GLOB LOADSO_SOURCES ${SDL2_SOURCE_DIR}/src/loadso/windows/*.c)
  1289     set(SOURCE_FILES ${SOURCE_FILES} ${LOADSO_SOURCES})
  1290     set(HAVE_SDL_LOADSO TRUE)
  1291   endif()
  1292 
  1293   file(GLOB CORE_SOURCES ${SDL2_SOURCE_DIR}/src/core/windows/*.c)
  1294   set(SOURCE_FILES ${SOURCE_FILES} ${CORE_SOURCES})
  1295 
  1296   if(SDL_VIDEO)
  1297     if(VIDEO_OPENGL)
  1298       set(SDL_VIDEO_OPENGL 1)
  1299       set(SDL_VIDEO_OPENGL_WGL 1)
  1300       set(SDL_VIDEO_RENDER_OGL 1)
  1301       set(HAVE_VIDEO_OPENGL TRUE)
  1302     endif()
  1303 
  1304     if(VIDEO_OPENGLES)
  1305       set(SDL_VIDEO_OPENGL_EGL 1)
  1306       set(SDL_VIDEO_OPENGL_ES2 1)
  1307       set(SDL_VIDEO_RENDER_OGL_ES2 1)
  1308       set(HAVE_VIDEO_OPENGLES TRUE)
  1309     endif()
  1310   endif()
  1311 
  1312   if(SDL_JOYSTICK)
  1313     file(GLOB JOYSTICK_SOURCES ${SDL2_SOURCE_DIR}/src/joystick/windows/*.c)
  1314     set(SOURCE_FILES ${SOURCE_FILES} ${JOYSTICK_SOURCES})
  1315     if(HAVE_DINPUT_H)
  1316       set(SDL_JOYSTICK_DINPUT 1)
  1317       list(APPEND EXTRA_LIBS dinput8)
  1318       if(CMAKE_COMPILER_IS_MINGW)
  1319         list(APPEND EXTRA_LIBS dxerr8)
  1320       elseif (NOT USE_WINSDK_DIRECTX)
  1321         list(APPEND EXTRA_LIBS dxerr)
  1322       endif()
  1323     endif()
  1324     if(HAVE_XINPUT_H)
  1325       set(SDL_JOYSTICK_XINPUT 1)
  1326     endif()
  1327     if(NOT HAVE_DINPUT_H AND NOT HAVE_XINPUT_H)
  1328       set(SDL_JOYSTICK_WINMM 1)
  1329     endif()
  1330     set(HAVE_SDL_JOYSTICK TRUE)
  1331 
  1332     if(SDL_HAPTIC)
  1333       if(HAVE_DINPUT_H OR HAVE_XINPUT_H)
  1334         file(GLOB HAPTIC_SOURCES ${SDL2_SOURCE_DIR}/src/haptic/windows/*.c)
  1335         if(HAVE_DINPUT_H)
  1336           set(SDL_HAPTIC_DINPUT 1)
  1337         endif()
  1338         if(HAVE_XINPUT_H)
  1339           set(SDL_HAPTIC_XINPUT 1)
  1340         endif()
  1341       else()
  1342         file(GLOB HAPTIC_SOURCES ${SDL2_SOURCE_DIR}/src/haptic/dummy/*.c)
  1343         set(SDL_HAPTIC_DUMMY 1)
  1344       endif()
  1345       set(SOURCE_FILES ${SOURCE_FILES} ${HAPTIC_SOURCES})
  1346       set(HAVE_SDL_HAPTIC TRUE)
  1347     endif()
  1348   endif()
  1349 
  1350   file(GLOB VERSION_SOURCES ${SDL2_SOURCE_DIR}/src/main/windows/*.rc)
  1351   file(GLOB SDLMAIN_SOURCES ${SDL2_SOURCE_DIR}/src/main/windows/*.c)
  1352   if(MINGW OR CYGWIN)
  1353     list(APPEND EXTRA_LIBS mingw32)
  1354     list(APPEND EXTRA_LDFLAGS "-mwindows")
  1355     set(SDL_CFLAGS "${SDL_CFLAGS} -Dmain=SDL_main")
  1356     list(APPEND SDL_LIBS "-lmingw32" "-lSDL2main" "-mwindows")
  1357   endif()
  1358 elseif(APPLE)
  1359   # TODO: rework this all for proper MacOS X, iOS and Darwin support
  1360 
  1361   # We always need these libs on macOS at the moment.
  1362   # !!! FIXME: we need Carbon for some very old API calls in
  1363   # !!! FIXME:  src/video/cocoa/SDL_cocoakeyboard.c, but we should figure out
  1364   # !!! FIXME:  how to dump those.
  1365   if(NOT IOS)
  1366     set(SDL_FRAMEWORK_COCOA 1)
  1367     set(SDL_FRAMEWORK_CARBON 1)
  1368   endif()
  1369 
  1370   # Requires the darwin file implementation
  1371   if(SDL_FILE)
  1372     file(GLOB EXTRA_SOURCES ${SDL2_SOURCE_DIR}/src/file/cocoa/*.m)
  1373     set(SOURCE_FILES ${EXTRA_SOURCES} ${SOURCE_FILES})
  1374     # !!! FIXME: modern CMake doesn't need "LANGUAGE C" for Objective-C.
  1375     set_source_files_properties(${EXTRA_SOURCES} PROPERTIES LANGUAGE C)
  1376     set(HAVE_SDL_FILE TRUE)
  1377     # !!! FIXME: why is COREVIDEO inside this if() block?
  1378     set(SDL_FRAMEWORK_COREVIDEO 1)
  1379   else()
  1380     message_error("SDL_FILE must be enabled to build on MacOS X")
  1381   endif()
  1382 
  1383   if(SDL_AUDIO)
  1384     set(SDL_AUDIO_DRIVER_COREAUDIO 1)
  1385     file(GLOB AUDIO_SOURCES ${SDL2_SOURCE_DIR}/src/audio/coreaudio/*.m)
  1386     # !!! FIXME: modern CMake doesn't need "LANGUAGE C" for Objective-C.
  1387     set_source_files_properties(${AUDIO_SOURCES} PROPERTIES LANGUAGE C)
  1388     set(SOURCE_FILES ${SOURCE_FILES} ${AUDIO_SOURCES})
  1389     set(HAVE_SDL_AUDIO TRUE)
  1390     set(SDL_FRAMEWORK_COREAUDIO 1)
  1391     set(SDL_FRAMEWORK_AUDIOTOOLBOX 1)
  1392   endif()
  1393 
  1394   if(SDL_JOYSTICK)
  1395     set(SDL_JOYSTICK_IOKIT 1)
  1396     if (IOS)
  1397       file(GLOB JOYSTICK_SOURCES ${SDL2_SOURCE_DIR}/src/joystick/iphoneos/*.m ${SDL2_SOURCE_DIR}/src/joystick/steam/*.c)
  1398     else()
  1399       file(GLOB JOYSTICK_SOURCES ${SDL2_SOURCE_DIR}/src/joystick/darwin/*.c)
  1400     endif()
  1401     set(SOURCE_FILES ${SOURCE_FILES} ${JOYSTICK_SOURCES})
  1402     set(HAVE_SDL_JOYSTICK TRUE)
  1403     set(SDL_FRAMEWORK_IOKIT 1)
  1404     set(SDL_FRAMEWORK_FF 1)
  1405   endif()
  1406 
  1407   if(SDL_HAPTIC)
  1408     set(SDL_HAPTIC_IOKIT 1)
  1409     if (IOS)
  1410       file(GLOB HAPTIC_SOURCES ${SDL2_SOURCE_DIR}/src/haptic/dummy/*.c)
  1411       set(SDL_HAPTIC_DUMMY 1)
  1412     else()
  1413       file(GLOB HAPTIC_SOURCES ${SDL2_SOURCE_DIR}/src/haptic/darwin/*.c)
  1414     endif()
  1415     set(SOURCE_FILES ${SOURCE_FILES} ${HAPTIC_SOURCES})
  1416     set(HAVE_SDL_HAPTIC TRUE)
  1417     set(SDL_FRAMEWORK_IOKIT 1)
  1418     set(SDL_FRAMEWORK_FF 1)
  1419     if(NOT SDL_JOYSTICK)
  1420       message(FATAL_ERROR "SDL_HAPTIC requires SDL_JOYSTICK to be enabled")
  1421     endif()
  1422   endif()
  1423 
  1424   if(SDL_POWER)
  1425     set(SDL_POWER_MACOSX 1)
  1426     if (IOS)
  1427       file(GLOB POWER_SOURCES ${SDL2_SOURCE_DIR}/src/power/uikit/*.m)
  1428     else()
  1429       file(GLOB POWER_SOURCES ${SDL2_SOURCE_DIR}/src/power/macosx/*.c)
  1430     endif()
  1431     set(SOURCE_FILES ${SOURCE_FILES} ${POWER_SOURCES})
  1432     set(HAVE_SDL_POWER TRUE)
  1433     set(SDL_FRAMEWORK_IOKIT 1)
  1434   endif()
  1435 
  1436   if(SDL_TIMERS)
  1437     set(SDL_TIMER_UNIX 1)
  1438     file(GLOB TIMER_SOURCES ${SDL2_SOURCE_DIR}/src/timer/unix/*.c)
  1439     set(SOURCE_FILES ${SOURCE_FILES} ${TIMER_SOURCES})
  1440     set(HAVE_SDL_TIMERS TRUE)
  1441   endif(SDL_TIMERS)
  1442 
  1443   if(SDL_FILESYSTEM)
  1444     set(SDL_FILESYSTEM_COCOA 1)
  1445     file(GLOB FILESYSTEM_SOURCES ${SDL2_SOURCE_DIR}/src/filesystem/cocoa/*.m)
  1446     # !!! FIXME: modern CMake doesn't need "LANGUAGE C" for Objective-C.
  1447     set_source_files_properties(${FILESYSTEM_SOURCES} PROPERTIES LANGUAGE C)
  1448     set(SOURCE_FILES ${SOURCE_FILES} ${FILESYSTEM_SOURCES})
  1449     set(HAVE_SDL_FILESYSTEM TRUE)
  1450   endif()
  1451 
  1452   # Actually load the frameworks at the end so we don't duplicate include.
  1453   if(SDL_FRAMEWORK_COREVIDEO)
  1454     find_library(COREVIDEO CoreVideo)
  1455     list(APPEND EXTRA_LIBS ${COREVIDEO})
  1456   endif()
  1457   if(SDL_FRAMEWORK_COCOA)
  1458     find_library(COCOA_LIBRARY Cocoa)
  1459     list(APPEND EXTRA_LIBS ${COCOA_LIBRARY})
  1460   endif()
  1461   if(SDL_FRAMEWORK_IOKIT)
  1462     find_library(IOKIT IOKit)
  1463     list(APPEND EXTRA_LIBS ${IOKIT})
  1464   endif()
  1465   if(SDL_FRAMEWORK_FF)
  1466     find_library(FORCEFEEDBACK ForceFeedback)
  1467     list(APPEND EXTRA_LIBS ${FORCEFEEDBACK})
  1468   endif()
  1469   if(SDL_FRAMEWORK_CARBON)
  1470     find_library(CARBON_LIBRARY Carbon)
  1471     list(APPEND EXTRA_LIBS ${CARBON_LIBRARY})
  1472   endif()
  1473   if(SDL_FRAMEWORK_COREAUDIO)
  1474     find_library(COREAUDIO CoreAudio)
  1475     list(APPEND EXTRA_LIBS ${COREAUDIO})
  1476   endif()
  1477   if(SDL_FRAMEWORK_AUDIOTOOLBOX)
  1478     find_library(AUDIOTOOLBOX AudioToolbox)
  1479     list(APPEND EXTRA_LIBS ${AUDIOTOOLBOX})
  1480   endif()
  1481 
  1482   # iOS hack needed - http://code.google.com/p/ios-cmake/ ?
  1483   if(SDL_VIDEO)
  1484     if (IOS)
  1485       set(SDL_VIDEO_DRIVER_UIKIT 1)
  1486       file(GLOB UIKITVIDEO_SOURCES ${SDL2_SOURCE_DIR}/src/video/uikit/*.m)
  1487       set(SOURCE_FILES ${SOURCE_FILES} ${UIKITVIDEO_SOURCES})
  1488     else()
  1489       CheckCOCOA()
  1490       if(VIDEO_OPENGL)
  1491         set(SDL_VIDEO_OPENGL 1)
  1492         set(SDL_VIDEO_OPENGL_CGL 1)
  1493         set(SDL_VIDEO_RENDER_OGL 1)
  1494         set(HAVE_VIDEO_OPENGL TRUE)
  1495       endif()
  1496 
  1497       if(VIDEO_OPENGLES)
  1498         set(SDL_VIDEO_OPENGL_EGL 1)
  1499         set(SDL_VIDEO_OPENGL_ES2 1)
  1500         set(SDL_VIDEO_RENDER_OGL_ES2 1)
  1501         set(HAVE_VIDEO_OPENGLES TRUE)
  1502       endif()
  1503     endif()
  1504   endif()
  1505 
  1506   CheckPTHREAD()
  1507 elseif(HAIKU)
  1508   if(SDL_VIDEO)
  1509     set(SDL_VIDEO_DRIVER_HAIKU 1)
  1510     file(GLOB HAIKUVIDEO_SOURCES ${SDL2_SOURCE_DIR}/src/video/haiku/*.c)
  1511     set(SOURCE_FILES ${SOURCE_FILES} ${HAIKUVIDEO_SOURCES})
  1512     set(HAVE_SDL_VIDEO TRUE)
  1513 
  1514     set(SDL_FILESYSTEM_HAIKU 1)
  1515     file(GLOB FILESYSTEM_SOURCES ${SDL2_SOURCE_DIR}/src/filesystem/haiku/*.cc)
  1516     set(SOURCE_FILES ${SOURCE_FILES} ${FILESYSTEM_SOURCES})
  1517     set(HAVE_SDL_FILESYSTEM TRUE)
  1518 
  1519     if(SDL_TIMERS)
  1520       set(SDL_TIMER_HAIKU 1)
  1521       file(GLOB TIMER_SOURCES ${SDL2_SOURCE_DIR}/src/timer/haiku/*.c)
  1522       set(SOURCE_FILES ${SOURCE_FILES} ${TIMER_SOURCES})
  1523       set(HAVE_SDL_TIMERS TRUE)
  1524     endif(SDL_TIMERS)
  1525 
  1526     if(VIDEO_OPENGL)
  1527       # TODO: Use FIND_PACKAGE(OpenGL) instead
  1528       set(SDL_VIDEO_OPENGL 1)
  1529       set(SDL_VIDEO_OPENGL_BGL 1)
  1530       set(SDL_VIDEO_RENDER_OGL 1)
  1531       list(APPEND EXTRA_LIBS GL)
  1532       set(HAVE_VIDEO_OPENGL TRUE)
  1533     endif()
  1534   endif()
  1535 
  1536   CheckPTHREAD()
  1537 endif()
  1538 
  1539 if(VIDEO_VULKAN)
  1540   set(SDL_VIDEO_VULKAN 1)
  1541 endif()
  1542 
  1543 # Dummies
  1544 # configure.in does it differently:
  1545 # if not have X
  1546 #   if enable_X {  SDL_X_DISABLED = 1 }
  1547 #   [add dummy sources]
  1548 # so it always adds a dummy, without checking, if it was actually requested.
  1549 # This leads to missing internal references on building, since the
  1550 # src/X/*.c does not get included.
  1551 if(NOT HAVE_SDL_JOYSTICK)
  1552   set(SDL_JOYSTICK_DISABLED 1)
  1553   if(SDL_JOYSTICK AND NOT APPLE) # results in unresolved symbols on OSX
  1554 
  1555     file(GLOB JOYSTICK_SOURCES ${SDL2_SOURCE_DIR}/src/joystick/dummy/*.c)
  1556     set(SOURCE_FILES ${SOURCE_FILES} ${JOYSTICK_SOURCES})
  1557   endif()
  1558 endif()
  1559 if(NOT HAVE_SDL_HAPTIC)
  1560   set(SDL_HAPTIC_DISABLED 1)
  1561   file(GLOB HAPTIC_SOURCES ${SDL2_SOURCE_DIR}/src/haptic/dummy/*.c)
  1562   set(SOURCE_FILES ${SOURCE_FILES} ${HAPTIC_SOURCES})
  1563 endif()
  1564 if(NOT HAVE_SDL_LOADSO)
  1565   set(SDL_LOADSO_DISABLED 1)
  1566   file(GLOB LOADSO_SOURCES ${SDL2_SOURCE_DIR}/src/loadso/dummy/*.c)
  1567   set(SOURCE_FILES ${SOURCE_FILES} ${LOADSO_SOURCES})
  1568 endif()
  1569 if(NOT HAVE_SDL_FILESYSTEM)
  1570   set(SDL_FILESYSTEM_DISABLED 1)
  1571   file(GLOB FILESYSTEM_SOURCES ${SDL2_SOURCE_DIR}/src/filesystem/dummy/*.c)
  1572   set(SOURCE_FILES ${SOURCE_FILES} ${FILESYSTEM_SOURCES})
  1573 endif()
  1574 
  1575 # We always need to have threads and timers around
  1576 if(NOT HAVE_SDL_THREADS)
  1577   set(SDL_THREADS_DISABLED 1)
  1578   file(GLOB THREADS_SOURCES ${SDL2_SOURCE_DIR}/src/thread/generic/*.c)
  1579   set(SOURCE_FILES ${SOURCE_FILES} ${THREADS_SOURCES})
  1580 endif()
  1581 if(NOT HAVE_SDL_TIMERS)
  1582   set(SDL_TIMERS_DISABLED 1)
  1583   file(GLOB TIMER_SOURCES ${SDL2_SOURCE_DIR}/src/timer/dummy/*.c)
  1584   set(SOURCE_FILES ${SOURCE_FILES} ${TIMER_SOURCES})
  1585 endif()
  1586 
  1587 if(NOT SDLMAIN_SOURCES)
  1588   file(GLOB SDLMAIN_SOURCES ${SDL2_SOURCE_DIR}/src/main/dummy/*.c)
  1589 endif()
  1590 
  1591 # Append the -MMD -MT flags
  1592 # if(DEPENDENCY_TRACKING)
  1593 #   if(COMPILER_IS_GNUCC)
  1594 #     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -MMD -MT \$@")
  1595 #   endif()
  1596 # endif()
  1597 
  1598 configure_file("${SDL2_SOURCE_DIR}/include/SDL_config.h.cmake"
  1599   "${SDL2_BINARY_DIR}/include/SDL_config.h")
  1600 
  1601 # Prepare the flags and remove duplicates
  1602 if(EXTRA_LDFLAGS)
  1603   list(REMOVE_DUPLICATES EXTRA_LDFLAGS)
  1604 endif()
  1605 if(EXTRA_LIBS)
  1606   list(REMOVE_DUPLICATES EXTRA_LIBS)
  1607 endif()
  1608 if(EXTRA_CFLAGS)
  1609   list(REMOVE_DUPLICATES EXTRA_CFLAGS)
  1610 endif()
  1611 listtostr(EXTRA_CFLAGS _EXTRA_CFLAGS)
  1612 set(EXTRA_CFLAGS ${_EXTRA_CFLAGS})
  1613 
  1614 # Compat helpers for the configuration files
  1615 if(NOT WINDOWS OR CYGWIN)
  1616   # TODO: we need a Windows script, too
  1617   execute_process(COMMAND sh ${SDL2_SOURCE_DIR}/build-scripts/updaterev.sh)
  1618 
  1619   set(prefix ${CMAKE_INSTALL_PREFIX})
  1620   set(exec_prefix "\${prefix}")
  1621   set(libdir "\${exec_prefix}/lib${LIB_SUFFIX}")
  1622   set(bindir "\${exec_prefix}/bin")
  1623   set(includedir "\${prefix}/include")
  1624   if(SDL_STATIC)
  1625     set(ENABLE_STATIC_TRUE "")
  1626     set(ENABLE_STATIC_FALSE "#")
  1627   else()
  1628     set(ENABLE_STATIC_TRUE "#")
  1629     set(ENABLE_STATIC_FALSE "")
  1630   endif()
  1631   if(SDL_SHARED)
  1632     set(ENABLE_SHARED_TRUE "")
  1633     set(ENABLE_SHARED_FALSE "#")
  1634   else()
  1635     set(ENABLE_SHARED_TRUE "#")
  1636     set(ENABLE_SHARED_FALSE "")
  1637   endif()
  1638 
  1639   # Clean up the different lists
  1640   listtostr(EXTRA_LIBS _EXTRA_LIBS "-l")
  1641   set(SDL_STATIC_LIBS ${SDL_LIBS} ${EXTRA_LDFLAGS} ${_EXTRA_LIBS})
  1642   list(REMOVE_DUPLICATES SDL_STATIC_LIBS)
  1643   listtostr(SDL_STATIC_LIBS _SDL_STATIC_LIBS)
  1644   set(SDL_STATIC_LIBS ${_SDL_STATIC_LIBS})
  1645   listtostr(SDL_LIBS _SDL_LIBS)
  1646   set(SDL_LIBS ${_SDL_LIBS})
  1647 
  1648   # MESSAGE(STATUS "SDL_LIBS: ${SDL_LIBS}")
  1649   # MESSAGE(STATUS "SDL_STATIC_LIBS: ${SDL_STATIC_LIBS}")
  1650 
  1651   configure_file("${SDL2_SOURCE_DIR}/sdl2.pc.in"
  1652     "${SDL2_BINARY_DIR}/sdl2.pc" @ONLY)
  1653   configure_file("${SDL2_SOURCE_DIR}/sdl2-config.in"
  1654     "${SDL2_BINARY_DIR}/sdl2-config")
  1655   configure_file("${SDL2_SOURCE_DIR}/sdl2-config.in"
  1656     "${SDL2_BINARY_DIR}/sdl2-config" @ONLY)
  1657   configure_file("${SDL2_SOURCE_DIR}/SDL2.spec.in"
  1658     "${SDL2_BINARY_DIR}/SDL2.spec" @ONLY)
  1659 endif()
  1660 
  1661 ##### Info output #####
  1662 message(STATUS "")
  1663 message(STATUS "SDL2 was configured with the following options:")
  1664 message(STATUS "")
  1665 message(STATUS "Platform: ${CMAKE_SYSTEM}")
  1666 message(STATUS "64-bit:   ${ARCH_64}")
  1667 message(STATUS "Compiler: ${CMAKE_C_COMPILER}")
  1668 message(STATUS "")
  1669 message(STATUS "Subsystems:")
  1670 foreach(_SUB ${SDL_SUBSYSTEMS})
  1671   string(TOUPPER ${_SUB} _OPT)
  1672   message_bool_option(${_SUB} SDL_${_OPT})
  1673 endforeach()
  1674 message(STATUS "")
  1675 message(STATUS "Options:")
  1676 list(SORT ALLOPTIONS)
  1677 foreach(_OPT ${ALLOPTIONS})
  1678   # Longest option is VIDEO_X11_XSCREENSAVER = 22 characters
  1679   # Get the padding
  1680   string(LENGTH ${_OPT} _OPTLEN)
  1681   math(EXPR _PADLEN "23 - ${_OPTLEN}")
  1682   string(RANDOM LENGTH ${_PADLEN} ALPHABET " " _PADDING)
  1683   message_tested_option(${_OPT} ${_PADDING})
  1684 endforeach()
  1685 message(STATUS "")
  1686 message(STATUS " CFLAGS:        ${CMAKE_C_FLAGS}")
  1687 message(STATUS " EXTRA_CFLAGS:  ${EXTRA_CFLAGS}")
  1688 message(STATUS " EXTRA_LDFLAGS: ${EXTRA_LDFLAGS}")
  1689 message(STATUS " EXTRA_LIBS:    ${EXTRA_LIBS}")
  1690 message(STATUS "")
  1691 message(STATUS " Build Shared Library: ${SDL_SHARED}")
  1692 message(STATUS " Build Static Library: ${SDL_STATIC}")
  1693 if(SDL_STATIC)
  1694     message(STATUS " Build Static Library with Position Independent Code: ${SDL_STATIC_PIC}")
  1695 endif()
  1696 message(STATUS "")
  1697 if(UNIX)
  1698   message(STATUS "If something was not detected, although the libraries")
  1699   message(STATUS "were installed, then make sure you have set the")
  1700   message(STATUS "CFLAGS and LDFLAGS environment variables correctly.")
  1701   message(STATUS "")
  1702 endif()
  1703 
  1704 # Ensure that the extra cflags are used at compile time
  1705 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${EXTRA_CFLAGS}")
  1706 
  1707 # Always build SDLmain
  1708 add_library(SDL2main STATIC ${SDLMAIN_SOURCES})
  1709 target_include_directories(SDL2main PUBLIC $<INSTALL_INTERFACE:include/SDL2>)
  1710 set(_INSTALL_LIBS "SDL2main")
  1711 if (NOT ANDROID)
  1712   set_target_properties(SDL2main PROPERTIES DEBUG_POSTFIX ${SDL_CMAKE_DEBUG_POSTFIX})
  1713 endif()
  1714 
  1715 if(SDL_SHARED)
  1716   add_library(SDL2 SHARED ${SOURCE_FILES} ${VERSION_SOURCES})
  1717   if(APPLE)
  1718     set_target_properties(SDL2 PROPERTIES MACOSX_RPATH 1)
  1719   elseif(UNIX AND NOT ANDROID)
  1720     set_target_properties(SDL2 PROPERTIES
  1721       VERSION ${LT_VERSION}
  1722       SOVERSION ${LT_REVISION}
  1723       OUTPUT_NAME "SDL2-${LT_RELEASE}")
  1724   else()
  1725     set_target_properties(SDL2 PROPERTIES
  1726       VERSION ${SDL_VERSION}
  1727       SOVERSION ${LT_REVISION}
  1728       OUTPUT_NAME "SDL2")
  1729   endif()
  1730   if(MSVC AND NOT LIBC)
  1731     # Don't try to link with the default set of libraries.
  1732     set_target_properties(SDL2 PROPERTIES LINK_FLAGS_RELEASE "/NODEFAULTLIB")
  1733     set_target_properties(SDL2 PROPERTIES LINK_FLAGS_DEBUG "/NODEFAULTLIB")
  1734     set_target_properties(SDL2 PROPERTIES STATIC_LIBRARY_FLAGS "/NODEFAULTLIB")
  1735   endif()
  1736   set(_INSTALL_LIBS "SDL2" ${_INSTALL_LIBS})
  1737   target_link_libraries(SDL2 ${EXTRA_LIBS} ${EXTRA_LDFLAGS})
  1738   target_include_directories(SDL2 PUBLIC $<INSTALL_INTERFACE:include/SDL2>)
  1739   if (NOT ANDROID)
  1740     set_target_properties(SDL2 PROPERTIES DEBUG_POSTFIX ${SDL_CMAKE_DEBUG_POSTFIX})
  1741   endif()
  1742 endif()
  1743 
  1744 if(SDL_STATIC)
  1745   set (BUILD_SHARED_LIBS FALSE)
  1746   add_library(SDL2-static STATIC ${SOURCE_FILES})
  1747   if (NOT SDL_SHARED OR NOT WIN32)
  1748     set_target_properties(SDL2-static PROPERTIES OUTPUT_NAME "SDL2")
  1749     # Note: Apparently, OUTPUT_NAME must really be unique; even when
  1750     # CMAKE_IMPORT_LIBRARY_SUFFIX or the like are given. Otherwise
  1751     # the static build may race with the import lib and one will get
  1752     # clobbered, when the suffix is realized via subsequent rename.
  1753   endif()
  1754   set_target_properties(SDL2-static PROPERTIES POSITION_INDEPENDENT_CODE ${SDL_STATIC_PIC})
  1755   if(MSVC AND NOT LIBC)
  1756     set_target_properties(SDL2-static PROPERTIES LINK_FLAGS_RELEASE "/NODEFAULTLIB")
  1757     set_target_properties(SDL2-static PROPERTIES LINK_FLAGS_DEBUG "/NODEFAULTLIB")
  1758     set_target_properties(SDL2-static PROPERTIES STATIC_LIBRARY_FLAGS "/NODEFAULTLIB")
  1759   endif()
  1760   # TODO: Win32 platforms keep the same suffix .lib for import and static
  1761   # libraries - do we need to consider this?
  1762   set(_INSTALL_LIBS "SDL2-static" ${_INSTALL_LIBS})
  1763   target_link_libraries(SDL2-static ${EXTRA_LIBS} ${EXTRA_LDFLAGS})
  1764   target_include_directories(SDL2-static PUBLIC $<INSTALL_INTERFACE:include/SDL2>)
  1765   if (NOT ANDROID)
  1766     set_target_properties(SDL2-static PROPERTIES DEBUG_POSTFIX ${SDL_CMAKE_DEBUG_POSTFIX})
  1767   endif()
  1768 endif()
  1769 
  1770 ##### Tests #####
  1771 
  1772 if(SDL_TEST)
  1773   file(GLOB TEST_SOURCES ${SDL2_SOURCE_DIR}/src/test/*.c)
  1774   add_library(SDL2_test STATIC ${TEST_SOURCES})
  1775 
  1776   add_subdirectory(test)
  1777 endif()
  1778 
  1779 ##### Installation targets #####
  1780 install(TARGETS ${_INSTALL_LIBS} EXPORT SDL2Targets
  1781   LIBRARY DESTINATION "lib${LIB_SUFFIX}"
  1782   ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
  1783   RUNTIME DESTINATION bin)
  1784 
  1785 ##### Export files #####
  1786 if (APPLE)
  1787   set(PKG_PREFIX "SDL2.framework/Resources")
  1788 elseif (WINDOWS)
  1789   set(PKG_PREFIX "cmake")
  1790 else ()
  1791   set(PKG_PREFIX "lib/cmake/SDL2")
  1792 endif ()
  1793 
  1794 include(CMakePackageConfigHelpers)
  1795 write_basic_package_version_file("${CMAKE_BINARY_DIR}/SDL2ConfigVersion.cmake"
  1796   VERSION ${SDL_VERSION}
  1797   COMPATIBILITY AnyNewerVersion
  1798 )
  1799 
  1800 install(EXPORT SDL2Targets
  1801   FILE SDL2Targets.cmake
  1802   NAMESPACE SDL2::
  1803   DESTINATION ${PKG_PREFIX}
  1804 )
  1805 install(
  1806   FILES
  1807     ${CMAKE_CURRENT_SOURCE_DIR}/SDL2Config.cmake
  1808     ${CMAKE_BINARY_DIR}/SDL2ConfigVersion.cmake
  1809   DESTINATION ${PKG_PREFIX}
  1810   COMPONENT Devel
  1811 )
  1812 
  1813 file(GLOB INCLUDE_FILES ${SDL2_SOURCE_DIR}/include/*.h)
  1814 file(GLOB BIN_INCLUDE_FILES ${SDL2_BINARY_DIR}/include/*.h)
  1815 foreach(_FNAME ${BIN_INCLUDE_FILES})
  1816   get_filename_component(_INCNAME ${_FNAME} NAME)
  1817   list(REMOVE_ITEM INCLUDE_FILES ${SDL2_SOURCE_DIR}/include/${_INCNAME})
  1818 endforeach()
  1819 list(APPEND INCLUDE_FILES ${BIN_INCLUDE_FILES})
  1820 install(FILES ${INCLUDE_FILES} DESTINATION include/SDL2)
  1821 
  1822 string(TOUPPER "${CMAKE_BUILD_TYPE}" UPPER_BUILD_TYPE)
  1823 if (UPPER_BUILD_TYPE MATCHES DEBUG)
  1824   set(SOPOSTFIX "${SDL_CMAKE_DEBUG_POSTFIX}")
  1825 else()
  1826   set(SOPOSTFIX "")
  1827 endif()
  1828 
  1829 if(NOT (WINDOWS OR CYGWIN))
  1830   if(SDL_SHARED)
  1831     if (APPLE)
  1832         set(SOEXT "dylib")
  1833     else()
  1834         set(SOEXT "so")
  1835     endif()
  1836     if(NOT ANDROID)
  1837         install(CODE "
  1838           execute_process(COMMAND ${CMAKE_COMMAND} -E create_symlink
  1839             \"libSDL2-2.0${SOPOSTFIX}.${SOEXT}\" \"libSDL2.${SOEXT}\")"
  1840             WORKING_DIR "${SDL2_BINARY_DIR}")
  1841         install(FILES ${SDL2_BINARY_DIR}/libSDL2.${SOEXT} DESTINATION "lib${LIB_SUFFIX}")
  1842     endif()
  1843   endif()
  1844   if(FREEBSD)
  1845     # FreeBSD uses ${PREFIX}/libdata/pkgconfig
  1846     install(FILES ${SDL2_BINARY_DIR}/sdl2.pc DESTINATION "libdata/pkgconfig")
  1847   else()
  1848     install(FILES ${SDL2_BINARY_DIR}/sdl2.pc
  1849       DESTINATION "lib${LIB_SUFFIX}/pkgconfig")
  1850   endif()
  1851   install(PROGRAMS ${SDL2_BINARY_DIR}/sdl2-config DESTINATION bin)
  1852   # TODO: what about the .spec file? Is it only needed for RPM creation?
  1853   install(FILES "${SDL2_SOURCE_DIR}/sdl2.m4" DESTINATION "${CMAKE_INSTALL_FULL_DATAROOTDIR}/aclocal")
  1854 endif()
  1855 
  1856 ##### Uninstall target #####
  1857 
  1858 if(NOT TARGET uninstall)
  1859   configure_file(
  1860       "${CMAKE_CURRENT_SOURCE_DIR}/cmake_uninstall.cmake.in"
  1861       "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
  1862       IMMEDIATE @ONLY)
  1863 
  1864   add_custom_target(uninstall
  1865       COMMAND ${CMAKE_COMMAND} -P ${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake)
  1866 endif()