configure.in
author Sam Lantinga <slouken@libsdl.org>
Sat, 03 Oct 2009 08:09:27 +0000
changeset 411 cade1e3a4cb8
parent 406 b67f52365db0
child 419 e27fe0bfe470
permissions -rw-r--r--
Split the mikmod support out into a separate file for clean coding
     1 dnl Process this file with autoconf to produce a configure script.
     2 AC_INIT(README)
     3 
     4 dnl Set various version strings - taken gratefully from the GTk sources
     5 
     6 # Making releases:
     7 #   MICRO_VERSION += 1;
     8 #   INTERFACE_AGE += 1;
     9 #   BINARY_AGE += 1;
    10 # if any functions have been added, set INTERFACE_AGE to 0.
    11 # if backwards compatibility has been broken,
    12 # set BINARY_AGE and INTERFACE_AGE to 0.
    13 #
    14 MAJOR_VERSION=1
    15 MINOR_VERSION=2
    16 MICRO_VERSION=8
    17 INTERFACE_AGE=6
    18 BINARY_AGE=8
    19 VERSION=$MAJOR_VERSION.$MINOR_VERSION.$MICRO_VERSION
    20 
    21 AC_SUBST(MAJOR_VERSION)
    22 AC_SUBST(MINOR_VERSION)
    23 AC_SUBST(MICRO_VERSION)
    24 AC_SUBST(INTERFACE_AGE)
    25 AC_SUBST(BINARY_AGE)
    26 AC_SUBST(VERSION)
    27 
    28 # libtool versioning
    29 LT_RELEASE=$MAJOR_VERSION.$MINOR_VERSION
    30 LT_CURRENT=`expr $MICRO_VERSION - $INTERFACE_AGE`
    31 LT_REVISION=$INTERFACE_AGE
    32 LT_AGE=`expr $BINARY_AGE - $INTERFACE_AGE`
    33 
    34 AC_SUBST(LT_RELEASE)
    35 AC_SUBST(LT_CURRENT)
    36 AC_SUBST(LT_REVISION)
    37 AC_SUBST(LT_AGE)
    38 
    39 dnl Detect the canonical build and host environments
    40 AC_CONFIG_AUX_DIRS($srcdir/build-scripts)
    41 AC_CANONICAL_HOST
    42 
    43 dnl Check for tools
    44 AC_LIBTOOL_WIN32_DLL
    45 AC_PROG_LIBTOOL
    46 AC_PROG_CC
    47 AC_PROG_INSTALL
    48 AC_PROG_MAKE_SET
    49 if test -z "$host_alias"; then
    50     hostaliaswindres=
    51 else
    52     hostaliaswindres="$host_alias-windres"
    53 fi
    54 AC_CHECK_PROGS(WINDRES, [windres $hostaliaswindres $host_os-windres])
    55 
    56 dnl Set up the compiler and linker flags
    57 case "$host" in
    58     *-*-cygwin*)
    59         # We build SDL on cygwin without the UNIX emulation layer
    60         BASE_CFLAGS="-I/usr/include/mingw -mno-cygwin"
    61         BASE_LDFLAGS="-mno-cygwin"
    62         ;;
    63     *)
    64         BASE_CFLAGS="-D_GNU_SOURCE=1"
    65         BASE_LDFLAGS=""
    66         ;;
    67 esac
    68 BUILD_CFLAGS="$CFLAGS $CPPFLAGS"
    69 EXTRA_CFLAGS="$INCLUDE $BASE_CFLAGS"
    70 BUILD_LDFLAGS="$LDFLAGS"
    71 EXTRA_LDFLAGS="$BASE_LDFLAGS"
    72 ## These are common directories to find software packages
    73 #for path in /usr/freeware /usr/pkg /usr/local; do
    74 #    if test -d $path/include; then
    75 #        EXTRA_CFLAGS="$EXTRA_CFLAGS -I$path/include"
    76 #    fi
    77 #    if test -d $path/lib; then
    78 #        EXTRA_LDFLAGS="$EXTRA_LDFLAGS -L$path/lib"
    79 #    fi
    80 #done
    81 CPPFLAGS="$CPPFLAGS $EXTRA_CFLAGS"
    82 CFLAGS="$CFLAGS $EXTRA_CFLAGS"
    83 LDFLAGS="$LDFLAGS $EXTRA_LDFLAGS"
    84 
    85 dnl Check for compiler characteristics
    86 AC_C_CONST
    87 
    88 case "$host" in
    89     *-*-cygwin* | *-*-mingw32*)
    90         SOURCES="$srcdir/version.rc"
    91         EXE=".exe"
    92         if test "$build" != "$host"; then # cross-compiling
    93             # Default cross-compile location
    94             ac_default_prefix=/usr/local/cross-tools/i386-mingw32
    95         else
    96             # Look for the location of the tools and install there
    97             if test "$BUILD_PREFIX" != ""; then
    98                 ac_default_prefix=$BUILD_PREFIX
    99             fi
   100         fi
   101         ;;
   102     *)
   103         SOURCES=""
   104         EXE=""
   105         ;;
   106 esac
   107 
   108 # Standard C sources
   109 SOURCES="$SOURCES \
   110 $srcdir/effect_position.c \
   111 $srcdir/effect_stereoreverse.c \
   112 $srcdir/effects_internal.c \
   113 $srcdir/load_aiff.c \
   114 $srcdir/load_voc.c \
   115 $srcdir/mixer.c \
   116 $srcdir/music.c"
   117 
   118 find_lib()
   119 {
   120     gcc_bin_path=[`$CC -print-search-dirs 2>/dev/null | fgrep programs: | sed 's/[^=]*=\(.*\)/\1/' | sed 's/:/ /g'`]
   121     gcc_lib_path=[`$CC -print-search-dirs 2>/dev/null | fgrep libraries: | sed 's/[^=]*=\(.*\)/\1/' | sed 's/:/ /g'`]
   122     env_lib_path=[`echo $LIBS $LDFLAGS | sed 's/-L[ ]*//g'`]
   123     if test "$cross_compiling" = yes; then
   124         host_lib_path=""
   125     else
   126         host_lib_path="/usr/lib /usr/local/lib"
   127     fi
   128     for path in $gcc_bin_path $gcc_lib_path $env_lib_path $host_lib_path; do
   129         lib=[`ls -- $path/$1 2>/dev/null | sort -r | sed 's/.*\/\(.*\)/\1/; q'`]
   130         if test x$lib != x; then
   131             echo $lib
   132             return
   133         fi
   134     done
   135 }
   136 
   137 dnl Check for SDL
   138 SDL_VERSION=1.2.10
   139 AM_PATH_SDL($SDL_VERSION,
   140             :,
   141             AC_MSG_ERROR([*** SDL version $SDL_VERSION not found!])
   142 )
   143 EXTRA_CFLAGS="$EXTRA_CFLAGS $SDL_CFLAGS"
   144 EXTRA_LDFLAGS="$EXTRA_LDFLAGS $SDL_LIBS"
   145 
   146 dnl Check command-line options
   147 
   148 AC_ARG_ENABLE([music-cmd],
   149 AC_HELP_STRING([--enable-music-cmd], [support an external music player [[default=yes]]]),
   150               [], [enable_music_cmd=yes])
   151 if test x$enable_music_cmd = xyes; then
   152     SOURCES="$SOURCES $srcdir/music_cmd.c"
   153     EXTRA_CFLAGS="$EXTRA_CFLAGS -DCMD_MUSIC"
   154 fi
   155 AC_ARG_ENABLE([music-wave],
   156 AC_HELP_STRING([--enable-music-wave], [enable streaming WAVE music [[default=yes]]]),
   157               [], [enable_music_wave=yes])
   158 if test x$enable_music_wave = xyes; then
   159     SOURCES="$SOURCES $srcdir/wavestream.c"
   160     EXTRA_CFLAGS="$EXTRA_CFLAGS -DWAV_MUSIC"
   161 fi
   162 no_libmikmod=yes
   163 libmikmod_maj=3
   164 libmikmod_min=1
   165 libmikmod_rev=10
   166 libmikmod_ver="$libmikmod_maj.$libmikmod_min.$libmikmod_rev"
   167 AC_ARG_ENABLE([music-libmikmod],
   168 AC_HELP_STRING([--enable-music-libmikmod], [enable MOD music via external libmikmod [[default=no]]]),
   169               [], [enable_music_libmikmod=no])
   170 if test x$enable_music_libmikmod = xyes; then
   171     AC_PATH_PROG(LIBMIKMOD_CONFIG, libmikmod-config, no, [$PATH])
   172     if test "$LIBMIKMOD_CONFIG" != "no" ; then
   173         no_libmikmod=no
   174         CFLAGS_SAVED="$CFLAGS"
   175         LIBS_SAVED="$LIBS"
   176         CFLAGS="$CFLAGS -DLIBMIKMOD_MUSIC `$LIBMIKMOD_CONFIG --cflags`"
   177         LIBS="$LIBS `$LIBMIKMOD_CONFIG --libs`"
   178         AC_MSG_CHECKING([for libmikmod - version >= $libmikmod_ver])
   179         AC_TRY_RUN([
   180 #include "mikmod.h"
   181 #include "stdio.h"
   182 
   183 int main(int argc, char **argv)
   184 {
   185     long maj=$libmikmod_maj,min=$libmikmod_min,rev=$libmikmod_rev,ver=MikMod_GetVersion();
   186     /*printf("(%d.%d.%d) ",ver>>16,(ver>>8)&0xff,ver&0xff);*/
   187     if(ver>=((maj<<16)|(min<<8)|(rev))) {
   188         printf("yes\n");
   189         return 0;
   190     }
   191     printf("no\n*** libmikmod is older than %d.%d.%d, not using.\n",maj,min,rev);
   192     return 1;
   193 }
   194 ], , , [echo $ac_n "cross compiling; assumed OK... $ac_c"])
   195     fi
   196     CFLAGS="$CFLAGS_SAVED"
   197     LIBS="$LIBS_SAVED"
   198 fi
   199 
   200 AC_ARG_ENABLE([music-mod],
   201 AC_HELP_STRING([--enable-music-mod], [enable MOD music via mikmod [[default=yes]]]),
   202               [], [enable_music_mod=yes])
   203 if test x$enable_music_mod = xyes; then
   204     EXTRA_CFLAGS="$EXTRA_CFLAGS -DMOD_MUSIC"
   205     SOURCES="$SOURCES $srcdir/music_mod.c"
   206 
   207     if test x$enable_music_libmikmod = xyes; then
   208         EXTRA_CFLAGS="$EXTRA_CFLAGS -DLIBMIKMOD_MUSIC `$LIBMIKMOD_CONFIG --cflags`"
   209         EXTRA_LDFLAGS="$EXTRA_LDFLAGS `$LIBMIKMOD_CONFIG --libs`"
   210     else
   211         EXTRA_CFLAGS="$EXTRA_CFLAGS -I\$(srcdir)/mikmod"
   212         SOURCES="$SOURCES $srcdir/mikmod/*.c"
   213     fi
   214 fi
   215 AC_ARG_ENABLE([music-midi],
   216 AC_HELP_STRING([--enable-music-midi], [enable MIDI music via timidity [[default=yes]]]),
   217               [], [enable_music_midi=yes])
   218 if test x$enable_music_midi = xyes; then
   219     EXTRA_CFLAGS="$EXTRA_CFLAGS -DMID_MUSIC"
   220     AC_ARG_ENABLE([music-timidity-midi],
   221 AC_HELP_STRING([--enable-music-timidity-midi], [enable timidity MIDI output [[default=yes]]]),
   222                   [], [enable_music_timidity_midi=yes])
   223     if test x$enable_music_timidity_midi = xyes; then
   224         EXTRA_CFLAGS="$EXTRA_CFLAGS -DUSE_TIMIDITY_MIDI -I\$(srcdir)/timidity"
   225         SOURCES="$SOURCES $srcdir/timidity/*.c"
   226     fi
   227     AC_ARG_ENABLE([music-native-midi],
   228 AC_HELP_STRING([--enable-music-native-midi], [enable native MIDI music output [[default=yes]]]),
   229                   [], [enable_music_native_midi=yes])
   230     if test x$enable_music_native_midi = xyes; then
   231         use_music_native_midi=no
   232         case "$host" in
   233             *-*-cygwin* | *-*-mingw32*)
   234                 use_music_native_midi=yes
   235                 EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lwinmm"
   236                 ;;
   237             *-*-darwin*)
   238                 # This doesn't work on Mac OS X 10.5+
   239                 # Max Horn (the original author) recommends disabling it for now.
   240                 #use_music_native_midi=yes
   241                 #EXTRA_LDFLAGS="$EXTRA_LDFLAGS -Wl,-framework,QuickTime -Wl,-framework,CoreServices"
   242                 ;;
   243         esac
   244         if test x$use_music_native_midi = xyes; then
   245             EXTRA_CFLAGS="$EXTRA_CFLAGS -DUSE_NATIVE_MIDI -I\$(srcdir)/native_midi"
   246             SOURCES="$SOURCES $srcdir/native_midi/*.c"
   247         fi
   248     fi
   249     AC_ARG_ENABLE([music-native-midi-gpl],
   250 AC_HELP_STRING([--enable-music-native-midi-gpl], [enable native MIDI on UNIX using GPL code [[default=no]]]),
   251                   [], [enable_music_native_midi_gpl=no])
   252     if test x$enable_music_native_midi_gpl = xyes; then
   253         use_music_native_midi_gpl=no
   254         case "$host" in
   255             *-*-linux* | *-*-freebsd*)
   256                 use_music_native_midi_gpl=yes
   257                 ;;
   258         esac
   259         if test x$use_music_native_midi_gpl = xyes; then
   260             EXTRA_CFLAGS="$EXTRA_CFLAGS -DUSE_NATIVE_MIDI -I\$(srcdir)/native_midi"
   261             SOURCES="$SOURCES $srcdir/native_midi_gpl/*.c"
   262         fi
   263     fi
   264 fi
   265 AC_ARG_ENABLE([music-ogg],
   266 AC_HELP_STRING([--enable-music-ogg], [enable Ogg Vorbis music [[default=yes]]]),
   267               [], [enable_music_ogg=yes])
   268 AC_ARG_ENABLE(music-ogg-tremor,
   269 [  --enable-music-ogg-tremor   enable OGG music via libtremor [[default=no]]],
   270               [], enable_music_ogg_tremor=no)
   271 AC_ARG_ENABLE([music-ogg-shared],
   272 AC_HELP_STRING([--enable-music-ogg-shared], [dynamically load Ogg Vorbis support [[default=yes]]]),
   273               [], [enable_music_ogg_shared=yes])
   274 if test x$enable_music_ogg = xyes; then
   275     if test x$enable_music_ogg_tremor = xyes; then
   276         AC_CHECK_HEADER([tremor/ivorbisfile.h], [have_tremor_hdr=yes])
   277         AC_CHECK_LIB([vorbisidec], [ov_open_callbacks], [have_tremor_lib=yes])
   278         if test x$have_tremor_hdr = xyes -a x$have_tremor_lib = xyes; then
   279             case "$host" in
   280                 *-*-darwin*)
   281                     ogg_lib=[`find_lib libvorbisidec*.dylib`]
   282                     if test x$ogg_lib = x; then
   283                         ogg_lib=[`find_lib libvorbisidec.[0-9]`]
   284                     fi
   285                     if test x$ogg_lib = x; then
   286                         ogg_lib=[`find_lib libvorbisidec.[0-9]*`]
   287                     fi
   288                     ;;
   289                 *-*-cygwin* | *-*-mingw32*)
   290                     ogg_lib=[`find_lib "vorbisidec*.dll"`]
   291                     ;;
   292                 *)
   293                     ogg_lib=[`find_lib "libvorbisidec.so.[0-9]"`]
   294                     if test x$ogg_lib = x; then
   295                         ogg_lib=[`find_lib "libvorbisidec.so.[0-9]*"`]
   296                     fi
   297                     ;;
   298             esac
   299             SOURCES="$SOURCES $srcdir/*_ogg.c"
   300             EXTRA_CFLAGS="$EXTRA_CFLAGS -DOGG_MUSIC -DOGG_USE_TREMOR"
   301             if test x$enable_music_ogg_shared = xyes && test x$ogg_lib != x; then
   302                 echo "-- dynamic libvorbisidec -> $ogg_lib"
   303                 EXTRA_CFLAGS="$EXTRA_CFLAGS -DOGG_DYNAMIC=\\\"$ogg_lib\\\""
   304             else
   305                 EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lvorbisidec"
   306             fi
   307         fi
   308     else
   309         AC_CHECK_HEADER([vorbis/vorbisfile.h], [have_ogg_hdr=yes])
   310         AC_CHECK_LIB([vorbisfile], [ov_open_callbacks], [have_ogg_lib=yes])
   311         if test x$have_ogg_hdr = xyes -a x$have_ogg_lib = xyes; then
   312             case "$host" in
   313                 *-*-darwin*)
   314                     ogg_lib=[`find_lib libvorbisfile*.dylib`]
   315                     ;;
   316                 *-*-cygwin* | *-*-mingw32*)
   317                     ogg_lib=[`find_lib "libvorbisfile*.dll"`]
   318                     ;;
   319                 *)
   320                     ogg_lib=[`find_lib "libvorbisfile.so.[0-9]"`]
   321                     if test x$ogg_lib = x; then
   322                         ogg_lib=[`find_lib "libvorbisfile.so.[0-9]*"`]
   323                     fi
   324                     ;;
   325             esac
   326             SOURCES="$SOURCES $srcdir/*_ogg.c"
   327             EXTRA_CFLAGS="$EXTRA_CFLAGS -DOGG_MUSIC"
   328             if test x$enable_music_ogg_shared = xyes && test x$ogg_lib != x; then
   329                 echo "-- dynamic libvorbisfile -> $ogg_lib"
   330                 EXTRA_CFLAGS="$EXTRA_CFLAGS -DOGG_DYNAMIC=\\\"$ogg_lib\\\""
   331             else
   332                 EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lvorbisfile -lvorbis -logg"
   333             fi
   334         fi
   335     fi
   336 fi
   337 libflac_ver=8
   338 AC_ARG_ENABLE([music-flac],
   339 AC_HELP_STRING([--enable-music-flac], [enable FLAC music [[default=yes]]]),
   340               [], [enable_music_flac=yes])
   341 AC_ARG_ENABLE([music-flac-shared],
   342 AC_HELP_STRING([--enable-music-flac-shared],
   343               [dynamically load FLAC support [[default=yes]]]),
   344               [], [enable_music_flac_shared=yes])
   345 if test x$enable_music_flac = xyes; then
   346 	AC_CHECK_HEADER([FLAC/export.h], [have_flac_export=yes])
   347 	if test x$have_flac_export = xyes; then
   348 		LIBS_SAVED="$LIBS"
   349 		LIBS="-lFLAC"
   350 	    AC_MSG_CHECKING([for libflac so-name version >= $libflac_ver])
   351 	    AC_TRY_RUN([
   352 #include "FLAC/export.h"
   353 #include "stdio.h"
   354 int main( int argc, char *argv[] ) {
   355 #if defined(FLAC_API_VERSION_CURRENT) && (FLAC_API_VERSION_CURRENT >= $libflac_ver)
   356 	return 0;
   357 #else
   358 	return 1;
   359 #endif
   360 }
   361 ], have_flac_ver=yes, have_flac_ver=no)
   362 		LIBS="$LIBS_SAVED"
   363 		AC_MSG_RESULT($have_flac_ver)
   364 		if test x$have_flac_ver = xno; then
   365 			echo "*** FLAC support has been disabled."
   366 		else
   367 			AC_CHECK_HEADER([FLAC/stream_decoder.h], [have_flac_hdr=yes])
   368 			AC_CHECK_LIB([FLAC], [FLAC__stream_decoder_new], [have_flac_lib=yes])
   369 			if test x$have_flac_hdr = xyes -a x$have_flac_lib = xyes; then	
   370 			    case "$host" in
   371 			        *-*-darwin*)
   372 			            flac_lib=[`find_lib FLAC*.dylib`]
   373 			            ;;
   374 			        *-*-cygwin* | *-*-mingw32*)
   375 			            flac_lib=[`find_lib "libFLAC*.dll"`]
   376 			            ;;
   377 			        *)
   378 			            flac_lib=[`find_lib "libFLAC.so.[0-9]"`]
   379 			            if test x$flac_lib = x; then
   380 			                flac_lib=[`find_lib "libFLAC.so.[0-9]*"`]
   381 			            fi
   382 			            ;;
   383 			    esac
   384 			    SOURCES="$SOURCES $srcdir/*_flac.c"
   385 			    EXTRA_CFLAGS="$EXTRA_CFLAGS -DFLAC_MUSIC"
   386 			    if test x$enable_music_flac_shared = xyes && test x$flac_lib != x; then
   387 			        echo "-- dynamic libFLAC -> $flac_lib"
   388 			        EXTRA_CFLAGS="$EXTRA_CFLAGS -DFLAC_DYNAMIC=\\\"$flac_lib\\\""
   389 			    else
   390 			        EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lFLAC"
   391 			    fi
   392 			fi
   393 		fi
   394 	fi
   395 fi
   396 AC_ARG_ENABLE(music-mp3,
   397 [  --enable-music-mp3      enable MP3 music via smpeg [[default=yes]]],
   398               , enable_music_mp3=yes)
   399 if test x$enable_music_mp3 = xyes; then
   400     SMPEG_VERSION=0.4.3
   401     AM_PATH_SMPEG($SMPEG_VERSION, have_smpeg=yes, have_smpeg=no)
   402     if test x$have_smpeg = xyes; then
   403         AC_ARG_ENABLE([music-mp3-shared],
   404 AC_HELP_STRING([--enable-music-mp3-shared], [dynamically load MP3 support [[default=yes]]]),
   405                       [], [enable_music_mp3_shared=yes])
   406         case "$host" in
   407             *-*-darwin*)
   408                 smpeg_lib=[`find_lib libsmpeg*.dylib`]
   409                 ;;
   410             *-*-cygwin* | *-*-mingw32*)
   411                 smpeg_lib=[`find_lib "smpeg*.dll"`]
   412                 ;;
   413             *)
   414                 smpeg_lib=[`find_lib "libsmpeg*.so.[0-9]"`]
   415                 if test x$smpeg_lib = x; then
   416                     smpeg_lib=[`find_lib "libsmpeg*.so.[0-9]*"`]
   417                 fi
   418                 ;;
   419         esac
   420         SOURCES="$SOURCES $srcdir/*_mp3.c"
   421         EXTRA_CFLAGS="$EXTRA_CFLAGS -DMP3_MUSIC $SMPEG_CFLAGS"
   422         if test x$enable_music_mp3_shared = xyes && test x$smpeg_lib != x; then
   423             echo "-- dynamic libsmpeg -> $smpeg_lib"
   424             EXTRA_CFLAGS="$EXTRA_CFLAGS -DMP3_DYNAMIC=\\\"$smpeg_lib\\\""
   425         else
   426             EXTRA_LDFLAGS="$EXTRA_LDFLAGS $SMPEG_LIBS"
   427         fi
   428     fi
   429 fi
   430 AC_ARG_ENABLE(music-mp3-mad-gpl,
   431 AC_HELP_STRING([--enable-music-mp3-mad-gpl], [enable MP3 music via libmad GPL code [[default=no]]]),
   432                   [], [enable_music_mp3_mad_gpl=no])
   433 if test x$enable_music_mp3_mad_gpl = xyes; then
   434     AC_MSG_CHECKING(for libmad headers)
   435     have_libmad=no
   436     AC_TRY_COMPILE([
   437      #include "mad.h"
   438     ],[
   439     ],[
   440     have_libmad=yes
   441     ])
   442     AC_MSG_RESULT($have_libmad)
   443     if test x$have_libmad = xyes; then
   444         SOURCES="$SOURCES $srcdir/music_mad.c"
   445         EXTRA_CFLAGS="$EXTRA_CFLAGS -DMP3_MAD_MUSIC"
   446         EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lmad"
   447     fi
   448 fi
   449 
   450 OBJECTS=`echo $SOURCES | sed 's,[[^ ]]*/\([[^ ]]*\)\.c,$(objects)/\1.lo,g'`
   451 OBJECTS=`echo $OBJECTS | sed 's,[[^ ]]*/\([[^ ]]*\)\.rc,$(objects)/\1.o,g'`
   452 
   453 dnl Expand the sources and objects needed to build the library
   454 AC_SUBST(ac_aux_dir)
   455 AC_SUBST(SOURCES)
   456 AC_SUBST(OBJECTS)
   457 AC_SUBST(BUILD_CFLAGS)
   458 AC_SUBST(EXTRA_CFLAGS)
   459 AC_SUBST(BUILD_LDFLAGS)
   460 AC_SUBST(EXTRA_LDFLAGS)
   461 AC_SUBST(EXE)
   462 AC_SUBST(WINDRES)
   463 AC_SUBST(SDL_VERSION)
   464 AC_SUBST(SDL_CFLAGS)
   465 AC_SUBST(SDL_LIBS)
   466 
   467 AC_OUTPUT([
   468     Makefile SDL_mixer.spec SDL_mixer.qpg SDL_mixer.pc
   469 ], [
   470     : >build-deps
   471     if test x"$MAKE" = x; then MAKE=make; fi; $MAKE depend
   472 ])