/
synth_sse_float.S
245 lines (217 loc) · 4.82 KB
/
synth_sse_float.S
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
/*
synth_sse_float: SSE optimized synth (float output version)
copyright 1995-2009 by the mpg123 project - free software under the terms of the LGPL 2.1
see COPYING and AUTHORS files in distribution or http://mpg123.org
initially written by Taihei Monma
*/
#include "mangle.h"
/* real *window; */
#define WINDOW %ebx
/* real *b0; */
#define B0 %edx
/* real *samples; */
#define SAMPLES %esi
/*
int synth_1to1_real_sse_asm(real *window, real *b0, real *samples, int bo1);
return value: number of clipped samples (0)
*/
#if !defined(__APPLE__) && !defined(__EMX__)
.section .rodata
#else
.data
#endif
ALIGN32
scale_sse:
.long 939524096
.long 939524096
.long 939524096
.long 939524096
.text
ALIGN16
.globl ASM_NAME(synth_1to1_real_sse_asm)
ASM_NAME(synth_1to1_real_sse_asm):
pushl %ebp
movl %esp, %ebp
pushl %ebx
pushl %esi
movl 8(%ebp), WINDOW
movl 12(%ebp), B0
movl 16(%ebp), SAMPLES
movl 20(%ebp), %eax
shll $2, %eax
leal 64(WINDOW), WINDOW
subl %eax, WINDOW
#undef _EBX_
#define _EBX_ %eax
GET_GOT
movl $4, %ecx
ALIGN16
1:
movups (WINDOW), %xmm0
movups 16(WINDOW), %xmm1
movups 32(WINDOW), %xmm2
movups 48(WINDOW), %xmm3
movups 128(WINDOW), %xmm4
movups 144(WINDOW), %xmm5
movups 160(WINDOW), %xmm6
movups 176(WINDOW), %xmm7
mulps 0(B0), %xmm0
mulps 16(B0), %xmm1
mulps 32(B0), %xmm2
mulps 48(B0), %xmm3
mulps 64(B0), %xmm4
mulps 80(B0), %xmm5
mulps 96(B0), %xmm6
mulps 112(B0), %xmm7
addps %xmm1, %xmm0
addps %xmm3, %xmm2
addps %xmm5, %xmm4
addps %xmm7, %xmm6
addps %xmm2, %xmm0
addps %xmm6, %xmm4
movaps %xmm4, %xmm5
movaps %xmm0, %xmm4
leal 256(WINDOW), WINDOW
leal 128(B0), B0
movups (WINDOW), %xmm0
movups 16(WINDOW), %xmm1
movups 32(WINDOW), %xmm2
movups 48(WINDOW), %xmm3
movups 128(WINDOW), %xmm6
movups 144(WINDOW), %xmm7
mulps (B0), %xmm0
mulps 16(B0), %xmm1
mulps 32(B0), %xmm2
mulps 48(B0), %xmm3
mulps 64(B0), %xmm6
mulps 80(B0), %xmm7
addps %xmm1, %xmm0
addps %xmm3, %xmm2
addps %xmm7, %xmm6
movups 160(WINDOW), %xmm1
movups 176(WINDOW), %xmm3
mulps 96(B0), %xmm1
mulps 112(B0), %xmm3
addps %xmm2, %xmm0
addps %xmm3, %xmm1
addps %xmm1, %xmm6
movaps %xmm6, %xmm7
movaps %xmm0, %xmm6
leal 256(WINDOW), WINDOW
leal 128(B0), B0
movaps %xmm4, %xmm0
movaps %xmm6, %xmm1
unpcklps %xmm5, %xmm4
unpcklps %xmm7, %xmm6
unpckhps %xmm5, %xmm0
unpckhps %xmm7, %xmm1
movaps %xmm4, %xmm2
movaps %xmm0, %xmm3
movlhps %xmm6, %xmm4
movhlps %xmm2, %xmm6
movlhps %xmm1, %xmm0
movhlps %xmm3, %xmm1
subps %xmm6, %xmm4
subps %xmm1, %xmm0
addps %xmm4, %xmm0
movups (SAMPLES), %xmm1
movups 16(SAMPLES), %xmm2
mulps LOCAL_VAR(scale_sse), %xmm0
shufps $0xdd, %xmm2, %xmm1
movaps %xmm0, %xmm2
unpcklps %xmm1, %xmm0
unpckhps %xmm1, %xmm2
movups %xmm0, (SAMPLES)
movups %xmm2, 16(SAMPLES)
leal 32(SAMPLES), SAMPLES
decl %ecx
jnz 1b
movl $4, %ecx
ALIGN16
1:
movups (WINDOW), %xmm0
movups 16(WINDOW), %xmm1
movups 32(WINDOW), %xmm2
movups 48(WINDOW), %xmm3
movups 128(WINDOW), %xmm4
movups 144(WINDOW), %xmm5
movups 160(WINDOW), %xmm6
movups 176(WINDOW), %xmm7
mulps 0(B0), %xmm0
mulps 16(B0), %xmm1
mulps 32(B0), %xmm2
mulps 48(B0), %xmm3
mulps -64(B0), %xmm4
mulps -48(B0), %xmm5
mulps -32(B0), %xmm6
mulps -16(B0), %xmm7
addps %xmm1, %xmm0
addps %xmm3, %xmm2
addps %xmm5, %xmm4
addps %xmm7, %xmm6
addps %xmm2, %xmm0
addps %xmm6, %xmm4
movaps %xmm4, %xmm5
movaps %xmm0, %xmm4
leal 256(WINDOW), WINDOW
leal -128(B0), B0
movups (WINDOW), %xmm0
movups 16(WINDOW), %xmm1
movups 32(WINDOW), %xmm2
movups 48(WINDOW), %xmm3
movups 128(WINDOW), %xmm6
movups 144(WINDOW), %xmm7
mulps (B0), %xmm0
mulps 16(B0), %xmm1
mulps 32(B0), %xmm2
mulps 48(B0), %xmm3
mulps -64(B0), %xmm6
mulps -48(B0), %xmm7
addps %xmm1, %xmm0
addps %xmm3, %xmm2
addps %xmm7, %xmm6
movups 160(WINDOW), %xmm1
movups 176(WINDOW), %xmm3
mulps -32(B0), %xmm1
mulps -16(B0), %xmm3
addps %xmm2, %xmm0
addps %xmm3, %xmm1
addps %xmm1, %xmm6
movaps %xmm6, %xmm7
movaps %xmm0, %xmm6
leal 256(WINDOW), WINDOW
leal -128(B0), B0
movaps %xmm4, %xmm0
movaps %xmm6, %xmm1
unpcklps %xmm5, %xmm4
unpcklps %xmm7, %xmm6
unpckhps %xmm5, %xmm0
unpckhps %xmm7, %xmm1
movaps %xmm4, %xmm2
movaps %xmm0, %xmm3
movlhps %xmm6, %xmm4
movhlps %xmm2, %xmm6
movlhps %xmm1, %xmm0
movhlps %xmm3, %xmm1
addps %xmm6, %xmm4
addps %xmm1, %xmm0
addps %xmm4, %xmm0
movups (SAMPLES), %xmm1
movups 16(SAMPLES), %xmm2
mulps LOCAL_VAR(scale_sse), %xmm0
shufps $0xdd, %xmm2, %xmm1
movaps %xmm0, %xmm2
unpcklps %xmm1, %xmm0
unpckhps %xmm1, %xmm2
movups %xmm0, (SAMPLES)
movups %xmm2, 16(SAMPLES)
leal 32(SAMPLES), SAMPLES
decl %ecx
jnz 1b
xorl %eax, %eax
popl %esi
popl %ebx
movl %ebp, %esp
popl %ebp
ret
NONEXEC_STACK