configure.in
author Sam Lantinga <slouken@libsdl.org>
Sun, 27 Sep 2009 19:34:09 +0000
changeset 402 2bfcf7edcb6f
parent 396 de5061390913
child 405 bfb16c4e42e0
permissions -rw-r--r--
Fixed bug #812

Max Horn 2009-09-27 11:58:18 PDT

I got build failure reports from various people for SDL-mixer on OS X when
compiling in 64bit mode, both in 10.5 and 10.6. The reason: Deprecated
QuickTime APIs that have been removed for 64bit binaries, see below.

Proposed short-term workaround: Disable or just remove the crappy "native" MIDI
code. It's rather bad anyway (I should know, i wrote it ;).

Mid/long-term solution: Write new CoreAudio based code to replace it. That code
then would work on all OS X versions (well, at least on 10.4 upwards for sure),
be more accurate, sound better and take up less system resources. And be
simpler, did I mention that? Generating MIDI output with CoreAudio is pretty
easy, we do it in ScummVM, Exult, Pentagram, DOSBox, ...
     1 dnl Process this file with autoconf to produce a configure script.
     2 AC_INIT(README)
     3 
     4 dnl Set various version strings - taken gratefully from the GTk sources
     5 
     6 # Making releases:
     7 #   MICRO_VERSION += 1;
     8 #   INTERFACE_AGE += 1;
     9 #   BINARY_AGE += 1;
    10 # if any functions have been added, set INTERFACE_AGE to 0.
    11 # if backwards compatibility has been broken,
    12 # set BINARY_AGE and INTERFACE_AGE to 0.
    13 #
    14 MAJOR_VERSION=1
    15 MINOR_VERSION=2
    16 MICRO_VERSION=8
    17 INTERFACE_AGE=6
    18 BINARY_AGE=8
    19 VERSION=$MAJOR_VERSION.$MINOR_VERSION.$MICRO_VERSION
    20 
    21 AC_SUBST(MAJOR_VERSION)
    22 AC_SUBST(MINOR_VERSION)
    23 AC_SUBST(MICRO_VERSION)
    24 AC_SUBST(INTERFACE_AGE)
    25 AC_SUBST(BINARY_AGE)
    26 AC_SUBST(VERSION)
    27 
    28 # libtool versioning
    29 LT_RELEASE=$MAJOR_VERSION.$MINOR_VERSION
    30 LT_CURRENT=`expr $MICRO_VERSION - $INTERFACE_AGE`
    31 LT_REVISION=$INTERFACE_AGE
    32 LT_AGE=`expr $BINARY_AGE - $INTERFACE_AGE`
    33 
    34 AC_SUBST(LT_RELEASE)
    35 AC_SUBST(LT_CURRENT)
    36 AC_SUBST(LT_REVISION)
    37 AC_SUBST(LT_AGE)
    38 
    39 dnl Detect the canonical build and host environments
    40 AC_CONFIG_AUX_DIRS($srcdir/build-scripts)
    41 AC_CANONICAL_HOST
    42 
    43 dnl Set up the compiler and linker flags
    44 case "$host" in
    45     *-*-cygwin*)
    46         # We build SDL on cygwin without the UNIX emulation layer
    47         BASE_CFLAGS="-I/usr/include/mingw -mno-cygwin"
    48         BASE_LDFLAGS="-mno-cygwin"
    49         ;;
    50     *)
    51         BASE_CFLAGS="-D_GNU_SOURCE=1"
    52         BASE_LDFLAGS=""
    53         ;;
    54 esac
    55 BUILD_CFLAGS="$CFLAGS $CPPFLAGS"
    56 EXTRA_CFLAGS="$INCLUDE $BASE_CFLAGS"
    57 BUILD_LDFLAGS="$LDFLAGS"
    58 EXTRA_LDFLAGS="$BASE_LDFLAGS"
    59 ## These are common directories to find software packages
    60 #for path in /usr/freeware /usr/pkg /usr/local; do
    61 #    if test -d $path/include; then
    62 #        EXTRA_CFLAGS="$EXTRA_CFLAGS -I$path/include"
    63 #    fi
    64 #    if test -d $path/lib; then
    65 #        EXTRA_LDFLAGS="$EXTRA_LDFLAGS -L$path/lib"
    66 #    fi
    67 #done
    68 CPPFLAGS="$CPPFLAGS $EXTRA_CFLAGS"
    69 CFLAGS="$CFLAGS $EXTRA_CFLAGS"
    70 LDFLAGS="$LDFLAGS $EXTRA_LDFLAGS"
    71 
    72 dnl Check for tools
    73 AC_LIBTOOL_WIN32_DLL
    74 AC_PROG_LIBTOOL
    75 AC_PROG_CC
    76 AC_PROG_INSTALL
    77 AC_PROG_MAKE_SET
    78 if test -z "$host_alias"; then
    79     hostaliaswindres=
    80 else
    81     hostaliaswindres="$host_alias-windres"
    82 fi
    83 AC_CHECK_PROGS(WINDRES, [windres $hostaliaswindres $host_os-windres])
    84 
    85 dnl Check for compiler characteristics
    86 AC_C_CONST
    87 
    88 case "$host" in
    89     *-*-cygwin* | *-*-mingw32*)
    90         SOURCES="$srcdir/version.rc"
    91         EXE=".exe"
    92         if test "$build" != "$host"; then # cross-compiling
    93             # Default cross-compile location
    94             ac_default_prefix=/usr/local/cross-tools/i386-mingw32
    95         else
    96             # Look for the location of the tools and install there
    97             if test "$BUILD_PREFIX" != ""; then
    98                 ac_default_prefix=$BUILD_PREFIX
    99             fi
   100         fi
   101         ;;
   102     *)
   103         SOURCES=""
   104         EXE=""
   105         ;;
   106 esac
   107 
   108 # Standard C sources
   109 SOURCES="$SOURCES \
   110 $srcdir/effect_position.c \
   111 $srcdir/effect_stereoreverse.c \
   112 $srcdir/effects_internal.c \
   113 $srcdir/load_aiff.c \
   114 $srcdir/load_voc.c \
   115 $srcdir/mixer.c \
   116 $srcdir/music.c"
   117 
   118 find_lib()
   119 {
   120     gcc_bin_path=[`$CC -print-search-dirs 2>/dev/null | fgrep programs: | sed 's/[^=]*=\(.*\)/\1/' | sed 's/:/ /g'`]
   121     gcc_lib_path=[`$CC -print-search-dirs 2>/dev/null | fgrep libraries: | sed 's/[^=]*=\(.*\)/\1/' | sed 's/:/ /g'`]
   122     env_lib_path=[`echo $LIBS $LDFLAGS | sed 's/-L[ ]*//g'`]
   123     for path in $gcc_bin_path $gcc_lib_path $env_lib_path /usr/lib /usr/local/lib; do
   124         lib=[`ls -- $path/$1 2>/dev/null | sort -r | sed 's/.*\/\(.*\)/\1/; q'`]
   125         if test x$lib != x; then
   126             echo $lib
   127             return
   128         fi
   129     done
   130 }
   131 
   132 dnl Check for SDL
   133 SDL_VERSION=1.2.10
   134 AM_PATH_SDL($SDL_VERSION,
   135             :,
   136             AC_MSG_ERROR([*** SDL version $SDL_VERSION not found!])
   137 )
   138 EXTRA_CFLAGS="$EXTRA_CFLAGS $SDL_CFLAGS"
   139 EXTRA_LDFLAGS="$EXTRA_LDFLAGS $SDL_LIBS"
   140 
   141 dnl Check command-line options
   142 
   143 AC_ARG_ENABLE([music-cmd],
   144 AC_HELP_STRING([--enable-music-cmd], [support an external music player [[default=yes]]]),
   145               [], [enable_music_cmd=yes])
   146 if test x$enable_music_cmd = xyes; then
   147     SOURCES="$SOURCES $srcdir/music_cmd.c"
   148     EXTRA_CFLAGS="$EXTRA_CFLAGS -DCMD_MUSIC"
   149 fi
   150 AC_ARG_ENABLE([music-wave],
   151 AC_HELP_STRING([--enable-music-wave], [enable streaming WAVE music [[default=yes]]]),
   152               [], [enable_music_wave=yes])
   153 if test x$enable_music_wave = xyes; then
   154     SOURCES="$SOURCES $srcdir/wavestream.c"
   155     EXTRA_CFLAGS="$EXTRA_CFLAGS -DWAV_MUSIC"
   156 fi
   157 no_libmikmod=yes
   158 libmikmod_maj=3
   159 libmikmod_min=1
   160 libmikmod_rev=10
   161 libmikmod_ver="$libmikmod_maj.$libmikmod_min.$libmikmod_rev"
   162 AC_ARG_ENABLE([music-libmikmod],
   163 AC_HELP_STRING([--enable-music-libmikmod], [enable MOD music via external libmikmod [[default=no]]]),
   164               [], [enable_music_libmikmod=no])
   165 if test x$enable_music_libmikmod = xyes; then
   166     AC_PATH_PROG(LIBMIKMOD_CONFIG, libmikmod-config, no, [$PATH])
   167     if test "$LIBMIKMOD_CONFIG" != "no" ; then
   168         no_libmikmod=no
   169         CFLAGS_SAVED="$CFLAGS"
   170         LIBS_SAVED="$LIBS"
   171         CFLAGS="$CFLAGS -DLIBMIKMOD_MUSIC `$LIBMIKMOD_CONFIG --cflags`"
   172         LIBS="$LIBS `$LIBMIKMOD_CONFIG --libs`"
   173         AC_MSG_CHECKING([for libmikmod - version >= $libmikmod_ver])
   174         AC_TRY_RUN([
   175 #include "mikmod.h"
   176 #include "stdio.h"
   177 
   178 int main(int argc, char **argv)
   179 {
   180     long maj=$libmikmod_maj,min=$libmikmod_min,rev=$libmikmod_rev,ver=MikMod_GetVersion();
   181     /*printf("(%d.%d.%d) ",ver>>16,(ver>>8)&0xff,ver&0xff);*/
   182     if(ver>=((maj<<16)|(min<<8)|(rev))) {
   183         printf("yes\n");
   184         return 0;
   185     }
   186     printf("no\n*** libmikmod is older than %d.%d.%d, not using.\n",maj,min,rev);
   187     return 1;
   188 }
   189 ], EXTRA_CFLAGS="$EXTRA_CFLAGS -DLIBMIKMOD_MUSIC `$LIBMIKMOD_CONFIG --cflags`";EXTRA_LDFLAGS="$EXTRA_LDFLAGS `$LIBMIKMOD_CONFIG --libs`", CFLAGS="$CFLAGS_SAVED";LIBS="$LIBS_SAVED",
   190 [echo $ac_n "cross compiling; assumed OK... $ac_c"])
   191     fi
   192 fi
   193 
   194 AC_ARG_ENABLE([music-mod],
   195 AC_HELP_STRING([--enable-music-mod], [enable MOD music via mikmod [[default=yes]]]),
   196               [], [enable_music_mod=$no_libmikmod])
   197 if test x$enable_music_mod = xyes -a x$enable_music_libmikmod = xno; then
   198     EXTRA_CFLAGS="$EXTRA_CFLAGS -DMOD_MUSIC -I\$(srcdir)/mikmod"
   199     SOURCES="$SOURCES $srcdir/mikmod/*.c"
   200 fi
   201 AC_ARG_ENABLE([music-midi],
   202 AC_HELP_STRING([--enable-music-midi], [enable MIDI music via timidity [[default=yes]]]),
   203               [], [enable_music_midi=yes])
   204 if test x$enable_music_midi = xyes; then
   205     EXTRA_CFLAGS="$EXTRA_CFLAGS -DMID_MUSIC"
   206     AC_ARG_ENABLE([music-timidity-midi],
   207 AC_HELP_STRING([--enable-music-timidity-midi], [enable timidity MIDI output [[default=yes]]]),
   208                   [], [enable_music_timidity_midi=yes])
   209     if test x$enable_music_timidity_midi = xyes; then
   210         EXTRA_CFLAGS="$EXTRA_CFLAGS -DUSE_TIMIDITY_MIDI -I\$(srcdir)/timidity"
   211         SOURCES="$SOURCES $srcdir/timidity/*.c"
   212     fi
   213     AC_ARG_ENABLE([music-native-midi],
   214 AC_HELP_STRING([--enable-music-native-midi], [enable native MIDI music output [[default=yes]]]),
   215                   [], [enable_music_native_midi=yes])
   216     if test x$enable_music_native_midi = xyes; then
   217         use_music_native_midi=no
   218         case "$host" in
   219             *-*-cygwin* | *-*-mingw32*)
   220                 use_music_native_midi=yes
   221                 EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lwinmm"
   222                 ;;
   223             *-*-darwin*)
   224                 # This doesn't work on Mac OS X 10.5+
   225                 # Max Horn (the original author) recommends disabling it for now.
   226                 #use_music_native_midi=yes
   227                 #EXTRA_LDFLAGS="$EXTRA_LDFLAGS -Wl,-framework,QuickTime -Wl,-framework,CoreServices"
   228                 ;;
   229         esac
   230         if test x$use_music_native_midi = xyes; then
   231             EXTRA_CFLAGS="$EXTRA_CFLAGS -DUSE_NATIVE_MIDI -I\$(srcdir)/native_midi"
   232             SOURCES="$SOURCES $srcdir/native_midi/*.c"
   233         fi
   234     fi
   235     AC_ARG_ENABLE([music-native-midi-gpl],
   236 AC_HELP_STRING([--enable-music-native-midi-gpl], [enable native MIDI on UNIX using GPL code [[default=no]]]),
   237                   [], [enable_music_native_midi_gpl=no])
   238     if test x$enable_music_native_midi_gpl = xyes; then
   239         use_music_native_midi_gpl=no
   240         case "$host" in
   241             *-*-linux* | *-*-freebsd*)
   242                 use_music_native_midi_gpl=yes
   243                 ;;
   244         esac
   245         if test x$use_music_native_midi_gpl = xyes; then
   246             EXTRA_CFLAGS="$EXTRA_CFLAGS -DUSE_NATIVE_MIDI -I\$(srcdir)/native_midi"
   247             SOURCES="$SOURCES $srcdir/native_midi_gpl/*.c"
   248         fi
   249     fi
   250 fi
   251 AC_ARG_ENABLE([music-ogg],
   252 AC_HELP_STRING([--enable-music-ogg], [enable Ogg Vorbis music [[default=yes]]]),
   253               [], [enable_music_ogg=yes])
   254 AC_ARG_ENABLE(music-ogg-tremor,
   255 [  --enable-music-ogg-tremor   enable OGG music via libtremor [[default=no]]],
   256               [], enable_music_ogg_tremor=no)
   257 AC_ARG_ENABLE([music-ogg-shared],
   258 AC_HELP_STRING([--enable-music-ogg-shared], [dynamically load Ogg Vorbis support [[default=yes]]]),
   259               [], [enable_music_ogg_shared=yes])
   260 if test x$enable_music_ogg = xyes; then
   261     if test x$enable_music_ogg_tremor = xyes; then
   262         AC_CHECK_HEADER([tremor/ivorbisfile.h], [have_tremor_hdr=yes])
   263         AC_CHECK_LIB([vorbisidec], [ov_open_callbacks], [have_tremor_lib=yes])
   264         if test x$have_tremor_hdr = xyes -a x$have_tremor_lib = xyes; then
   265             case "$host" in
   266                 *-*-darwin*)
   267                     ogg_lib=[`find_lib libvorbisidec*.dylib`]
   268                     if test x$ogg_lib = x; then
   269                         ogg_lib=[`find_lib libvorbisidec.[0-9]`]
   270                     fi
   271                     if test x$ogg_lib = x; then
   272                         ogg_lib=[`find_lib libvorbisidec.[0-9]*`]
   273                     fi
   274                     ;;
   275                 *-*-cygwin* | *-*-mingw32*)
   276                     ogg_lib=[`find_lib "vorbisidec*.dll"`]
   277                     ;;
   278                 *)
   279                     ogg_lib=[`find_lib "libvorbisidec.so.[0-9]"`]
   280                     if test x$ogg_lib = x; then
   281                         ogg_lib=[`find_lib "libvorbisidec.so.[0-9]*"`]
   282                     fi
   283                     ;;
   284             esac
   285             SOURCES="$SOURCES $srcdir/*_ogg.c"
   286             EXTRA_CFLAGS="$EXTRA_CFLAGS -DOGG_MUSIC -DOGG_USE_TREMOR"
   287             if test x$enable_music_ogg_shared = xyes && test x$ogg_lib != x; then
   288                 echo "-- dynamic libvorbisidec -> $ogg_lib"
   289                 EXTRA_CFLAGS="$EXTRA_CFLAGS -DOGG_DYNAMIC=\\\"$ogg_lib\\\""
   290             else
   291                 EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lvorbisidec"
   292             fi
   293         fi
   294     else
   295         AC_CHECK_HEADER([vorbis/vorbisfile.h], [have_ogg_hdr=yes])
   296         AC_CHECK_LIB([vorbisfile], [ov_open_callbacks], [have_ogg_lib=yes])
   297         if test x$have_ogg_hdr = xyes -a x$have_ogg_lib = xyes; then
   298             case "$host" in
   299                 *-*-darwin*)
   300                     ogg_lib=[`find_lib libvorbisfile*.dylib`]
   301                     ;;
   302                 *-*-cygwin* | *-*-mingw32*)
   303                     ogg_lib=[`find_lib "libvorbisfile*.dll"`]
   304                     ;;
   305                 *)
   306                     ogg_lib=[`find_lib "libvorbisfile.so.[0-9]"`]
   307                     if test x$ogg_lib = x; then
   308                         ogg_lib=[`find_lib "libvorbisfile.so.[0-9]*"`]
   309                     fi
   310                     ;;
   311             esac
   312             SOURCES="$SOURCES $srcdir/*_ogg.c"
   313             EXTRA_CFLAGS="$EXTRA_CFLAGS -DOGG_MUSIC"
   314             if test x$enable_music_ogg_shared = xyes && test x$ogg_lib != x; then
   315                 echo "-- dynamic libvorbisfile -> $ogg_lib"
   316                 EXTRA_CFLAGS="$EXTRA_CFLAGS -DOGG_DYNAMIC=\\\"$ogg_lib\\\""
   317             else
   318                 EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lvorbisfile -lvorbis -logg"
   319             fi
   320         fi
   321     fi
   322 fi
   323 libflac_ver=8
   324 AC_ARG_ENABLE([music-flac],
   325 AC_HELP_STRING([--enable-music-flac], [enable FLAC music [[default=yes]]]),
   326               [], [enable_music_flac=yes])
   327 AC_ARG_ENABLE([music-flac-shared],
   328 AC_HELP_STRING([--enable-music-flac-shared],
   329               [dynamically load FLAC support [[default=yes]]]),
   330               [], [enable_music_flac_shared=yes])
   331 if test x$enable_music_flac = xyes; then
   332 	AC_CHECK_HEADER([FLAC/export.h], [have_flac_export=yes])
   333 	if test x$have_flac_export = xyes; then
   334 		LIBS_SAVED="$LIBS"
   335 		LIBS="-lFLAC"
   336 	    AC_MSG_CHECKING([for libflac so-name version >= $libflac_ver])
   337 	    AC_TRY_RUN([
   338 #include "FLAC/export.h"
   339 #include "stdio.h"
   340 int main( int argc, char *argv[] ) {
   341 #if defined(FLAC_API_VERSION_CURRENT) && (FLAC_API_VERSION_CURRENT >= $libflac_ver)
   342 	return 0;
   343 #else
   344 	return 1;
   345 #endif
   346 }
   347 ], have_flac_ver=yes, have_flac_ver=no)
   348 		LIBS="$LIBS_SAVED"
   349 		AC_MSG_RESULT($have_flac_ver)
   350 		if test x$have_flac_ver = xno; then
   351 			echo "*** FLAC support has been disabled."
   352 		else
   353 			AC_CHECK_HEADER([FLAC/stream_decoder.h], [have_flac_hdr=yes])
   354 			AC_CHECK_LIB([FLAC], [FLAC__stream_decoder_new], [have_flac_lib=yes])
   355 			if test x$have_flac_hdr = xyes -a x$have_flac_lib = xyes; then	
   356 			    case "$host" in
   357 			        *-*-darwin*)
   358 			            flac_lib=[`find_lib FLAC*.dylib`]
   359 			            ;;
   360 			        *-*-cygwin* | *-*-mingw32*)
   361 			            flac_lib=[`find_lib "libFLAC*.dll"`]
   362 			            ;;
   363 			        *)
   364 			            flac_lib=[`find_lib "libFLAC.so.[0-9]"`]
   365 			            if test x$flac_lib = x; then
   366 			                flac_lib=[`find_lib "libFLAC.so.[0-9]*"`]
   367 			            fi
   368 			            ;;
   369 			    esac
   370 			    SOURCES="$SOURCES $srcdir/*_flac.c"
   371 			    EXTRA_CFLAGS="$EXTRA_CFLAGS -DFLAC_MUSIC"
   372 			    if test x$enable_music_flac_shared = xyes && test x$flac_lib != x; then
   373 			        echo "-- dynamic libFLAC -> $flac_lib"
   374 			        EXTRA_CFLAGS="$EXTRA_CFLAGS -DFLAC_DYNAMIC=\\\"$flac_lib\\\""
   375 			    else
   376 			        EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lFLAC"
   377 			    fi
   378 			fi
   379 		fi
   380 	fi
   381 fi
   382 AC_ARG_ENABLE(music-mp3,
   383 [  --enable-music-mp3      enable MP3 music via smpeg [[default=yes]]],
   384               , enable_music_mp3=yes)
   385 if test x$enable_music_mp3 = xyes; then
   386     SMPEG_VERSION=0.4.3
   387     AM_PATH_SMPEG($SMPEG_VERSION, have_smpeg=yes, have_smpeg=no)
   388     if test x$have_smpeg = xyes; then
   389         AC_ARG_ENABLE([music-mp3-shared],
   390 AC_HELP_STRING([--enable-music-mp3-shared], [dynamically load MP3 support [[default=yes]]]),
   391                       [], [enable_music_mp3_shared=yes])
   392         case "$host" in
   393             *-*-darwin*)
   394                 smpeg_lib=[`find_lib libsmpeg*.dylib`]
   395                 ;;
   396             *-*-cygwin* | *-*-mingw32*)
   397                 smpeg_lib=[`find_lib "smpeg*.dll"`]
   398                 ;;
   399             *)
   400                 smpeg_lib=[`find_lib "libsmpeg*.so.[0-9]"`]
   401                 if test x$smpeg_lib = x; then
   402                     smpeg_lib=[`find_lib "libsmpeg*.so.[0-9]*"`]
   403                 fi
   404                 ;;
   405         esac
   406         SOURCES="$SOURCES $srcdir/*_mp3.c"
   407         EXTRA_CFLAGS="$EXTRA_CFLAGS -DMP3_MUSIC $SMPEG_CFLAGS"
   408         if test x$enable_music_mp3_shared = xyes && test x$smpeg_lib != x; then
   409             echo "-- dynamic libsmpeg -> $smpeg_lib"
   410             EXTRA_CFLAGS="$EXTRA_CFLAGS -DMP3_DYNAMIC=\\\"$smpeg_lib\\\""
   411         else
   412             EXTRA_LDFLAGS="$EXTRA_LDFLAGS $SMPEG_LIBS"
   413         fi
   414     fi
   415 fi
   416 AC_ARG_ENABLE(music-mp3-mad-gpl,
   417 AC_HELP_STRING([--enable-music-mp3-mad-gpl], [enable MP3 music via libmad GPL code [[default=no]]]),
   418                   [], [enable_music_mp3_mad_gpl=no])
   419 if test x$enable_music_mp3_mad_gpl = xyes; then
   420     AC_MSG_CHECKING(for libmad headers)
   421     have_libmad=no
   422     AC_TRY_COMPILE([
   423      #include "mad.h"
   424     ],[
   425     ],[
   426     have_libmad=yes
   427     ])
   428     AC_MSG_RESULT($have_libmad)
   429     if test x$have_libmad = xyes; then
   430         SOURCES="$SOURCES $srcdir/music_mad.c"
   431         EXTRA_CFLAGS="$EXTRA_CFLAGS -DMP3_MAD_MUSIC"
   432         EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lmad"
   433     fi
   434 fi
   435 
   436 OBJECTS=`echo $SOURCES | sed 's,[[^ ]]*/\([[^ ]]*\)\.c,$(objects)/\1.lo,g'`
   437 OBJECTS=`echo $OBJECTS | sed 's,[[^ ]]*/\([[^ ]]*\)\.rc,$(objects)/\1.o,g'`
   438 
   439 dnl Expand the sources and objects needed to build the library
   440 AC_SUBST(ac_aux_dir)
   441 AC_SUBST(SOURCES)
   442 AC_SUBST(OBJECTS)
   443 AC_SUBST(BUILD_CFLAGS)
   444 AC_SUBST(EXTRA_CFLAGS)
   445 AC_SUBST(BUILD_LDFLAGS)
   446 AC_SUBST(EXTRA_LDFLAGS)
   447 AC_SUBST(EXE)
   448 AC_SUBST(WINDRES)
   449 AC_SUBST(SDL_VERSION)
   450 AC_SUBST(SDL_CFLAGS)
   451 AC_SUBST(SDL_LIBS)
   452 
   453 AC_OUTPUT([
   454     Makefile SDL_mixer.spec SDL_mixer.qpg SDL_mixer.pc
   455 ], [
   456     : >build-deps
   457     if test x"$MAKE" = x; then MAKE=make; fi; $MAKE depend
   458 ])