dnl Process this file with autoconf to produce a configure script.

AC_INIT(README)

dnl Set various version strings - taken gratefully from the GTk sources

#

# Making releases:

# Edit include/SDL/SDL_version.h and change the version, then:

#   SDL_MICRO_VERSION += 1;

#   SDL_INTERFACE_AGE += 1;

#   SDL_BINARY_AGE += 1;

# if any functions have been added, set SDL_INTERFACE_AGE to 0.

# if backwards compatibility has been broken,

# set SDL_BINARY_AGE and SDL_INTERFACE_AGE to 0.

#

SDL_MAJOR_VERSION=1

SDL_MINOR_VERSION=2

SDL_MICRO_VERSION=7

SDL_INTERFACE_AGE=7

SDL_BINARY_AGE=7

SDL_VERSION=$SDL_MAJOR_VERSION.$SDL_MINOR_VERSION.$SDL_MICRO_VERSION

AC_SUBST(SDL_MAJOR_VERSION)

AC_SUBST(SDL_MINOR_VERSION)

AC_SUBST(SDL_MICRO_VERSION)

AC_SUBST(SDL_INTERFACE_AGE)

AC_SUBST(SDL_BINARY_AGE)

AC_SUBST(SDL_VERSION)

# libtool versioning

LT_RELEASE=$SDL_MAJOR_VERSION.$SDL_MINOR_VERSION

LT_CURRENT=`expr $SDL_MICRO_VERSION - $SDL_INTERFACE_AGE`

LT_REVISION=$SDL_INTERFACE_AGE

LT_AGE=`expr $SDL_BINARY_AGE - $SDL_INTERFACE_AGE`

AC_SUBST(LT_RELEASE)

AC_SUBST(LT_CURRENT)

AC_SUBST(LT_REVISION)

AC_SUBST(LT_AGE)

dnl Detect the canonical host and target build environment

AC_CANONICAL_SYSTEM

dnl Setup for automake

AM_INIT_AUTOMAKE(SDL, $SDL_VERSION)

dnl Check for tools

AC_LIBTOOL_WIN32_DLL

AM_PROG_LIBTOOL

AC_PROG_MAKE_SET

AC_PROG_CC

AC_C_INLINE

AC_C_CONST

AC_PROG_CXX

AC_PROG_INSTALL

AC_FUNC_ALLOCA

ASFLAGS=""

AC_SUBST(ASFLAGS)

CCAS="$CC"

AC_SUBST(CCAS)

CCASFLAGS=""

AC_SUBST(CCASFLAGS)

AM_CONDITIONAL([am__fastdepOBJC], false)

dnl The alpha architecture needs special flags for binary portability

case "$target" in

    alpha*-*-linux*)

        if test x$ac_cv_prog_gcc = xyes; then

            CFLAGS="$CFLAGS -mcpu=ev4 -Wa,-mall"

        fi

        ;;

esac

dnl Add compiler-specific optimization flags

dnl See if the user wants aggressive optimizations of the code

AC_ARG_ENABLE(debug,

[  --enable-debug          Disable aggressive optimizations [default=yes]],

              , enable_debug=yes)

if test x$enable_debug != xyes; then

    if test x$ac_cv_prog_gcc = xyes; then

        CFLAGS="$CFLAGS -fexpensive-optimizations"

        # Ack! This breaks the MMX YV12 conversion on gcc 2.95.2

        # CFLAGS="$CFLAGS -fomit-frame-pointer"

    fi

    case "$target" in

        i486-*-*)

            if test x$ac_cv_prog_gcc = xyes; then

                CFLAGS="$CFLAGS -march=486"

            fi

            ;;

        i?86-*-*)

            if test x$ac_cv_prog_gcc = xyes; then

                CFLAGS="$CFLAGS -march=pentium -mcpu=pentiumpro"

            fi

            ;;

        *-*-osf*)

            if test x$ac_cv_prog_gcc != xyes; then

                CFLAGS="-g3 -fast -arch host"

            fi

            ;;

    esac

fi

dnl Add verbose warnings by default, and allow ANSI compliance checking

AC_ARG_ENABLE(strict-ansi,

[  --enable-strict-ansi    Enable strict ANSI compliance build [default=no]],

              , enable_strict_ansi=no)

if test x$ac_cv_prog_gcc = xyes; then

    CFLAGS="$CFLAGS -Wall"

    if test x$enable_strict_ansi = xyes; then

        CFLAGS="$CFLAGS -ansi -pedantic -D_XOPEN_SOURCE"

    fi

fi

dnl Initialize the compiler and linker flags for SDL applications

SDL_CFLAGS=""

SDL_LIBS="-lSDL"

dnl Add the math library for the new gamma correction support

case "$target" in

    *-*-cygwin* | *-*-mingw32*)

        MATHLIB=""

        ;;

    *-*-beos*)

        MATHLIB=""

        ;;

    *-*-darwin*)

        MATHLIB=""

        ;;

    *)

        MATHLIB="-lm"

        ;;

esac

SYSTEM_LIBS="$SYSTEM_LIBS $MATHLIB"

dnl Enable/disable various subsystems of the SDL library

AC_ARG_ENABLE(audio,

[  --enable-audio          Enable the audio subsystem [default=yes]],

              , enable_audio=yes)

if test x$enable_audio = xyes; then

    SDL_EXTRADIRS="$SDL_EXTRADIRS audio"

    SDL_EXTRALIBS="$SDL_EXTRALIBS audio/libaudio.la"

else

    CFLAGS="$CFLAGS -DDISABLE_AUDIO"

fi

AC_ARG_ENABLE(video,

[  --enable-video          Enable the video subsystem [default=yes]],

              , enable_video=yes)

if test x$enable_video = xyes; then

    SDL_EXTRADIRS="$SDL_EXTRADIRS video"

    SDL_EXTRALIBS="$SDL_EXTRALIBS video/libvideo.la"

else

    CFLAGS="$CFLAGS -DDISABLE_VIDEO"

fi

AC_ARG_ENABLE(events,

[  --enable-events         Enable the events subsystem [default=yes]],

              , enable_events=yes)

if test x$enable_video = xyes -a x$enable_events = xyes; then

    SDL_EXTRADIRS="$SDL_EXTRADIRS events"

    SDL_EXTRALIBS="$SDL_EXTRALIBS events/libevents.la"

else

    CFLAGS="$CFLAGS -DDISABLE_EVENTS"

fi

AC_ARG_ENABLE(joystick,

[  --enable-joystick       Enable the joystick subsystem [default=yes]],

              , enable_joystick=yes)

if test x$enable_joystick = xyes; then

    SDL_EXTRADIRS="$SDL_EXTRADIRS joystick"

    SDL_EXTRALIBS="$SDL_EXTRALIBS joystick/libjoystick.la"

else

    CFLAGS="$CFLAGS -DDISABLE_JOYSTICK"

fi

AC_ARG_ENABLE(cdrom,

[  --enable-cdrom          Enable the cdrom subsystem [default=yes]],

              , enable_cdrom=yes)

if test x$enable_cdrom = xyes; then

    SDL_EXTRADIRS="$SDL_EXTRADIRS cdrom"

    SDL_EXTRALIBS="$SDL_EXTRALIBS cdrom/libcdrom.la"

else

    CFLAGS="$CFLAGS -DDISABLE_CDROM"

fi

AC_ARG_ENABLE(threads,

[  --enable-threads        Enable the threading subsystem [default=yes]],

              , enable_threads=yes)

SDL_EXTRADIRS="$SDL_EXTRADIRS thread"

SDL_EXTRALIBS="$SDL_EXTRALIBS thread/libthread.la"

if test x$enable_threads != xyes; then

    CFLAGS="$CFLAGS -DDISABLE_THREADS"

    COPY_ARCH_SRC(src/thread, generic, SDL_systhread.c)

    COPY_ARCH_SRC(src/thread, generic, SDL_systhread_c.h)

    COPY_ARCH_SRC(src/thread, generic, SDL_sysmutex.c)

    COPY_ARCH_SRC(src/thread, generic, SDL_sysmutex_c.h)

    COPY_ARCH_SRC(src/thread, generic, SDL_syssem.c)

    COPY_ARCH_SRC(src/thread, generic, SDL_syssem_c.h)

    COPY_ARCH_SRC(src/thread, generic, SDL_syscond.c)

    COPY_ARCH_SRC(src/thread, generic, SDL_syscond_c.h)

fi

AC_ARG_ENABLE(timers,

[  --enable-timers         Enable the timer subsystem [default=yes]],

              , enable_timers=yes)

if test x$enable_timers = xyes; then

    SDL_EXTRADIRS="$SDL_EXTRADIRS timer"

    SDL_EXTRALIBS="$SDL_EXTRALIBS timer/libtimer.la"

else

    CFLAGS="$CFLAGS -DDISABLE_TIMERS"

fi

AC_ARG_ENABLE(endian,

[  --enable-endian         Enable the endian subsystem [default=yes]],

              , enable_endian=yes)

if test x$enable_endian = xyes; then

    SDL_EXTRADIRS="$SDL_EXTRADIRS endian"

    SDL_EXTRALIBS="$SDL_EXTRALIBS endian/libendian.la"

else

    CFLAGS="$CFLAGS -DDISABLE_ENDIAN"

fi

AC_ARG_ENABLE(file,

[  --enable-file           Enable the file subsystem [default=yes]],

              , enable_file=yes)

if test x$enable_file = xyes; then

    SDL_EXTRADIRS="$SDL_EXTRADIRS file"

    SDL_EXTRALIBS="$SDL_EXTRALIBS file/libfile.la"

else

    CFLAGS="$CFLAGS -DDISABLE_FILE"

fi

dnl See if the OSS audio interface is supported

CheckOSS()

{

    AC_ARG_ENABLE(oss,

[  --enable-oss            support the OSS audio API [default=yes]],

                  , enable_oss=yes)

    if test x$enable_audio = xyes -a x$enable_oss = xyes; then

        AC_MSG_CHECKING(for OSS audio support)

        have_oss=no

        if test x$have_oss != xyes; then

            AC_TRY_COMPILE([

              #include <sys/soundcard.h>

            ],[

              int arg = SNDCTL_DSP_SETFRAGMENT;

            ],[

            have_oss=yes

            ])

        fi

        if test x$have_oss != xyes; then

            AC_TRY_COMPILE([

              #include <soundcard.h>

            ],[

              int arg = SNDCTL_DSP_SETFRAGMENT;

            ],[

            have_oss=yes

            CFLAGS="$CFLAGS -DOSS_USE_SOUNDCARD_H"

            ])

        fi

        AC_MSG_RESULT($have_oss)

        if test x$have_oss = xyes; then

            CFLAGS="$CFLAGS -DOSS_SUPPORT"

            AUDIO_SUBDIRS="$AUDIO_SUBDIRS dsp"

            AUDIO_DRIVERS="$AUDIO_DRIVERS dsp/libaudio_dsp.la"

            AUDIO_SUBDIRS="$AUDIO_SUBDIRS dma"

            AUDIO_DRIVERS="$AUDIO_DRIVERS dma/libaudio_dma.la"

        fi

    fi

}

dnl See if the ALSA audio interface is supported

CheckALSA()

{

    AC_ARG_ENABLE(alsa,

[  --enable-alsa           support the ALSA audio API [default=yes]],

                  , enable_alsa=yes)

    if test x$enable_audio = xyes -a x$enable_alsa = xyes; then

        AC_MSG_CHECKING(for ALSA audio support)

        have_alsa=no

        AC_TRY_COMPILE([

          #include <alsa/asoundlib.h>

        ],[

          #if SND_LIB_VERSION < ((0<<16)|(9<<8)|0)

          #error Your version of ALSA is too old

          #endif

          snd_pcm_t *pcm_handle;

        ],[

        AC_CHECK_LIB(asound, snd_pcm_open, have_alsa=yes)

        ])

        if test x$have_alsa = xyes; then

            CFLAGS="$CFLAGS -DALSA_SUPPORT"

            SYSTEM_LIBS="$SYSTEM_LIBS -lasound"

            AUDIO_SUBDIRS="$AUDIO_SUBDIRS alsa"

            AUDIO_DRIVERS="$AUDIO_DRIVERS alsa/libaudio_alsa.la"

        else

            AC_MSG_RESULT($have_alsa)

        fi

    fi

}

dnl Check whether we want to use IRIX 6.5+ native audio or not

CheckDMEDIA()

{

    if test x$enable_audio = xyes; then

        AC_MSG_CHECKING(for dmedia audio support)

        have_dmedia=no

        AC_TRY_COMPILE([

          #include <dmedia/audio.h>

        ],[

          ALport audio_port;

        ],[

        have_dmedia=yes

        ])

        # Set up files for the audio library

        if test x$have_dmedia = xyes; then

            CFLAGS="$CFLAGS -DDMEDIA_SUPPORT"

            AUDIO_SUBDIRS="$AUDIO_SUBDIRS dmedia"

            AUDIO_DRIVERS="$AUDIO_DRIVERS dmedia/libaudio_dmedia.la"

            SYSTEM_LIBS="$SYSTEM_LIBS -laudio"

        fi

    fi

}

dnl Find the ESD includes and libraries

CheckESD()

{

    AC_ARG_ENABLE(esd,

[  --enable-esd            support the Enlightened Sound Daemon [default=yes]],

                  , enable_esd=yes)

    if test x$enable_audio = xyes -a x$enable_esd = xyes; then

        use_esd=no

        AM_PATH_ESD(0.2.8, use_esd=yes)

        if test x$use_esd = xyes; then

            AC_ARG_ENABLE(esd-shared,

[  --enable-esd-shared     dynamically load ESD audio support [default=yes]],

                          , enable_esd_shared=yes)

            esd_lib_spec=`echo $ESD_LIBS | sed 's/.*-L\([[^ ]]*\).*/\1\/libesd.so.*/'`

            esd_lib=`ls $esd_lib_spec | head -1 | sed 's/.*\/\(.*\)/\1/'`

            echo "-- $esd_lib_spec -> $esd_lib"

            if test x$enable_dlopen != xyes && \

               test x$enable_esd_shared = xyes; then

                AC_MSG_ERROR([You must have dlopen() support and use the --enable-dlopen option])

            fi

            if test x$enable_dlopen = xyes && \

               test x$enable_esd_shared = xyes && test x$esd_lib != x; then

                CFLAGS="$CFLAGS -DESD_SUPPORT -DESD_DYNAMIC=\$(esd_lib) $ESD_CFLAGS"

                AC_SUBST(esd_lib)

            else

                CFLAGS="$CFLAGS -DESD_SUPPORT $ESD_CFLAGS"

                SYSTEM_LIBS="$SYSTEM_LIBS $ESD_LIBS"

            fi

            AUDIO_SUBDIRS="$AUDIO_SUBDIRS esd"

            AUDIO_DRIVERS="$AUDIO_DRIVERS esd/libaudio_esd.la"

        fi

    fi

}

CheckARTSC()

{

    AC_ARG_ENABLE(arts,

[  --enable-arts           support the Analog Real Time Synthesizer [default=yes]],

                  , enable_arts=yes)

    if test x$enable_audio = xyes -a x$enable_arts = xyes; then

        AC_PATH_PROG(ARTSCCONFIG, artsc-config)

        if test x$ARTSCCONFIG = x -o x$ARTSCCONFIG = x'"$ARTSCCONFIG"'; then

            : # arts isn't installed

        else

            ARTSC_CFLAGS=`$ARTSCCONFIG --cflags`

            ARTSC_LIBS=`$ARTSCCONFIG --libs`

            AC_MSG_CHECKING(for aRts development environment)

            audio_arts=no

            save_CFLAGS="$CFLAGS"

            CFLAGS="$CFLAGS $ARTSC_CFLAGS"

            AC_TRY_COMPILE([

             #include <artsc.h>

            ],[

             arts_stream_t stream;

            ],[

            audio_arts=yes

            ])

            CFLAGS="$save_CFLAGS"

            AC_MSG_RESULT($audio_arts)

            if test x$audio_arts = xyes; then

                AC_ARG_ENABLE(arts-shared,

[  --enable-arts-shared    dynamically load aRts audio support [default=yes]],

                              , enable_arts_shared=yes)

                arts_lib_spec=`echo $ARTSC_LIBS | sed 's/.*-L\([[^ ]]*\).*/\1\/libartsc.so.*/'`

                arts_lib=`ls $arts_lib_spec | head -1 | sed 's/.*\/\(.*\)/\1/'`

                echo "-- $arts_lib_spec -> $arts_lib"

                if test x$enable_dlopen != xyes && \

                   test x$enable_arts_shared = xyes; then

                    AC_MSG_ERROR([You must have dlopen() support and use the --enable-dlopen option])

                fi

                if test x$enable_dlopen = xyes && \

                   test x$enable_arts_shared = xyes && test x$arts_lib != x; then

                    CFLAGS="$CFLAGS -DARTSC_SUPPORT -DARTSC_DYNAMIC=\$(arts_lib) $ARTSC_CFLAGS"

                    AC_SUBST(arts_lib)

                else

                    CFLAGS="$CFLAGS -DARTSC_SUPPORT $ARTSC_CFLAGS"

                    SYSTEM_LIBS="$SYSTEM_LIBS $ARTSC_LIBS"

                fi

                AUDIO_SUBDIRS="$AUDIO_SUBDIRS arts"

                AUDIO_DRIVERS="$AUDIO_DRIVERS arts/libaudio_arts.la"

            fi

        fi

    fi

}

dnl See if the NAS audio interface is supported

CheckNAS()

{

    AC_ARG_ENABLE(nas,

[  --enable-nas            support the NAS audio API [default=yes]],

                  , enable_nas=yes)

    if test x$enable_audio = xyes -a x$enable_nas = xyes; then

        AC_MSG_CHECKING(for NAS audio support)

        have_nas=no

        if test -r /usr/X11R6/include/audio/audiolib.h; then

            have_nas=yes

            CFLAGS="$CFLAGS -DNAS_SUPPORT -I/usr/X11R6/include/"

            SYSTEM_LIBS="$SYSTEM_LIBS -laudio -lXt"

            AUDIO_SUBDIRS="$AUDIO_SUBDIRS nas"

            AUDIO_DRIVERS="$AUDIO_DRIVERS nas/libaudio_nas.la"

        dnl On IRIX, the NAS includes are in a different directory,

        dnl and libnas must be explicitly linked in

        elif test -r /usr/freeware/include/nas/audiolib.h; then

            have_nas=yes

            CFLAGS="$CFLAGS -DNAS_SUPPORT"

            SYSTEM_LIBS="$SYSTEM_LIBS -lnas -lXt"

            AUDIO_SUBDIRS="$AUDIO_SUBDIRS nas"

            AUDIO_DRIVERS="$AUDIO_DRIVERS nas/libaudio_nas.la"

        fi

        AC_MSG_RESULT($have_nas)

    fi

}

dnl rcg07142001 See if the user wants the disk writer audio driver...

CheckDiskAudio()

{

    AC_ARG_ENABLE(diskaudio,

[  --enable-diskaudio      support the disk writer audio driver [default=yes]],

                  , enable_diskaudio=yes)

    if test x$enable_audio = xyes -a x$enable_diskaudio = xyes; then

        CFLAGS="$CFLAGS -DDISKAUD_SUPPORT"

        AUDIO_SUBDIRS="$AUDIO_SUBDIRS disk"

        AUDIO_DRIVERS="$AUDIO_DRIVERS disk/libaudio_disk.la"

    fi

}

dnl Set up the Atari Audio driver

CheckAtariAudio()

{

    AC_ARG_ENABLE(mintaudio,

[  --enable-mintaudio      support Atari audio driver [default=yes]],

                  , enable_mintaudio=yes)

    if test x$enable_audio = xyes -a x$enable_mintaudio = xyes; then

        mintaudio=no

        AC_CHECK_HEADER(mint/falcon.h, have_mint_falcon_hdr=yes)

        if test x$have_mint_falcon_hdr = xyes; then

            mintaudio=yes

            CFLAGS="$CFLAGS -DMINTAUDIO_SUPPORT"

            AUDIO_SUBDIRS="$AUDIO_SUBDIRS mint"

            AUDIO_DRIVERS="$AUDIO_DRIVERS mint/libaudio_mintaudio.la"

        fi

    fi

}

dnl See if we can use x86 assembly blitters

# NASM is available from: http://nasm.octium.net/

CheckNASM()

{

    dnl Make sure we are running on an x86 platform

    case $target in

        i?86*)

            ;;

        *)

        # Nope, bail early.

            return

            ;;

    esac

    dnl Check for NASM (for assembly blit routines)

    AC_ARG_ENABLE(nasm,

[  --enable-nasm           use nasm assembly blitters on x86 [default=yes]],

                  , enable_nasm=yes)

    if test x$enable_video = xyes -a x$enable_nasm = xyes; then

        AC_PATH_PROG(NASM, nasm)

        if test x$NASM = x -o x$NASM = x'"$NASM"'; then

            : # nasm isn't installed

        else

            CFLAGS="$CFLAGS -DUSE_ASMBLIT -I$srcdir/hermes"

            case $ARCH in

              win32)

                  NASMFLAGS="-f win32"

                  ;;

              openbsd)

                  NASMFLAGS="-f aoutb"

                  ;;

              *)

                  NASMFLAGS="-f elf"

                  ;;

            esac

            AC_SUBST(NASMFLAGS)

            CFLAGS="$CFLAGS -I\$(top_srcdir)/src/hermes"

            SDL_EXTRADIRS="$SDL_EXTRADIRS hermes"

            SDL_EXTRALIBS="$SDL_EXTRALIBS hermes/libhermes.la"

        fi

    fi

}

dnl Find the nanox include and library directories

CheckNANOX()

{

    AC_ARG_ENABLE(video-nanox,

        [  --enable-video-nanox use nanox video driver [default=no]],

        , enable_video_nanox=no)

    AC_ARG_ENABLE(nanox-debug,  

        [  --enable-nanox-debug print debug messages [default=no]],

        , enable_nanox_debug=no)

    AC_ARG_ENABLE(nanox-share-memory,  

        [  --enable-nanox-share-memory use share memory [default=no]],

        , enable_nanox_share_memory=no)

    AC_ARG_ENABLE(nanox_direct_fb, 

        [  --enable-nanox-direct-fb use direct framebuffer access [default=no]],

        , enable_nanox_direct_fb=no)

    if test x$enable_video = xyes -a x$enable_video_nanox = xyes; then

        if test x$enable_nanox_debug = xyes; then

            CFLAGS="$CFLAGS -DENABLE_NANOX_DEBUG"

        fi

        if test x$enable_nanox_share_memory = xyes; then

            CFLAGS="$CFLAGS -DNANOX_SHARE_MEMORY"

        fi

        if test x$enable_nanox_direct_fb = xyes; then

            CFLAGS="$CFLAGS -DENABLE_NANOX_DIRECT_FB"

        fi

        CFLAGS="$CFLAGS $X_CFLAGS -DENABLE_NANOX"

        SYSTEM_LIBS="$SYSTEM_LIBS -lnano-X"

        VIDEO_SUBDIRS="$VIDEO_SUBDIRS nanox"

        VIDEO_DRIVERS="$VIDEO_DRIVERS nanox/libvideo_nanox.la"

    fi

}

dnl Find the X11 include and library directories

CheckX11()

{

    AC_ARG_ENABLE(video-x11,

[  --enable-video-x11      use X11 video driver [default=yes]],

                  , enable_video_x11=yes)

    if test x$enable_video = xyes -a x$enable_video_x11 = xyes; then

        AC_PATH_X

        AC_PATH_XTRA

        if test x$have_x = xyes; then

            CFLAGS="$CFLAGS $X_CFLAGS -DENABLE_X11 -DXTHREADS -I$srcdir/include -I$srcdir/src/video"

            if test x$ac_cv_func_shmat != xyes; then

                CFLAGS="$CFLAGS -DNO_SHARED_MEMORY"

            fi

            SYSTEM_LIBS="$SYSTEM_LIBS $X_LIBS -lX11 -lXext"

            VIDEO_SUBDIRS="$VIDEO_SUBDIRS x11"

            VIDEO_DRIVERS="$VIDEO_DRIVERS x11/libvideo_x11.la"

            AC_ARG_ENABLE(video-x11-vm,

[  --enable-video-x11-vm   use X11 VM extension for fullscreen [default=yes]],

                          , enable_video_x11_vm=yes)

            if test x$enable_video_x11_vm = xyes; then

                AC_MSG_CHECKING(for XFree86 VidMode 1.0 support)

                video_x11_vm=no

                AC_TRY_COMPILE([

                 #include <X11/Xlib.h>

                 #include <XFree86/extensions/xf86vmode.h>

                ],[

                ],[

                video_x11_vm=yes

                ])

                AC_MSG_RESULT($video_x11_vm)

                if test x$video_x11_vm = xyes; then

                    CFLAGS="$CFLAGS -DXFREE86_VM"

                    VIDEO_SUBDIRS="$VIDEO_SUBDIRS XFree86/Xxf86vm"

                    VIDEO_DRIVERS="$VIDEO_DRIVERS XFree86/Xxf86vm/libXFree86_Xxf86vm.la"

                    AC_MSG_CHECKING(for XFree86 VidMode gamma support)

                    video_x11_vmgamma=no

                    AC_TRY_COMPILE([

                     #include <X11/Xlib.h>

                     #include <XFree86/extensions/xf86vmode.h>

                    ],[

                     SDL_NAME(XF86VidModeGamma) gamma;

                    ],[

                    video_x11_vmgamma=yes

                    ])

                    AC_MSG_RESULT($video_x11_vmgamma)

                    if test x$video_x11_vmgamma = xyes; then

                        CFLAGS="$CFLAGS -DXFREE86_VMGAMMA"

                    fi

                fi

            fi

            AC_ARG_ENABLE(dga,

[  --enable-dga            allow use of X11 DGA code [default=yes]],

                          , enable_dga=yes)

            AC_ARG_ENABLE(video-x11-dgamouse,

[  --enable-video-x11-dgamouse  use X11 DGA for mouse events [default=yes]],

                          , enable_video_x11_dgamouse=yes)

            if test x$enable_dga = xyes; then

                AC_MSG_CHECKING(for XFree86 DGA 1.0 support)

                video_x11_dga=no

                AC_TRY_COMPILE([

                 #include <X11/Xlib.h>

                 #include <XFree86/extensions/xf86dga.h>

                ],[

                ],[

                video_x11_dga=yes

                ])

                AC_MSG_RESULT($video_x11_dga)

                if test x$video_x11_dga = xyes; then

                    CFLAGS="$CFLAGS -DXFREE86_DGAMOUSE"

                    if test x$enable_video_x11_dgamouse = xyes; then

                        CFLAGS="$CFLAGS -DDEFAULT_DGAMOUSE"

                    fi

                    VIDEO_SUBDIRS="$VIDEO_SUBDIRS XFree86/Xxf86dga"

                    VIDEO_DRIVERS="$VIDEO_DRIVERS XFree86/Xxf86dga/libXFree86_Xxf86dga.la"

                fi

            fi

            AC_ARG_ENABLE(video-x11-xv,

[  --enable-video-x11-xv   use X11 XvImage extension for video [default=yes]],

                          , enable_video_x11_xv=yes)

            if test x$enable_video_x11_xv = xyes; then

                AC_MSG_CHECKING(for XFree86 XvImage support)

                video_x11_xv=no

                AC_TRY_COMPILE([

                 #include <X11/Xlib.h>

                 #include <sys/ipc.h>

                 #include <sys/shm.h>

                 #include <X11/extensions/XShm.h>

                 #include <XFree86/extensions/Xvlib.h>

                ],[

                 SDL_NAME(XvImage) *image;

                ],[

                video_x11_xv=yes

                ])

                AC_MSG_RESULT($video_x11_xv)

                if test x$video_x11_xv = xyes; then

                    CFLAGS="$CFLAGS -DXFREE86_XV"

                    VIDEO_SUBDIRS="$VIDEO_SUBDIRS XFree86/Xv"

                    VIDEO_DRIVERS="$VIDEO_DRIVERS XFree86/Xv/libXFree86_Xv.la"

                fi

            fi

            AC_ARG_ENABLE(video-x11-xinerama,

[  --enable-video-x11-xinerama   enable X11 Xinerama support [default=yes]],

                            , enable_video_x11_xinerama=yes)

            if test x$enable_video_x11_xinerama = xyes; then

                AC_MSG_CHECKING(for X11 Xinerama support)

                video_x11_xinerama=no

                AC_TRY_COMPILE([

                 #include <X11/Xlib.h>

                 #include <XFree86/extensions/Xinerama.h>

                ],[

                 SDL_NAME(XineramaScreenInfo) *xinerama;

                ],[

                video_x11_xinerama=yes

                ])

                AC_MSG_RESULT($video_x11_xinerama)

                if test x$video_x11_xinerama = xyes; then

                    CFLAGS="$CFLAGS -DHAVE_XINERAMA"

                    VIDEO_SUBDIRS="$VIDEO_SUBDIRS XFree86/Xinerama"

                    VIDEO_DRIVERS="$VIDEO_DRIVERS XFree86/Xinerama/libXFree86_Xinerama.la"

                fi

            fi

            AC_ARG_ENABLE(video-x11-xme,

[  --enable-video-x11-xme  enable Xi Graphics XME for fullscreen [default=yes]],

                            , enable_video_x11_xme=yes)

            if test x$enable_video_x11_xme = xyes; then

                AC_MSG_CHECKING(for Xi Graphics XiGMiscExtension support)

                video_x11_xme=no

                AC_TRY_COMPILE([

                 #include <X11/Xlib.h>

                 #include <X11/extensions/xme.h>

                ],[

                 XiGMiscResolutionInfo *resolutions;

                ],[

                video_x11_xme=yes

                ])

                AC_MSG_RESULT($video_x11_xme)

                if test x$video_x11_xme = xyes; then

                    CFLAGS="$CFLAGS -DHAVE_XIGXME"

                    SYSTEM_LIBS="$SYSTEM_LIBS -lxme"

                fi

            fi

        fi

    fi

}

dnl Find the X11 DGA 2.0 include and library directories

CheckDGA()

{

    AC_ARG_ENABLE(video-dga,

[  --enable-video-dga      use DGA 2.0 video driver [default=yes]],

                  , enable_video_dga=yes)

    if test x$video_x11_dga = xyes -a x$enable_video_dga = xyes; then

        save_CFLAGS="$CFLAGS"; CFLAGS="$CFLAGS -Isrc/video"

        AC_MSG_CHECKING(for XFree86 DGA 2.0 support)

        video_x11_dga2=no

        AC_TRY_COMPILE([

         #include <X11/Xlib.h>

         #include <XFree86/extensions/xf86dga.h>

        ],[

         SDL_NAME(XDGAEvent) xevent;

        ],[

        video_x11_dga2=yes

        ])

        AC_MSG_RESULT($video_x11_dga2)

        if test x$video_x11_dga2 = xyes; then

            CFLAGS="$CFLAGS -DENABLE_DGA"

            VIDEO_SUBDIRS="$VIDEO_SUBDIRS dga"

            VIDEO_DRIVERS="$VIDEO_DRIVERS dga/libvideo_dga.la"

        fi

    fi

}

CheckPHOTON()

{

    AC_ARG_ENABLE(video-photon,

[  --enable-video-photon   use QNX Photon video driver [default=yes]],

                  , enable_video_photon=yes)

    if test x$enable_video = xyes -a x$enable_video_photon = xyes; then

        AC_MSG_CHECKING(for QNX Photon support)

        video_photon=no

        AC_TRY_COMPILE([

          #include <Ph.h>

          #include <Pt.h>

          #include <photon/Pg.h>

          #include <photon/PdDirect.h>

        ],[

         PgDisplaySettings_t *visual;

        ],[

        video_photon=yes

        ])

        AC_MSG_RESULT($video_photon)

        if test x$video_photon = xyes; then

            CFLAGS="$CFLAGS -DENABLE_PHOTON"

            SYSTEM_LIBS="$SYSTEM_LIBS -lph"

            VIDEO_SUBDIRS="$VIDEO_SUBDIRS photon"

            VIDEO_DRIVERS="$VIDEO_DRIVERS photon/libvideo_photon.la"

            CheckOpenGLQNX

        fi

    fi

}

dnl Find the framebuffer console includes

CheckFBCON()

{

    AC_ARG_ENABLE(video-fbcon,

[  --enable-video-fbcon    use framebuffer console video driver [default=yes]],

                  , enable_video_fbcon=yes)

    if test x$enable_video = xyes -a x$enable_video_fbcon = xyes; then

        AC_MSG_CHECKING(for framebuffer console support)

        video_fbcon=no

        AC_TRY_COMPILE([

         #include <linux/fb.h>

         #include <linux/kd.h>

         #include <linux/keyboard.h>

        ],[

        ],[

        video_fbcon=yes

        ])

        AC_MSG_RESULT($video_fbcon)

        if test x$video_fbcon = xyes; then

            CFLAGS="$CFLAGS -DENABLE_FBCON"

            VIDEO_SUBDIRS="$VIDEO_SUBDIRS fbcon"

            VIDEO_DRIVERS="$VIDEO_DRIVERS fbcon/libvideo_fbcon.la"

        fi

    fi

}

dnl Find DirectFB

CheckDirectFB()

{

    AC_ARG_ENABLE(video-directfb,

[  --enable-video-directfb use DirectFB video driver [default=no]],

                  , enable_video_directfb=no)

    if test x$enable_video = xyes -a x$enable_video_directfb = xyes; then

        video_directfb=no

        AC_PATH_PROG(PKG_CONFIG, pkg-config, no)

        if test x$PKG_CONFIG = xno ; then

            AC_MSG_WARN([*** pkg-config is required to build the DirectFB video driver.])

        else

            AC_MSG_CHECKING(for DirectFB support)

            if ! $PKG_CONFIG --atleast-pkgconfig-version 0.7 ; then

                AC_MSG_ERROR([*** pkg-config too old; version 0.7 or better required.])

            fi

            DIRECTFB_REQUIRED_VERSION=0.9.15

            if $PKG_CONFIG --atleast-version $DIRECTFB_REQUIRED_VERSION directfb ; then

                DIRECTFB_CFLAGS=`$PKG_CONFIG --cflags directfb`

                DIRECTFB_LIBS=`$PKG_CONFIG --libs directfb`

                video_directfb=yes

            fi

        fi

        AC_MSG_RESULT($video_directfb)

        if test x$video_directfb = xyes; then

            CFLAGS="$CFLAGS -DENABLE_DIRECTFB"

            VIDEO_SUBDIRS="$VIDEO_SUBDIRS directfb"

            VIDEO_DRIVERS="$VIDEO_DRIVERS directfb/libvideo_directfb.la"

            AC_SUBST(DIRECTFB_CFLAGS)

            AC_SUBST(DIRECTFB_LIBS)

        fi

    fi

}

dnl See if we're running on PlayStation 2 hardware

CheckPS2GS()

{

    AC_ARG_ENABLE(video-ps2gs,

[  --enable-video-ps2gs    use PlayStation 2 GS video driver [default=yes]],

                  , enable_video_ps2gs=yes)

    if test x$enable_video = xyes -a x$enable_video_ps2gs = xyes; then

        AC_MSG_CHECKING(for PlayStation 2 GS support)

        video_ps2gs=no

        AC_TRY_COMPILE([

         #include <linux/ps2/dev.h>

         #include <linux/ps2/gs.h>

        ],[

        ],[

        video_ps2gs=yes

        ])

        AC_MSG_RESULT($video_ps2gs)

        if test x$video_ps2gs = xyes; then

            CFLAGS="$CFLAGS -DENABLE_PS2GS"

            VIDEO_SUBDIRS="$VIDEO_SUBDIRS ps2gs"

            VIDEO_DRIVERS="$VIDEO_DRIVERS ps2gs/libvideo_ps2gs.la"

        fi

    fi

}

dnl Find the GGI includes

CheckGGI()

{

    AC_ARG_ENABLE(video-ggi,

[  --enable-video-ggi      use GGI video driver [default=no]],

                  , enable_video_ggi=no)

    if test x$enable_video = xyes -a x$enable_video_ggi = xyes; then

        AC_MSG_CHECKING(for GGI support)

        video_ggi=no

        AC_TRY_COMPILE([

         #include <ggi/ggi.h>

         #include <ggi/gii.h>

        ],[

        ],[

        video_ggi=yes

        ])

        AC_MSG_RESULT($video_ggi)

        if test x$video_ggi = xyes; then

            CFLAGS="$CFLAGS $X_CFLAGS -DENABLE_GGI"

            SYSTEM_LIBS="$SYSTEM_LIBS -lggi -lgii -lgg"

            VIDEO_SUBDIRS="$VIDEO_SUBDIRS ggi"

            VIDEO_DRIVERS="$VIDEO_DRIVERS ggi/libvideo_ggi.la"

        fi

    fi

}

dnl Find the SVGAlib includes and libraries

CheckSVGA()

{

    AC_ARG_ENABLE(video-svga,

[  --enable-video-svga     use SVGAlib video driver [default=no]],

                  , enable_video_svga=no)

    if test x$enable_video = xyes -a x$enable_video_svga = xyes; then

        AC_MSG_CHECKING(for SVGAlib (1.4.0+) support)

        video_svga=no

        AC_TRY_COMPILE([

         #include <vga.h>

         #include <vgamouse.h>

         #include <vgakeyboard.h>

        ],[

         if ( SCANCODE_RIGHTWIN && SCANCODE_LEFTWIN ) {

             exit(0);

         }

        ],[

        video_svga=yes

        ])

        AC_MSG_RESULT($video_svga)

        if test x$video_svga = xyes; then

            CFLAGS="$CFLAGS -DENABLE_SVGALIB"

            SYSTEM_LIBS="$SYSTEM_LIBS -lvga"

            VIDEO_SUBDIRS="$VIDEO_SUBDIRS svga"

            VIDEO_DRIVERS="$VIDEO_DRIVERS svga/libvideo_svga.la"

        fi

    fi

}

dnl Find the VGL includes and libraries

CheckVGL()

{

    AC_ARG_ENABLE(video-vgl,

[  --enable-video-vgl      use VGL video driver [default=no]],

                  , enable_video_vgl=no)

    if test x$enable_video = xyes -a x$enable_video_vgl = xyes; then

        AC_MSG_CHECKING(for libVGL support)

        video_vgl=no

        AC_TRY_COMPILE([

         #include <sys/fbio.h>

         #include <sys/consio.h>

         #include <sys/kbio.h>

         #include <vgl.h>

        ],[

         VGLBitmap bitmap;

         exit(bitmap.Bitmap);

        ],[

        video_vgl=yes

        ])

        AC_MSG_RESULT($video_vgl)

        if test x$video_vgl = xyes; then

            CFLAGS="$CFLAGS -DENABLE_VGL"

            SYSTEM_LIBS="$SYSTEM_LIBS -lvgl"

            VIDEO_SUBDIRS="$VIDEO_SUBDIRS vgl"

            VIDEO_DRIVERS="$VIDEO_DRIVERS vgl/libvideo_vgl.la"

        fi

    fi

}

dnl Find the AAlib includes

CheckAAlib()

{

    AC_ARG_ENABLE(video-aalib,

[  --enable-video-aalib    use AAlib video driver [default=no]],

                  , enable_video_aalib=no)

    if test x$enable_video = xyes -a x$enable_video_aalib = xyes; then

        AC_MSG_CHECKING(for AAlib support)

        video_aalib=no

        AC_TRY_COMPILE([

         #include <aalib.h>

        ],[

        ],[

        video_aalib=yes

        ])

        AC_MSG_RESULT($video_aalib)

        if test x$video_aalib = xyes; then

            CFLAGS="$CFLAGS -DENABLE_AALIB"

            SYSTEM_LIBS="$SYSTEM_LIBS -laa"

            VIDEO_SUBDIRS="$VIDEO_SUBDIRS aalib"

            VIDEO_DRIVERS="$VIDEO_DRIVERS aalib/libvideo_aa.la"

        fi

    fi

}

dnl Set up the Atari Xbios driver

CheckAtariXbiosVideo()

{

    AC_ARG_ENABLE(xbios,

[  --enable-video-xbios    use Atari Xbios video driver [default=yes]],

                  , enable_video_xbios=yes)

    video_xbios=no

    if test x$enable_video = xyes -a x$enable_video_xbios = xyes; then

        video_xbios=yes

        CFLAGS="$CFLAGS -DENABLE_XBIOS"

        VIDEO_SUBDIRS="$VIDEO_SUBDIRS xbios"

        VIDEO_DRIVERS="$VIDEO_DRIVERS xbios/libvideo_xbios.la"

    fi

}

dnl Set up the Atari Gem driver

CheckAtariGemVideo()

{

    AC_ARG_ENABLE(gem,

[  --enable-video-gem      use Atari Gem video driver [default=yes]],

                  , enable_video_gem=yes)

    if test x$enable_video = xyes -a x$enable_video_gem = xyes; then

        video_gem=no

        AC_CHECK_HEADER(gem.h, have_gem_hdr=yes)

        AC_CHECK_LIB(gem, appl_init, have_gem_lib=yes)

        if test x$have_gem_hdr = xyes -a x$have_gem_lib = xyes; then

            video_gem=yes

            CFLAGS="$CFLAGS -DENABLE_GEM"

            SYSTEM_LIBS="$SYSTEM_LIBS -lgem"

            VIDEO_SUBDIRS="$VIDEO_SUBDIRS gem"

            VIDEO_DRIVERS="$VIDEO_DRIVERS gem/libvideo_gem.la"

        fi

    fi

}

dnl Set up the Atari Bios keyboard driver

CheckAtariBiosEvent()

{

    CFLAGS="$CFLAGS -I\$(top_srcdir)/src/video/ataricommon"