configure.in
author Ozkan Sezer <sezeroz@gmail.com>
Sat, 13 Oct 2018 17:20:02 +0300
branchSDL-1.2
changeset 905 a31a903d1f72
parent 902 6c862e733898
child 907 f4c576887ec3
permissions -rw-r--r--
backport find_lib() fix to get the latest version of the libraries.

(default 2.0 branch commit: ffac9e0ac797)
     1 dnl Process this file with autoconf to produce a configure script.
     2 AC_INIT(README)
     3 AC_CONFIG_AUX_DIR(build-scripts)
     4 
     5 dnl Set various version strings - taken gratefully from the GTk sources
     6 
     7 # Making releases:
     8 #   MICRO_VERSION += 1;
     9 #   INTERFACE_AGE += 1;
    10 #   BINARY_AGE += 1;
    11 # if any functions have been added, set INTERFACE_AGE to 0.
    12 # if backwards compatibility has been broken,
    13 # set BINARY_AGE and INTERFACE_AGE to 0.
    14 #
    15 MAJOR_VERSION=1
    16 MINOR_VERSION=2
    17 MICRO_VERSION=13
    18 INTERFACE_AGE=1
    19 BINARY_AGE=13
    20 VERSION=$MAJOR_VERSION.$MINOR_VERSION.$MICRO_VERSION
    21 
    22 AC_SUBST(MAJOR_VERSION)
    23 AC_SUBST(MINOR_VERSION)
    24 AC_SUBST(MICRO_VERSION)
    25 AC_SUBST(INTERFACE_AGE)
    26 AC_SUBST(BINARY_AGE)
    27 AC_SUBST(VERSION)
    28 
    29 # libtool versioning
    30 LT_INIT([win32-dll])
    31 
    32 LT_RELEASE=$MAJOR_VERSION.$MINOR_VERSION
    33 LT_CURRENT=`expr $MICRO_VERSION - $INTERFACE_AGE`
    34 LT_REVISION=$INTERFACE_AGE
    35 LT_AGE=`expr $BINARY_AGE - $INTERFACE_AGE`
    36 m4_pattern_allow([^LT_])
    37 
    38 AC_SUBST(LT_RELEASE)
    39 AC_SUBST(LT_CURRENT)
    40 AC_SUBST(LT_REVISION)
    41 AC_SUBST(LT_AGE)
    42 
    43 dnl Detect the canonical build and host environments
    44 AC_CONFIG_AUX_DIRS($srcdir/build-scripts)
    45 dnl AC_CANONICAL_HOST
    46 
    47 dnl Check for tools
    48 AC_PROG_LIBTOOL
    49 AC_PROG_CC
    50 AC_PROG_INSTALL
    51 AC_PROG_MAKE_SET
    52 if test -z "$host_alias"; then
    53     hostaliaswindres=
    54 else
    55     hostaliaswindres="$host_alias-windres"
    56 fi
    57 AC_CHECK_PROGS(WINDRES, [windres $hostaliaswindres $host_os-windres])
    58 
    59 dnl Set up the compiler and linker flags
    60 case "$host" in
    61     *-*-cygwin*)
    62         # We build SDL on cygwin without the UNIX emulation layer
    63         BASE_CFLAGS="-I/usr/include/mingw -mno-cygwin"
    64         BASE_LDFLAGS="-mno-cygwin"
    65         ;;
    66     *)
    67         BASE_CFLAGS="-D_GNU_SOURCE=1"
    68         BASE_LDFLAGS=""
    69         ;;
    70 esac
    71 BUILD_CFLAGS="$CFLAGS $CPPFLAGS"
    72 EXTRA_CFLAGS="$INCLUDE $BASE_CFLAGS"
    73 BUILD_LDFLAGS="$LDFLAGS"
    74 EXTRA_LDFLAGS="$BASE_LDFLAGS"
    75 ## These are common directories to find software packages
    76 #for path in /usr/freeware /usr/pkg /usr/local; do
    77 #    if test -d $path/include; then
    78 #        EXTRA_CFLAGS="$EXTRA_CFLAGS -I$path/include"
    79 #    fi
    80 #    if test -d $path/lib; then
    81 #        EXTRA_LDFLAGS="$EXTRA_LDFLAGS -L$path/lib"
    82 #    fi
    83 #done
    84 CPPFLAGS="$CPPFLAGS $EXTRA_CFLAGS"
    85 CFLAGS="$CFLAGS $EXTRA_CFLAGS"
    86 LDFLAGS="$LDFLAGS $EXTRA_LDFLAGS"
    87 
    88 dnl Check for compiler characteristics
    89 AC_C_CONST
    90 
    91 dnl See whether we can use gcc style dependency tracking
    92 AC_ARG_ENABLE(dependency-tracking,
    93 AC_HELP_STRING([--enable-dependency-tracking],
    94                [Use gcc -MMD -MT dependency tracking [[default=yes]]]),
    95               , enable_dependency_tracking=yes)
    96 if test x$enable_dependency_tracking = xyes; then
    97     have_gcc_mmd_mt=no
    98     AC_MSG_CHECKING(for GCC -MMD -MT option)
    99     AC_TRY_COMPILE([
   100     #if !defined(__GNUC__) || __GNUC__ < 3
   101     #error Dependency tracking requires GCC 3.0 or newer
   102     #endif
   103     ],[
   104     ],[
   105     have_gcc_mmd_mt=yes
   106     ])
   107     AC_MSG_RESULT($have_gcc_mmd_mt)
   108 
   109     if test x$have_gcc_mmd_mt = xyes; then
   110         DEPENDENCY_TRACKING_OPTIONS="-MMD -MT \$@"
   111     fi
   112 fi
   113     
   114 case "$host" in
   115     *mingw32ce*)
   116         #VERSION_SOURCES="$srcdir/version.rc"
   117         EXE=".exe"
   118 	;;
   119     *-*-cygwin* | *-*-mingw32*)
   120         VERSION_SOURCES="$srcdir/version.rc"
   121         EXE=".exe"
   122         if test "$build" != "$host"; then # cross-compiling
   123             # Default cross-compile location
   124             ac_default_prefix=/usr/local/cross-tools/i386-mingw32
   125         else
   126             # Look for the location of the tools and install there
   127             if test "$BUILD_PREFIX" != ""; then
   128                 ac_default_prefix=$BUILD_PREFIX
   129             fi
   130         fi
   131         ;;
   132     *)
   133         SOURCES=""
   134         EXE=""
   135         ;;
   136 esac
   137 
   138 # Standard C sources
   139 SOURCES="$SOURCES \
   140 $srcdir/effect_position.c \
   141 $srcdir/effect_stereoreverse.c \
   142 $srcdir/effects_internal.c \
   143 $srcdir/load_aiff.c \
   144 $srcdir/load_voc.c \
   145 $srcdir/mixer.c \
   146 $srcdir/music.c"
   147 
   148 dnl set this to use on systems that use lib64 instead of lib
   149 base_libdir=`echo \${libdir} | sed 's/.*\/\(.*\)/\1/; q'`
   150 
   151 dnl See if GCC's -fvisibility=hidden is supported (gcc4 and later, usually).
   152 dnl  Details of this flag are here: http://gcc.gnu.org/wiki/Visibility
   153 CheckVisibilityHidden()
   154 {
   155     AC_MSG_CHECKING(for GCC -fvisibility=hidden option)
   156     have_gcc_fvisibility=no
   157 
   158     visibility_CFLAGS="-fvisibility=hidden"
   159     save_CFLAGS="$CFLAGS"
   160     CFLAGS="$save_CFLAGS $visibility_CFLAGS -Werror"
   161     AC_TRY_COMPILE([
   162     #if !defined(__GNUC__) || __GNUC__ < 4
   163     #error SDL only uses visibility attributes in GCC 4 or newer
   164     #endif
   165     ],[
   166     ],[
   167     have_gcc_fvisibility=yes
   168     ])
   169     AC_MSG_RESULT($have_gcc_fvisibility)
   170     CFLAGS="$save_CFLAGS"
   171 
   172     if test x$have_gcc_fvisibility = xyes; then
   173         EXTRA_CFLAGS="$EXTRA_CFLAGS $visibility_CFLAGS"
   174     fi
   175 }
   176 
   177 
   178 dnl Function to find a library in the compiler search path
   179 find_lib()
   180 {
   181     gcc_bin_path=[`$CC -print-search-dirs 2>/dev/null | fgrep programs: | sed 's/[^=]*=\(.*\)/\1/' | sed 's/:/ /g'`]
   182     gcc_lib_path=[`$CC -print-search-dirs 2>/dev/null | fgrep libraries: | sed 's/[^=]*=\(.*\)/\1/' | sed 's/:/ /g'`]
   183     env_lib_path=[`echo $LIBS $LDFLAGS $* | sed 's/-L[ ]*//g'`]
   184     if test "$cross_compiling" = yes; then
   185         host_lib_path=""
   186     else
   187         host_lib_path="/usr/$base_libdir /usr/local/$base_libdir"
   188     fi
   189     for path in $env_lib_path $gcc_bin_path $gcc_lib_path $host_lib_path; do
   190         lib=[`ls -- $path/$1 2>/dev/null | sed -e '/\.so\..*\./d' -e 's,.*/,,' | sort | tail -1`]
   191         if test x$lib != x; then
   192             echo $lib
   193             return
   194         fi
   195     done
   196 }
   197 
   198 dnl Check for SDL
   199 SDL_VERSION=1.2.10
   200 AM_PATH_SDL($SDL_VERSION,
   201             :,
   202             AC_MSG_ERROR([*** SDL version $SDL_VERSION not found!])
   203 )
   204 EXTRA_CFLAGS="$EXTRA_CFLAGS $SDL_CFLAGS"
   205 EXTRA_LDFLAGS="$EXTRA_LDFLAGS $SDL_LIBS"
   206 
   207 dnl Check for math library
   208 AC_CHECK_LIB(m, pow, [LIBM="-lm"])
   209 
   210 dnl Check command-line options
   211 
   212 CheckVisibilityHidden
   213 
   214 AC_ARG_ENABLE([music-cmd],
   215 AC_HELP_STRING([--enable-music-cmd], [support an external music player [[default=yes]]]),
   216               [], [enable_music_cmd=detect])
   217 if test "x$enable_music_cmd" != xno; then
   218     AC_CHECK_FUNCS([fork vfork])
   219     if test "x$ac_cv_func_fork" = "xyes"; then
   220         EXTRA_CFLAGS="$EXTRA_CFLAGS -DHAVE_FORK"
   221     elif test "x$ac_cv_func_vfork" = "xyes"; then
   222         EXTRA_CFLAGS="$EXTRA_CFLAGS -DHAVE_VFORK"
   223     elif test "x$enable_music_cmd" = "xyes"; then
   224         AC_MSG_ERROR([external music player not available on your platform])
   225     else
   226         enable_music_cmd=no
   227     fi
   228     if test "x$enable_music_cmd" != xno; then
   229         SOURCES="$SOURCES $srcdir/music_cmd.c"
   230         EXTRA_CFLAGS="$EXTRA_CFLAGS -DCMD_MUSIC"
   231     fi
   232 fi
   233 
   234 AC_ARG_ENABLE([music-wave],
   235 AC_HELP_STRING([--enable-music-wave], [enable streaming WAVE music [[default=yes]]]),
   236               [], [enable_music_wave=yes])
   237 if test x$enable_music_wave = xyes; then
   238     SOURCES="$SOURCES $srcdir/wavestream.c"
   239     EXTRA_CFLAGS="$EXTRA_CFLAGS -DWAV_MUSIC"
   240 fi
   241 
   242 AC_ARG_ENABLE([music-mod],
   243 AC_HELP_STRING([--enable-music-mod], [enable MOD music via mikmod [[default=yes]]]),
   244               [], [enable_music_mod=yes])
   245 AC_ARG_ENABLE([music-mod-shared],
   246 AC_HELP_STRING([--enable-music-mod-shared], [dynamically load MOD support [[default=yes]]]),
   247               [], [enable_music_mod_shared=yes])
   248 if test x$enable_music_mod = xyes; then
   249     have_libmikmod=no
   250     libmikmod_maj=3
   251     libmikmod_min=1
   252     libmikmod_rev=10
   253     libmikmod_ver="$libmikmod_maj.$libmikmod_min.$libmikmod_rev"
   254     AC_PATH_PROG(LIBMIKMOD_CONFIG, libmikmod-config, no, [$PATH])
   255     if test "$LIBMIKMOD_CONFIG" != "no" ; then
   256         
   257         CFLAGS_SAVED="$CFLAGS"
   258         LIBS_SAVED="$LIBS"
   259         CFLAGS="$CFLAGS -DLIBMIKMOD_MUSIC `$LIBMIKMOD_CONFIG --cflags`"
   260         LIBS="$LIBS `$LIBMIKMOD_CONFIG --libs`"
   261         have_libmikmod=yes
   262         AC_MSG_CHECKING([for libmikmod - version >= $libmikmod_ver])
   263         AC_TRY_RUN([
   264 #include "mikmod.h"
   265 #include "stdio.h"
   266 
   267 int main(int argc, char **argv)
   268 {
   269 long maj=$libmikmod_maj,min=$libmikmod_min,rev=$libmikmod_rev,ver=MikMod_GetVersion();
   270 /*printf("(%d.%d.%d) ",ver>>16,(ver>>8)&0xff,ver&0xff);*/
   271 if(ver>=((maj<<16)|(min<<8)|(rev))) {
   272     printf("yes\n");
   273     return 0;
   274 }
   275 printf("no\n*** libmikmod is older than %d.%d.%d, not using.\n",maj,min,rev);
   276 return 1;
   277 }
   278 ], [], have_libmikmod=no; CFLAGS="$CFLAGS_SAVED"; LIBS="$LIBS_SAVED",
   279         [echo $ac_n "cross compiling; assumed OK... $ac_c"])
   280     fi
   281 
   282     if test x$have_libmikmod = xyes; then
   283         case "$host" in
   284             *-*-darwin*)
   285                 mikmod_lib=[`find_lib libmikmod.dylib`]
   286                 ;;
   287             *-*-cygwin* | *-*-mingw32*)
   288                 mikmod_lib=[`find_lib "libmikmod*.dll"`]
   289                 ;;
   290             *)
   291                 mikmod_lib=[`find_lib "libmikmod[0-9]*.so.*"`]
   292                 if test x$mikmod_lib = x; then
   293                     mikmod_lib=[`find_lib "libmikmod.so.*"`]
   294                 fi
   295                 ;;
   296         esac
   297         SOURCES="$SOURCES $srcdir/*_mod.c"
   298         EXTRA_CFLAGS="$EXTRA_CFLAGS -DMOD_MUSIC `$LIBMIKMOD_CONFIG --cflags`"
   299         if test x$enable_music_mod_shared = xyes && test x$mikmod_lib != x; then
   300             echo "-- dynamic libmikmod -> $mikmod_lib"
   301             EXTRA_CFLAGS="$EXTRA_CFLAGS -DMOD_DYNAMIC=\\\"$mikmod_lib\\\""
   302         else
   303             EXTRA_LDFLAGS="$EXTRA_LDFLAGS `$LIBMIKMOD_CONFIG --libs`"
   304         fi
   305     else
   306         AC_MSG_WARN([*** Unable to find MikMod library (http://mikmod.raphnet.net/)])
   307     fi
   308 fi
   309 
   310 AC_ARG_ENABLE([music-mod-modplug],
   311 AC_HELP_STRING([--enable-music-mod-modplug], [enable MOD music via modplug [[default=no]]]),
   312               [], [enable_music_mod_modplug=no])
   313 if test x$enable_music_mod_modplug = xyes; then
   314 	PKG_CHECK_MODULES([MODPLUG], [libmodplug >= 0.8.7])
   315 	EXTRA_CFLAGS="$EXTRA_CFLAGS -DMODPLUG_MUSIC  $MODPLUG_CFLAGS"
   316 	EXTRA_LDFLAGS="$EXTRA_LDFLAGS $MODPLUG_LIBS"
   317 dnl	AC_TRY_COMPILE([
   318 dnl     #include "modplug.h"
   319 dnl    ],[
   320 dnl    ],[
   321     have_libmodplug=yes
   322     SOURCES="$SOURCES $srcdir/music_modplug.c"
   323 dnl    ])
   324 else
   325 	have_libmodplug=no
   326 fi
   327 
   328 if test x$have_libmikmod != xyes -a x$have_libmodplug != xyes ; then
   329 	AC_MSG_WARN([MOD support disabled])
   330 fi
   331 
   332 AC_ARG_ENABLE([music-midi],
   333 AC_HELP_STRING([--enable-music-midi], [enable MIDI music via timidity [[default=yes]]]),
   334               [], [enable_music_midi=yes])
   335 if test x$enable_music_midi = xyes; then
   336     EXTRA_CFLAGS="$EXTRA_CFLAGS -DMID_MUSIC"
   337     AC_ARG_ENABLE([music-timidity-midi],
   338 AC_HELP_STRING([--enable-music-timidity-midi], [enable timidity MIDI output [[default=yes]]]),
   339                   [], [enable_music_timidity_midi=yes])
   340     if test x$enable_music_timidity_midi = xyes; then
   341         EXTRA_CFLAGS="$EXTRA_CFLAGS -DUSE_TIMIDITY_MIDI -I\$(srcdir)/timidity"
   342         SOURCES="$SOURCES $srcdir/timidity/*.c"
   343     fi
   344     AC_ARG_ENABLE([music-native-midi],
   345 AC_HELP_STRING([--enable-music-native-midi], [enable native MIDI music output [[default=yes]]]),
   346                   [], [enable_music_native_midi=yes])
   347     if test x$enable_music_native_midi = xyes; then
   348         use_music_native_midi=no
   349         case "$host" in
   350             *mingw32ce*)
   351                 use_music_native_midi=no
   352                 ;;
   353             *-*-cygwin* | *-*-mingw32*)
   354                 use_music_native_midi=yes
   355                 EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lwinmm"
   356                 ;;
   357             *-*-darwin*)
   358                 use_music_native_midi=yes
   359                 EXTRA_LDFLAGS="$EXTRA_LDFLAGS -Wl,-framework,AudioToolbox -Wl,-framework,AudioUnit -Wl,-framework,CoreServices"
   360                 ;;
   361             *-*-haiku*)
   362                 use_music_native_midi=yes_cpp
   363                 EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lmidi" 
   364                 ;;
   365         esac
   366         if test x$use_music_native_midi = xyes; then
   367             EXTRA_CFLAGS="$EXTRA_CFLAGS -DUSE_NATIVE_MIDI -I\$(srcdir)/native_midi"
   368             SOURCES="$SOURCES $srcdir/native_midi/*.c"
   369         elif test x$use_music_native_midi = xyes_cpp; then
   370             EXTRA_CFLAGS="$EXTRA_CFLAGS -DUSE_NATIVE_MIDI -I\$(srcdir)/native_midi"
   371             SOURCES="$SOURCES $srcdir/native_midi/*.c"
   372             SOURCES_CXX="$SOURCES_CXX $srcdir/native_midi/*.cpp"
   373         fi
   374     fi
   375     AC_ARG_ENABLE([music-fluidsynth-midi],
   376 AC_HELP_STRING([--enable-music-fluidsynth-midi], [enable FluidSynth MIDI output [[default=yes]]]),
   377                   [], [enable_music_fluidsynth_midi=yes])
   378     AC_ARG_ENABLE([music-fluidsynth-shared],
   379 AC_HELP_STRING([--enable-music-fluidsynth-shared], [dynamically load FluidSynth support [[default=yes]]]),
   380                   [], [enable_music_fluidsynth_shared=yes])
   381     if test x$enable_music_fluidsynth_midi = xyes; then
   382         AC_CHECK_HEADER([fluidsynth.h], [have_fluidsynth_hdr=yes])
   383         AC_CHECK_LIB([fluidsynth], [fluid_player_add_mem], [have_fluidsynth_lib=yes])
   384         if test x$have_fluidsynth_hdr = xyes -a x$have_fluidsynth_lib = xyes; then
   385             case "$host" in
   386                 *-*-darwin*)
   387                     fluidsynth_lib=[`find_lib libfluidsynth.dylib`]
   388                     ;;
   389                 *-*-cygwin* | *-*-mingw32*)
   390                     fluidsynth_lib=[`find_lib "fluidsynth*.dll"`]
   391                     ;;
   392                 *)
   393                     fluidsynth_lib=[`find_lib "libfluidsynth[0-9]*.so.*"`]
   394                     if test x$fluidsynth_lib = x; then
   395                         fluidsynth_lib=[`find_lib "libfluidsynth.so.*"`]
   396                     fi
   397                     ;;
   398             esac
   399             SOURCES="$SOURCES $srcdir/dynamic_fluidsynth.c $srcdir/fluidsynth.c"
   400             EXTRA_CFLAGS="$EXTRA_CFLAGS -DUSE_FLUIDSYNTH_MIDI"
   401             if test x$enable_music_fluidsynth_shared = xyes && test x$fluidsynth_lib != x; then
   402                 echo "-- dynamic libfluidsyth -> $fluidsynth_lib"
   403                 EXTRA_CFLAGS="$EXTRA_CFLAGS -DFLUIDSYNTH_DYNAMIC=\\\"$fluidsynth_lib\\\""
   404             else
   405                 EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lfluidsynth"
   406             fi
   407         else
   408             AC_MSG_WARN([*** Unable to find FluidSynth library (http://www.fluidsynth.org/)])
   409             AC_MSG_WARN([FluidSynth support disabled])
   410         fi
   411     fi
   412 fi
   413 
   414 AC_ARG_ENABLE([music-ogg],
   415 AC_HELP_STRING([--enable-music-ogg], [enable Ogg Vorbis music [[default=yes]]]),
   416               [], [enable_music_ogg=yes])
   417 AC_ARG_ENABLE(music-ogg-tremor,
   418 AC_HELP_STRING([--enable-music-ogg-tremor], [enable OGG Vorbis music via libtremor [[default=no]]]),
   419               [], enable_music_ogg_tremor=no)
   420 AC_ARG_ENABLE([music-ogg-shared],
   421 AC_HELP_STRING([--enable-music-ogg-shared], [dynamically load Ogg Vorbis support [[default=yes]]]),
   422               [], [enable_music_ogg_shared=yes])
   423 if test x$enable_music_ogg = xyes; then
   424     if test x$enable_music_ogg_tremor = xyes; then
   425         AC_CHECK_HEADER([tremor/ivorbisfile.h], [have_tremor_hdr=yes])
   426         AC_CHECK_LIB([vorbisidec -logg], [ov_open_callbacks], [have_tremor_lib=yes])
   427         if test x$have_tremor_hdr = xyes -a x$have_tremor_lib = xyes; then
   428             case "$host" in
   429                 *-*-darwin*)
   430                     ogg_lib=[`find_lib libvorbisidec.dylib`]
   431                     ;;
   432                 *-*-cygwin* | *-*-mingw32*)
   433                     ogg_lib=[`find_lib "vorbisidec*.dll"`]
   434                     ;;
   435                 *)
   436                     ogg_lib=[`find_lib "libvorbisidec[0-9]*.so.*"`]
   437                     if test x$ogg_lib = x; then
   438                         ogg_lib=[`find_lib "libvorbisidec.so.*"`]
   439                     fi
   440                     ;;
   441             esac
   442             SOURCES="$SOURCES $srcdir/*_ogg.c"
   443             EXTRA_CFLAGS="$EXTRA_CFLAGS -DOGG_MUSIC -DOGG_USE_TREMOR"
   444             if test x$enable_music_ogg_shared = xyes && test x$ogg_lib != x; then
   445                 echo "-- dynamic libvorbisidec -> $ogg_lib"
   446                 EXTRA_CFLAGS="$EXTRA_CFLAGS -DOGG_DYNAMIC=\\\"$ogg_lib\\\""
   447             else
   448                 EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lvorbisidec -lvorbis"
   449             fi
   450         else
   451             AC_MSG_WARN([*** Unable to find Ogg Vorbis Tremor library (http://www.xiph.org/)])
   452             AC_MSG_WARN([Ogg Vorbis support disabled])
   453         fi
   454     else
   455         AC_CHECK_HEADER([vorbis/vorbisfile.h], [have_ogg_hdr=yes])
   456         AC_CHECK_LIB([vorbisfile -lvorbis -logg -lm], [ov_open_callbacks], [have_ogg_lib=yes])
   457         if test x$have_ogg_hdr = xyes -a x$have_ogg_lib = xyes; then
   458             case "$host" in
   459                 *-*-darwin*)
   460                     ogg_lib=[`find_lib libvorbisfile.dylib`]
   461                     ;;
   462                 *-*-cygwin* | *-*-mingw32*)
   463                     ogg_lib=[`find_lib "libvorbisfile*.dll"`]
   464                     ;;
   465                 *)
   466                     ogg_lib=[`find_lib "libvorbisfile[0-9]*.so.*"`]
   467                     if test x$ogg_lib = x; then
   468                         ogg_lib=[`find_lib "libvorbisfile.so.*"`]
   469                     fi
   470                     ;;
   471             esac
   472             SOURCES="$SOURCES $srcdir/*_ogg.c"
   473             EXTRA_CFLAGS="$EXTRA_CFLAGS -DOGG_MUSIC"
   474             if test x$enable_music_ogg_shared = xyes && test x$ogg_lib != x; then
   475                 echo "-- dynamic libvorbisfile -> $ogg_lib"
   476                 EXTRA_CFLAGS="$EXTRA_CFLAGS -DOGG_DYNAMIC=\\\"$ogg_lib\\\""
   477             else
   478                 EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lvorbisfile -lvorbis -logg -lm"
   479             fi
   480         else
   481             AC_MSG_WARN([*** Unable to find Ogg Vorbis library (http://www.xiph.org/)])
   482             AC_MSG_WARN([Ogg Vorbis support disabled])
   483         fi
   484     fi
   485 fi
   486 
   487 libflac_ver=8
   488 AC_ARG_ENABLE([music-flac],
   489 AC_HELP_STRING([--enable-music-flac], [enable FLAC music [[default=yes]]]),
   490               [], [enable_music_flac=yes])
   491 AC_ARG_ENABLE([music-flac-shared],
   492 AC_HELP_STRING([--enable-music-flac-shared],
   493               [dynamically load FLAC support [[default=yes]]]),
   494               [], [enable_music_flac_shared=yes])
   495 if test x$enable_music_flac = xyes; then
   496     AC_CHECK_HEADER([FLAC/export.h], [have_flac_export=yes])
   497     if test x$have_flac_export = xyes; then
   498         LIBS_SAVED="$LIBS"
   499         LIBS="-lFLAC"
   500         AC_MSG_CHECKING([for libflac so-name version >= $libflac_ver])
   501         AC_TRY_COMPILE([
   502 #include "FLAC/export.h"
   503 #include "stdio.h"
   504 ],[
   505 #if defined(FLAC_API_VERSION_CURRENT) && (FLAC_API_VERSION_CURRENT >= $libflac_ver)
   506 #else
   507 #error "old-flac"
   508 #endif
   509 ], have_flac_ver=yes, have_flac_ver=no)
   510         LIBS="$LIBS_SAVED"
   511         AC_MSG_RESULT($have_flac_ver)
   512     fi
   513 
   514     if test x$have_flac_ver = xyes; then
   515         AC_CHECK_HEADER([FLAC/stream_decoder.h], [have_flac_hdr=yes])
   516         AC_CHECK_LIB([FLAC], [FLAC__stream_decoder_new], [have_flac_lib=yes])
   517         if test x$have_flac_hdr = xyes -a x$have_flac_lib = xyes; then    
   518             case "$host" in
   519                 *-*-darwin*)
   520                     flac_lib=[`find_lib libFLAC.dylib`]
   521                     ;;
   522                 *-*-cygwin* | *-*-mingw32*)
   523                     flac_lib=[`find_lib "libFLAC-*.dll"`]
   524                     ;;
   525                 *)
   526                     flac_lib=[`find_lib "libFLAC[0-9]*.so.*"`]
   527                     if test x$flac_lib = x; then
   528                         flac_lib=[`find_lib "libFLAC.so.*"`]
   529                     fi
   530                     ;;
   531             esac
   532             SOURCES="$SOURCES $srcdir/*_flac.c"
   533             EXTRA_CFLAGS="$EXTRA_CFLAGS -DFLAC_MUSIC"
   534             if test x$enable_music_flac_shared = xyes && test x$flac_lib != x; then
   535                 echo "-- dynamic libFLAC -> $flac_lib"
   536                 EXTRA_CFLAGS="$EXTRA_CFLAGS -DFLAC_DYNAMIC=\\\"$flac_lib\\\""
   537             else
   538                 EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lFLAC"
   539             fi
   540         fi
   541     else
   542         AC_MSG_WARN([*** Unable to find FLAC library (http://flac.sourceforge.net/)])
   543         AC_MSG_WARN([FLAC support disabled])
   544     fi
   545 fi
   546 
   547 AC_CHECK_HEADERS([signal.h], [EXTRA_CFLAGS="$EXTRA_CFLAGS -DHAVE_SIGNAL_H"])
   548 AC_CHECK_FUNCS(setbuf, [EXTRA_CFLAGS="$EXTRA_CFLAGS -DHAVE_SETBUF"])
   549 
   550 AC_ARG_ENABLE(music-mp3,
   551 AC_HELP_STRING([--enable-music-mp3], [enable MP3 music via libmpg123 [[default=yes]]]),
   552               [], enable_music_mp3=yes)
   553 AC_ARG_ENABLE([music-mp3-shared],
   554 AC_HELP_STRING([--enable-music-mp3-shared], [dynamically load MP3 support [[default=yes]]]),
   555               [], [enable_music_mp3_shared=yes])
   556 if test x$enable_music_mp3 = xyes; then
   557     AC_CHECK_HEADER([mpg123.h], [have_mpg123_hdr=yes])
   558     AC_CHECK_LIB([mpg123], [mpg123_replace_reader_handle], [have_mpg123_lib=yes])
   559     if test x$have_mpg123_hdr = xyes -a x$have_mpg123_lib = xyes; then
   560         have_mpg123=yes
   561         case "$host" in
   562             *-*-darwin*)
   563                 mpg123_lib=[`find_lib libmpg123.dylib`]
   564                 ;;
   565             *-*-cygwin* | *-*-mingw32*)
   566                 mpg123_lib=[`find_lib "libmpg123*.dll"`]
   567                 ;;
   568             *)
   569                 mpg123_lib=[`find_lib "libmpg123.so.*"`]
   570                 ;;
   571         esac
   572         SOURCES="$SOURCES $srcdir/*_mp3.c $srcdir/*_mpg.c"
   573         EXTRA_CFLAGS="$EXTRA_CFLAGS -DMP3_MUSIC"
   574         if test x$enable_music_mp3_shared = xyes && test x$mpg123_lib != x; then
   575             echo "-- dynamic libmpg123 -> $mpg123_lib"
   576             EXTRA_CFLAGS="$EXTRA_CFLAGS -DMPG123_DYNAMIC=\\\"$mpg123_lib\\\""
   577         else
   578             EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lmpg123"
   579         fi
   580     else
   581         AC_MSG_WARN([*** Unable to find mpg123 library (https://www.mpg123.de)])
   582     fi
   583 fi
   584 
   585 AC_ARG_ENABLE(music-mp3-mad-gpl,
   586 AC_HELP_STRING([--enable-music-mp3-mad-gpl], [enable MP3 music via libmad GPL code [[default=no]]]),
   587                   [], [enable_music_mp3_mad_gpl=no])
   588 if test x$enable_music_mp3_mad_gpl = xyes; then
   589     AC_MSG_CHECKING(for libmad headers)
   590     have_libmad=no
   591     AC_TRY_COMPILE([
   592      #include "mad.h"
   593     ],[
   594     ],[
   595     have_libmad=yes
   596     ])
   597     AC_MSG_RESULT($have_libmad)
   598     if test x$have_libmad = xyes; then
   599         SOURCES="$SOURCES $srcdir/music_mad.c"
   600         EXTRA_CFLAGS="$EXTRA_CFLAGS -DMP3_MAD_MUSIC"
   601         EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lmad"
   602     else
   603         AC_MSG_WARN([*** Unable to find MAD library (http://www.underbit.com/products/mad/)])
   604     fi
   605 fi
   606 
   607 if test x$have_mpg123 != xyes -a x$have_libmad != xyes; then
   608     AC_MSG_WARN([MP3 support disabled])
   609 fi
   610 
   611 EXTRA_LDFLAGS="$EXTRA_LDFLAGS $LIBM"
   612 
   613 OBJECTS=`echo $SOURCES`
   614 DEPENDS=`echo $SOURCES`
   615 OBJECTS=`echo "$OBJECTS" | sed 's,[[^ ]]*/\([[^ ]]*\)\.c,$(objects)/\1.lo,g'`
   616 DEPENDS=`echo "$DEPENDS" | sed 's,\([[^ ]]*\)/\([[^ ]]*\)\.c,\\
   617 $(objects)/\2.lo: \1/\2.c\\
   618 	\$(LIBTOOL) --mode=compile \$(CC) \$(CFLAGS) \$(EXTRA_CFLAGS) '"$DEPENDENCY_TRACKING_OPTIONS"' -c \$< -o \$@,g'`
   619 
   620 OBJECTS_CXX=`echo $SOURCES_CXX`
   621 DEPENDS_CXX=`echo $SOURCES_CXX`
   622 OBJECTS_CXX=`echo "$OBJECTS_CXX" | sed 's,[[^ ]]*/\([[^ ]]*\)\.cpp,$(objects)/\1.lo,g'`
   623 DEPENDS_CXX=`echo "$DEPENDS_CXX" | sed 's,\([[^ ]]*\)/\([[^ ]]*\)\.cpp,\\
   624 $(objects)/\2.lo: \1/\2.cpp\\
   625 	\$(LIBTOOL) --mode=compile \$(CXX) \$(CFLAGS) \$(EXTRA_CFLAGS) '"$DEPENDENCY_TRACKING_OPTIONS"' -c \$< -o \$@,g'`
   626 OBJECTS="$OBJECTS $OBJECTS_CXX"
   627 DEPENDS="$DEPENDS $DEPENDS_CXX"
   628 DEPENDS=`echo "$DEPENDS" | sed 's,\\$,\\\\$,g'`
   629 
   630 VERSION_OBJECTS=`echo $VERSION_SOURCES`
   631 VERSION_DEPENDS=`echo $VERSION_SOURCES`
   632 VERSION_OBJECTS=`echo "$VERSION_OBJECTS" | sed 's,[[^ ]]*/\([[^ ]]*\)\.rc,$(objects)/\1.o,g'`
   633 VERSION_DEPENDS=`echo "$VERSION_DEPENDS" | sed 's,\([[^ ]]*\)/\([[^ ]]*\)\.rc,\\
   634 $(objects)/\2.o: \1/\2.rc\\
   635 	\$(WINDRES) \$< \$@,g'`
   636 VERSION_DEPENDS=`echo "$VERSION_DEPENDS" | sed 's,\\$,\\\\$,g'`
   637 
   638 PLAYWAVE_SOURCES="$srcdir/playwave.c"
   639 PLAYWAVE_OBJECTS=`echo $PLAYWAVE_SOURCES`
   640 PLAYWAVE_DEPENDS=`echo $PLAYWAVE_SOURCES`
   641 PLAYWAVE_OBJECTS=`echo "$PLAYWAVE_OBJECTS" | sed 's,[[^ ]]*/\([[^ ]]*\)\.c,$(objects)/\1.lo,g'`
   642 PLAYWAVE_DEPENDS=`echo "$PLAYWAVE_DEPENDS" | sed 's,\([[^ ]]*\)/\([[^ ]]*\)\.c,\\
   643 $(objects)/\2.lo: \1/\2.c\\
   644 	\$(LIBTOOL) --mode=compile \$(CC) \$(CFLAGS) \$(EXTRA_CFLAGS) '"$DEPENDENCY_TRACKING_OPTIONS"' -c \$< -o \$@,g'`
   645 PLAYWAVE_DEPENDS=`echo "$PLAYWAVE_DEPENDS" | sed 's,\\$,\\\\$,g'`
   646 
   647 PLAYMUS_SOURCES="$srcdir/playmus.c"
   648 PLAYMUS_OBJECTS=`echo $PLAYMUS_SOURCES`
   649 PLAYMUS_DEPENDS=`echo $PLAYMUS_SOURCES`
   650 PLAYMUS_OBJECTS=`echo "$PLAYMUS_OBJECTS" | sed 's,[[^ ]]*/\([[^ ]]*\)\.c,$(objects)/\1.lo,g'`
   651 PLAYMUS_DEPENDS=`echo "$PLAYMUS_DEPENDS" | sed 's,\([[^ ]]*\)/\([[^ ]]*\)\.c,\\
   652 $(objects)/\2.lo: \1/\2.c\\
   653 	\$(LIBTOOL) --mode=compile \$(CC) \$(CFLAGS) \$(EXTRA_CFLAGS) '"$DEPENDENCY_TRACKING_OPTIONS"' -c \$< -o \$@,g'`
   654 PLAYMUS_DEPENDS=`echo "$PLAYMUS_DEPENDS" | sed 's,\\$,\\\\$,g'`
   655 
   656 dnl Expand the sources and objects needed to build the library
   657 AC_SUBST(ac_aux_dir)
   658 AC_SUBST(OBJECTS)
   659 AC_SUBST(VERSION_OBJECTS)
   660 AC_SUBST(PLAYWAVE_OBJECTS)
   661 AC_SUBST(PLAYMUS_OBJECTS)
   662 AC_SUBST(BUILD_CFLAGS)
   663 AC_SUBST(EXTRA_CFLAGS)
   664 AC_SUBST(BUILD_LDFLAGS)
   665 AC_SUBST(EXTRA_LDFLAGS)
   666 AC_SUBST(EXE)
   667 AC_SUBST(WINDRES)
   668 AC_SUBST(SDL_VERSION)
   669 AC_SUBST(SDL_CFLAGS)
   670 AC_SUBST(SDL_LIBS)
   671 
   672 AC_OUTPUT([
   673 ])
   674 AC_CONFIG_FILES([
   675     Makefile SDL_mixer.spec SDL_mixer.qpg SDL_mixer.pc
   676 ])
   677 AC_CONFIG_COMMANDS([default],
   678                    [cat >>Makefile <<__EOF__
   679 
   680 # Build rules for objects
   681 -include \$(OBJECTS:.lo=.d)
   682 $DEPENDS
   683 $VERSION_DEPENDS
   684 
   685 -include \$(PLAYWAVE_OBJECTS:.lo=.d)
   686 $PLAYWAVE_DEPENDS
   687 
   688 -include \$(PLAYMUS_OBJECTS:.lo=.d)
   689 $PLAYMUS_DEPENDS
   690 __EOF__ 
   691 ], [
   692 DEPENDS="$DEPENDS"
   693 VERSION_DEPENDS="$VERSION_DEPENDS"
   694 PLAYWAVE_DEPENDS="$PLAYWAVE_DEPENDS"
   695 PLAYMUS_DEPENDS="$PLAYMUS_DEPENDS"
   696 ])
   697 AC_OUTPUT