configure.in
author Sam Lantinga <slouken@libsdl.org>
Thu, 15 Apr 2010 07:19:18 -0700
changeset 489 08eaf23a2284
parent 488 94b190330355
child 494 4f4caf04bcd1
permissions -rw-r--r--
SDL_mixer configure bug patch (double music_modplug.o linking)

Jon Atkins to Sam

Sam,

was playing with the new hg repo of SDL_mixer and had trouble with the mad music configure option adding the modplug source when it shouldn't!
here's the hg diff for the fix.

-- Jon
     1 dnl Process this file with autoconf to produce a configure script.
     2 AC_INIT(README)
     3 AC_CONFIG_AUX_DIRS($srcdir/build-scripts)
     4 
     5 dnl Set various version strings - taken gratefully from the GTk sources
     6 
     7 # Making releases:
     8 #   MICRO_VERSION += 1;
     9 #   INTERFACE_AGE += 1;
    10 #   BINARY_AGE += 1;
    11 # if any functions have been added, set INTERFACE_AGE to 0.
    12 # if backwards compatibility has been broken,
    13 # set BINARY_AGE and INTERFACE_AGE to 0.
    14 #
    15 MAJOR_VERSION=1
    16 MINOR_VERSION=2
    17 MICRO_VERSION=11
    18 INTERFACE_AGE=1
    19 BINARY_AGE=11
    20 VERSION=$MAJOR_VERSION.$MINOR_VERSION.$MICRO_VERSION
    21 
    22 AC_SUBST(MAJOR_VERSION)
    23 AC_SUBST(MINOR_VERSION)
    24 AC_SUBST(MICRO_VERSION)
    25 AC_SUBST(INTERFACE_AGE)
    26 AC_SUBST(BINARY_AGE)
    27 AC_SUBST(VERSION)
    28 
    29 # libtool versioning
    30 LT_INIT([win32-dll])
    31 
    32 LT_RELEASE=$MAJOR_VERSION.$MINOR_VERSION
    33 LT_CURRENT=`expr $MICRO_VERSION - $INTERFACE_AGE`
    34 LT_REVISION=$INTERFACE_AGE
    35 LT_AGE=`expr $BINARY_AGE - $INTERFACE_AGE`
    36 m4_pattern_allow([^LT_])
    37 
    38 AC_SUBST(LT_RELEASE)
    39 AC_SUBST(LT_CURRENT)
    40 AC_SUBST(LT_REVISION)
    41 AC_SUBST(LT_AGE)
    42 
    43 dnl Detect the canonical build and host environments
    44 AC_CONFIG_AUX_DIRS($srcdir/build-scripts)
    45 dnl AC_CANONICAL_HOST
    46 
    47 dnl Check for tools
    48 AC_PROG_LIBTOOL
    49 AC_PROG_CC
    50 AC_PROG_INSTALL
    51 AC_PROG_MAKE_SET
    52 if test -z "$host_alias"; then
    53     hostaliaswindres=
    54 else
    55     hostaliaswindres="$host_alias-windres"
    56 fi
    57 AC_CHECK_PROGS(WINDRES, [windres $hostaliaswindres $host_os-windres])
    58 
    59 dnl Set up the compiler and linker flags
    60 case "$host" in
    61     *-*-cygwin*)
    62         # We build SDL on cygwin without the UNIX emulation layer
    63         BASE_CFLAGS="-I/usr/include/mingw -mno-cygwin"
    64         BASE_LDFLAGS="-mno-cygwin"
    65         ;;
    66     *)
    67         BASE_CFLAGS="-D_GNU_SOURCE=1"
    68         BASE_LDFLAGS=""
    69         ;;
    70 esac
    71 BUILD_CFLAGS="$CFLAGS $CPPFLAGS"
    72 EXTRA_CFLAGS="$INCLUDE $BASE_CFLAGS"
    73 BUILD_LDFLAGS="$LDFLAGS"
    74 EXTRA_LDFLAGS="$BASE_LDFLAGS"
    75 ## These are common directories to find software packages
    76 #for path in /usr/freeware /usr/pkg /usr/local; do
    77 #    if test -d $path/include; then
    78 #        EXTRA_CFLAGS="$EXTRA_CFLAGS -I$path/include"
    79 #    fi
    80 #    if test -d $path/lib; then
    81 #        EXTRA_LDFLAGS="$EXTRA_LDFLAGS -L$path/lib"
    82 #    fi
    83 #done
    84 CPPFLAGS="$CPPFLAGS $EXTRA_CFLAGS"
    85 CFLAGS="$CFLAGS $EXTRA_CFLAGS"
    86 LDFLAGS="$LDFLAGS $EXTRA_LDFLAGS"
    87 
    88 dnl Check for compiler characteristics
    89 AC_C_CONST
    90 
    91 dnl See whether we can use gcc style dependency tracking
    92 AC_ARG_ENABLE(dependency-tracking,
    93 AC_HELP_STRING([--enable-dependency-tracking],
    94                [Use gcc -MMD -MT dependency tracking [[default=yes]]]),
    95               , enable_dependency_tracking=yes)
    96 if test x$enable_dependency_tracking = xyes; then
    97     have_gcc_mmd_mt=no
    98     AC_MSG_CHECKING(for GCC -MMD -MT option)
    99     AC_TRY_COMPILE([
   100     #if !defined(__GNUC__) || __GNUC__ < 3
   101     #error Dependency tracking requires GCC 3.0 or newer
   102     #endif
   103     ],[
   104     ],[
   105     have_gcc_mmd_mt=yes
   106     ])
   107     AC_MSG_RESULT($have_gcc_mmd_mt)
   108 
   109     if test x$have_gcc_mmd_mt = xyes; then
   110         DEPENDENCY_TRACKING_OPTIONS="-MMD -MT \$@"
   111     fi
   112 fi
   113     
   114 case "$host" in
   115     *mingw32ce*)
   116         #VERSION_SOURCES="$srcdir/version.rc"
   117         EXE=".exe"
   118 	;;
   119     *-*-cygwin* | *-*-mingw32*)
   120         VERSION_SOURCES="$srcdir/version.rc"
   121         EXE=".exe"
   122         if test "$build" != "$host"; then # cross-compiling
   123             # Default cross-compile location
   124             ac_default_prefix=/usr/local/cross-tools/i386-mingw32
   125         else
   126             # Look for the location of the tools and install there
   127             if test "$BUILD_PREFIX" != ""; then
   128                 ac_default_prefix=$BUILD_PREFIX
   129             fi
   130         fi
   131         ;;
   132     *)
   133         SOURCES=""
   134         EXE=""
   135         ;;
   136 esac
   137 
   138 # Standard C sources
   139 SOURCES="$SOURCES \
   140 $srcdir/effect_position.c \
   141 $srcdir/effect_stereoreverse.c \
   142 $srcdir/effects_internal.c \
   143 $srcdir/load_aiff.c \
   144 $srcdir/load_voc.c \
   145 $srcdir/mixer.c \
   146 $srcdir/music.c"
   147 
   148 dnl set this to use on systems that use lib64 instead of lib
   149 base_libdir=`echo \${libdir} | sed 's/.*\/\(.*\)/\1/; q'`
   150 
   151 dnl See if GCC's -fvisibility=hidden is supported (gcc4 and later, usually).
   152 dnl  Details of this flag are here: http://gcc.gnu.org/wiki/Visibility
   153 CheckVisibilityHidden()
   154 {
   155     AC_MSG_CHECKING(for GCC -fvisibility=hidden option)
   156     have_gcc_fvisibility=no
   157 
   158     visibility_CFLAGS="-fvisibility=hidden"
   159     save_CFLAGS="$CFLAGS"
   160     CFLAGS="$save_CFLAGS $visibility_CFLAGS -Werror"
   161     AC_TRY_COMPILE([
   162     #if !defined(__GNUC__) || __GNUC__ < 4
   163     #error SDL only uses visibility attributes in GCC 4 or newer
   164     #endif
   165     ],[
   166     ],[
   167     have_gcc_fvisibility=yes
   168     ])
   169     AC_MSG_RESULT($have_gcc_fvisibility)
   170     CFLAGS="$save_CFLAGS"
   171 
   172     if test x$have_gcc_fvisibility = xyes; then
   173         EXTRA_CFLAGS="$EXTRA_CFLAGS $visibility_CFLAGS"
   174     fi
   175 }
   176 
   177 
   178 dnl Function to find a library in the compiler search path
   179 find_lib()
   180 {
   181     gcc_bin_path=[`$CC -print-search-dirs 2>/dev/null | fgrep programs: | sed 's/[^=]*=\(.*\)/\1/' | sed 's/:/ /g'`]
   182     gcc_lib_path=[`$CC -print-search-dirs 2>/dev/null | fgrep libraries: | sed 's/[^=]*=\(.*\)/\1/' | sed 's/:/ /g'`]
   183     env_lib_path=[`echo $LIBS $LDFLAGS $* | sed 's/-L[ ]*//g'`]
   184     if test "$cross_compiling" = yes; then
   185         host_lib_path=""
   186     else
   187         host_lib_path="/usr/$base_libdir /usr/local/$base_libdir"
   188     fi
   189     for path in $gcc_bin_path $gcc_lib_path $env_lib_path $host_lib_path; do
   190         lib=[`ls -- $path/$1 2>/dev/null | sort | sed 's/.*\/\(.*\)/\1/; q'`]
   191         if test x$lib != x; then
   192             echo $lib
   193             return
   194         fi
   195     done
   196 }
   197 
   198 dnl Check for SDL
   199 SDL_VERSION=1.2.10
   200 AM_PATH_SDL($SDL_VERSION,
   201             :,
   202             AC_MSG_ERROR([*** SDL version $SDL_VERSION not found!])
   203 )
   204 EXTRA_CFLAGS="$EXTRA_CFLAGS $SDL_CFLAGS"
   205 EXTRA_LDFLAGS="$EXTRA_LDFLAGS $SDL_LIBS"
   206 
   207 dnl Check for math library
   208 AC_CHECK_LIB(m, pow, [LIBM="-lm"])
   209 
   210 dnl Check command-line options
   211 
   212 CheckVisibilityHidden
   213 
   214 AC_ARG_ENABLE([music-cmd],
   215 AC_HELP_STRING([--enable-music-cmd], [support an external music player [[default=yes]]]),
   216               [], [enable_music_cmd=detect])
   217 if test "x$enable_music_cmd" != xno; then
   218     AC_CHECK_FUNCS([fork vfork])
   219     if test "x$ac_cv_func_fork" = "xyes"; then
   220         EXTRA_CFLAGS="$EXTRA_CFLAGS -DHAVE_FORK"
   221     elif test "x$ac_cv_func_vfork" = "xyes"; then
   222         EXTRA_CFLAGS="$EXTRA_CFLAGS -DHAVE_VFORK"
   223     elif test "x$enable_music_cmd" = "xyes"; then
   224         AC_MSG_ERROR([external music player not available on your platform])
   225     else
   226         enable_music_cmd=no
   227     fi
   228     if test "x$enable_music_cmd" != xno; then
   229         SOURCES="$SOURCES $srcdir/music_cmd.c"
   230         EXTRA_CFLAGS="$EXTRA_CFLAGS -DCMD_MUSIC"
   231     fi
   232 fi
   233 
   234 AC_ARG_ENABLE([music-wave],
   235 AC_HELP_STRING([--enable-music-wave], [enable streaming WAVE music [[default=yes]]]),
   236               [], [enable_music_wave=yes])
   237 if test x$enable_music_wave = xyes; then
   238     SOURCES="$SOURCES $srcdir/wavestream.c"
   239     EXTRA_CFLAGS="$EXTRA_CFLAGS -DWAV_MUSIC"
   240 fi
   241 
   242 AC_ARG_ENABLE([music-mod],
   243 AC_HELP_STRING([--enable-music-mod], [enable MOD music via mikmod [[default=yes]]]),
   244               [], [enable_music_mod=yes])
   245 AC_ARG_ENABLE([music-mod-shared],
   246 AC_HELP_STRING([--enable-music-mod-shared], [dynamically load MOD support [[default=yes]]]),
   247               [], [enable_music_mod_shared=yes])
   248 if test x$enable_music_mod = xyes; then
   249     have_libmikmod=no
   250     libmikmod_maj=3
   251     libmikmod_min=1
   252     libmikmod_rev=10
   253     libmikmod_ver="$libmikmod_maj.$libmikmod_min.$libmikmod_rev"
   254     AC_PATH_PROG(LIBMIKMOD_CONFIG, libmikmod-config, no, [$PATH])
   255     if test "$LIBMIKMOD_CONFIG" != "no" ; then
   256         
   257         CFLAGS_SAVED="$CFLAGS"
   258         LIBS_SAVED="$LIBS"
   259         CFLAGS="$CFLAGS -DLIBMIKMOD_MUSIC `$LIBMIKMOD_CONFIG --cflags`"
   260         LIBS="$LIBS `$LIBMIKMOD_CONFIG --libs`"
   261         have_libmikmod=yes
   262         AC_MSG_CHECKING([for libmikmod - version >= $libmikmod_ver])
   263         AC_TRY_RUN([
   264 #include "mikmod.h"
   265 #include "stdio.h"
   266 
   267 int main(int argc, char **argv)
   268 {
   269 long maj=$libmikmod_maj,min=$libmikmod_min,rev=$libmikmod_rev,ver=MikMod_GetVersion();
   270 /*printf("(%d.%d.%d) ",ver>>16,(ver>>8)&0xff,ver&0xff);*/
   271 if(ver>=((maj<<16)|(min<<8)|(rev))) {
   272     printf("yes\n");
   273     return 0;
   274 }
   275 printf("no\n*** libmikmod is older than %d.%d.%d, not using.\n",maj,min,rev);
   276 return 1;
   277 }
   278 ], [], have_libmikmod=no; CFLAGS="$CFLAGS_SAVED"; LIBS="$LIBS_SAVED",
   279         [echo $ac_n "cross compiling; assumed OK... $ac_c"])
   280     fi
   281 
   282     if test x$have_libmikmod = xyes; then
   283         case "$host" in
   284             *-*-darwin*)
   285                 mikmod_lib=[`find_lib libmikmod.dylib`]
   286                 ;;
   287             *-*-cygwin* | *-*-mingw32*)
   288                 mikmod_lib=[`find_lib "mikmod*.dll"`]
   289                 ;;
   290             *)
   291                 mikmod_lib=[`find_lib "libmikmod*.so.[0-9]"`]
   292                 if test x$mikmod_lib = x; then
   293                     mikmod_lib=[`find_lib "libmikmod*.so.[0-9]*"`]
   294                 fi
   295                 ;;
   296         esac
   297         SOURCES="$SOURCES $srcdir/*_mod.c"
   298         EXTRA_CFLAGS="$EXTRA_CFLAGS -DMOD_MUSIC `$LIBMIKMOD_CONFIG --cflags`"
   299         if test x$enable_music_mod_shared = xyes && test x$mikmod_lib != x; then
   300             echo "-- dynamic libmikmod -> $mikmod_lib"
   301             EXTRA_CFLAGS="$EXTRA_CFLAGS -DMOD_DYNAMIC=\\\"$mikmod_lib\\\""
   302         else
   303             EXTRA_LDFLAGS="$EXTRA_LDFLAGS `$LIBMIKMOD_CONFIG --libs`"
   304         fi
   305     else
   306         AC_MSG_WARN([*** Unable to find MikMod library (http://mikmod.raphnet.net/)])
   307     fi
   308 fi
   309 
   310 AC_ARG_ENABLE([music-mod-modplug],
   311 AC_HELP_STRING([--enable-music-mod-modplug], [enable MOD music via modplug [[default=no]]]),
   312               [], [enable_music_mod_modplug=no])
   313 if test x$enable_music_mod_modplug = xyes; then
   314 	PKG_CHECK_MODULES([MODPLUG], [libmodplug >= 0.8.7])
   315 	EXTRA_CFLAGS="$EXTRA_CFLAGS -DMODPLUG_MUSIC  $MODPLUG_CFLAGS"
   316 	EXTRA_LDFLAGS="$EXTRA_LDFLAGS $MODPLUG_LIBS"
   317 dnl	AC_TRY_COMPILE([
   318 dnl     #include "modplug.h"
   319 dnl    ],[
   320 dnl    ],[
   321     have_libmodplug=yes
   322     SOURCES="$SOURCES $srcdir/music_modplug.c"
   323 dnl    ])
   324 else
   325 	have_libmodplug=no
   326 fi
   327 
   328 if test x$have_libmikmod != xyes -a x$have_libmodplug != xyes ; then
   329 	AC_MSG_WARN([MOD support disabled])
   330 fi
   331 
   332 AC_ARG_ENABLE([music-midi],
   333 AC_HELP_STRING([--enable-music-midi], [enable MIDI music via timidity [[default=yes]]]),
   334               [], [enable_music_midi=yes])
   335 if test x$enable_music_midi = xyes; then
   336     EXTRA_CFLAGS="$EXTRA_CFLAGS -DMID_MUSIC"
   337     AC_ARG_ENABLE([music-timidity-midi],
   338 AC_HELP_STRING([--enable-music-timidity-midi], [enable timidity MIDI output [[default=yes]]]),
   339                   [], [enable_music_timidity_midi=yes])
   340     if test x$enable_music_timidity_midi = xyes; then
   341         EXTRA_CFLAGS="$EXTRA_CFLAGS -DUSE_TIMIDITY_MIDI -I\$(srcdir)/timidity"
   342         SOURCES="$SOURCES $srcdir/timidity/*.c"
   343     fi
   344     AC_ARG_ENABLE([music-native-midi],
   345 AC_HELP_STRING([--enable-music-native-midi], [enable native MIDI music output [[default=yes]]]),
   346                   [], [enable_music_native_midi=yes])
   347     if test x$enable_music_native_midi = xyes; then
   348         use_music_native_midi=no
   349         case "$host" in
   350             *mingw32ce*)
   351                 use_music_native_midi=no
   352                 ;;
   353             *-*-cygwin* | *-*-mingw32*)
   354                 use_music_native_midi=yes
   355                 EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lwinmm"
   356                 ;;
   357             *-*-darwin*)
   358                 use_music_native_midi=yes
   359                 EXTRA_LDFLAGS="$EXTRA_LDFLAGS -Wl,-framework,AudioToolbox -Wl,-framework,AudioUnit -Wl,-framework,CoreServices"
   360                 ;;
   361         esac
   362         if test x$use_music_native_midi = xyes; then
   363             EXTRA_CFLAGS="$EXTRA_CFLAGS -DUSE_NATIVE_MIDI -I\$(srcdir)/native_midi"
   364             SOURCES="$SOURCES $srcdir/native_midi/*.c"
   365         fi
   366     fi
   367     AC_ARG_ENABLE([music-native-midi-gpl],
   368 AC_HELP_STRING([--enable-music-native-midi-gpl], [enable native MIDI on UNIX using GPL code [[default=no]]]),
   369                   [], [enable_music_native_midi_gpl=no])
   370     if test x$enable_music_native_midi_gpl = xyes; then
   371         use_music_native_midi_gpl=no
   372         case "$host" in
   373             *-*-linux* | *-*-freebsd*)
   374                 use_music_native_midi_gpl=yes
   375                 ;;
   376         esac
   377         if test x$use_music_native_midi_gpl = xyes; then
   378             EXTRA_CFLAGS="$EXTRA_CFLAGS -DUSE_NATIVE_MIDI -I\$(srcdir)/native_midi"
   379             SOURCES="$SOURCES $srcdir/native_midi_gpl/*.c"
   380         fi
   381     fi
   382 fi
   383 
   384 AC_ARG_ENABLE([music-ogg],
   385 AC_HELP_STRING([--enable-music-ogg], [enable Ogg Vorbis music [[default=yes]]]),
   386               [], [enable_music_ogg=yes])
   387 AC_ARG_ENABLE(music-ogg-tremor,
   388 AC_HELP_STRING([--enable-music-ogg-tremor], [enable OGG Vorbis music via libtremor [[default=no]]]),
   389               [], enable_music_ogg_tremor=no)
   390 AC_ARG_ENABLE([music-ogg-shared],
   391 AC_HELP_STRING([--enable-music-ogg-shared], [dynamically load Ogg Vorbis support [[default=yes]]]),
   392               [], [enable_music_ogg_shared=yes])
   393 if test x$enable_music_ogg = xyes; then
   394     if test x$enable_music_ogg_tremor = xyes; then
   395         AC_CHECK_HEADER([tremor/ivorbisfile.h], [have_tremor_hdr=yes])
   396         AC_CHECK_LIB([vorbisidec], [ov_open_callbacks], [have_tremor_lib=yes])
   397         if test x$have_tremor_hdr = xyes -a x$have_tremor_lib = xyes; then
   398             case "$host" in
   399                 *-*-darwin*)
   400                     ogg_lib=[`find_lib libvorbisidec.dylib`]
   401                     if test x$ogg_lib = x; then
   402                         ogg_lib=[`find_lib libvorbisidec.[0-9]`]
   403                     fi
   404                     if test x$ogg_lib = x; then
   405                         ogg_lib=[`find_lib libvorbisidec.[0-9]*`]
   406                     fi
   407                     ;;
   408                 *-*-cygwin* | *-*-mingw32*)
   409                     ogg_lib=[`find_lib "vorbisidec*.dll"`]
   410                     ;;
   411                 *)
   412                     ogg_lib=[`find_lib "libvorbisidec.so.[0-9]"`]
   413                     if test x$ogg_lib = x; then
   414                         ogg_lib=[`find_lib "libvorbisidec.so.[0-9]*"`]
   415                     fi
   416                     ;;
   417             esac
   418             SOURCES="$SOURCES $srcdir/*_ogg.c"
   419             EXTRA_CFLAGS="$EXTRA_CFLAGS -DOGG_MUSIC -DOGG_USE_TREMOR"
   420             if test x$enable_music_ogg_shared = xyes && test x$ogg_lib != x; then
   421                 echo "-- dynamic libvorbisidec -> $ogg_lib"
   422                 EXTRA_CFLAGS="$EXTRA_CFLAGS -DOGG_DYNAMIC=\\\"$ogg_lib\\\""
   423             else
   424                 EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lvorbisidec -lvorbis -logg $LIBM"
   425             fi
   426         else
   427             AC_MSG_WARN([*** Unable to find Ogg Vorbis Tremor library (http://www.xiph.org/)])
   428             AC_MSG_WARN([Ogg Vorbis support disabled])
   429         fi
   430     else
   431         AC_CHECK_HEADER([vorbis/vorbisfile.h], [have_ogg_hdr=yes])
   432         AC_CHECK_LIB([vorbisfile], [ov_open_callbacks], [have_ogg_lib=yes])
   433         if test x$have_ogg_hdr = xyes -a x$have_ogg_lib = xyes; then
   434             case "$host" in
   435                 *-*-darwin*)
   436                     ogg_lib=[`find_lib libvorbisfile.dylib`]
   437                     ;;
   438                 *-*-cygwin* | *-*-mingw32*)
   439                     ogg_lib=[`find_lib "libvorbisfile*.dll"`]
   440                     ;;
   441                 *)
   442                     ogg_lib=[`find_lib "libvorbisfile.so.[0-9]"`]
   443                     if test x$ogg_lib = x; then
   444                         ogg_lib=[`find_lib "libvorbisfile.so.[0-9]*"`]
   445                     fi
   446                     ;;
   447             esac
   448             SOURCES="$SOURCES $srcdir/*_ogg.c"
   449             EXTRA_CFLAGS="$EXTRA_CFLAGS -DOGG_MUSIC"
   450             if test x$enable_music_ogg_shared = xyes && test x$ogg_lib != x; then
   451                 echo "-- dynamic libvorbisfile -> $ogg_lib"
   452                 EXTRA_CFLAGS="$EXTRA_CFLAGS -DOGG_DYNAMIC=\\\"$ogg_lib\\\""
   453             else
   454                 EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lvorbisfile -lvorbis -logg $LIBM"
   455             fi
   456         else
   457             AC_MSG_WARN([*** Unable to find Ogg Vorbis library (http://www.xiph.org/)])
   458             AC_MSG_WARN([Ogg Vorbis support disabled])
   459         fi
   460     fi
   461 fi
   462 
   463 libflac_ver=8
   464 AC_ARG_ENABLE([music-flac],
   465 AC_HELP_STRING([--enable-music-flac], [enable FLAC music [[default=yes]]]),
   466               [], [enable_music_flac=yes])
   467 AC_ARG_ENABLE([music-flac-shared],
   468 AC_HELP_STRING([--enable-music-flac-shared],
   469               [dynamically load FLAC support [[default=yes]]]),
   470               [], [enable_music_flac_shared=yes])
   471 if test x$enable_music_flac = xyes; then
   472     AC_CHECK_HEADER([FLAC/export.h], [have_flac_export=yes])
   473     if test x$have_flac_export = xyes; then
   474         LIBS_SAVED="$LIBS"
   475         LIBS="-lFLAC"
   476         AC_MSG_CHECKING([for libflac so-name version >= $libflac_ver])
   477         AC_TRY_RUN([
   478 #include "FLAC/export.h"
   479 #include "stdio.h"
   480 int main( int argc, char *argv[] ) {
   481 #if defined(FLAC_API_VERSION_CURRENT) && (FLAC_API_VERSION_CURRENT >= $libflac_ver)
   482     return 0;
   483 #else
   484     return 1;
   485 #endif
   486 }
   487 ], have_flac_ver=yes, have_flac_ver=no)
   488         LIBS="$LIBS_SAVED"
   489         AC_MSG_RESULT($have_flac_ver)
   490     fi
   491 
   492     if test x$have_flac_ver = xyes; then
   493         AC_CHECK_HEADER([FLAC/stream_decoder.h], [have_flac_hdr=yes])
   494         AC_CHECK_LIB([FLAC], [FLAC__stream_decoder_new], [have_flac_lib=yes])
   495         if test x$have_flac_hdr = xyes -a x$have_flac_lib = xyes; then    
   496             case "$host" in
   497                 *-*-darwin*)
   498                     flac_lib=[`find_lib libFLAC.dylib`]
   499                     ;;
   500                 *-*-cygwin* | *-*-mingw32*)
   501                     flac_lib=[`find_lib "libFLAC*.dll"`]
   502                     ;;
   503                 *)
   504                     flac_lib=[`find_lib "libFLAC.so.[0-9]"`]
   505                     if test x$flac_lib = x; then
   506                         flac_lib=[`find_lib "libFLAC.so.[0-9]*"`]
   507                     fi
   508                     ;;
   509             esac
   510             SOURCES="$SOURCES $srcdir/*_flac.c"
   511             EXTRA_CFLAGS="$EXTRA_CFLAGS -DFLAC_MUSIC"
   512             if test x$enable_music_flac_shared = xyes && test x$flac_lib != x; then
   513                 echo "-- dynamic libFLAC -> $flac_lib"
   514                 EXTRA_CFLAGS="$EXTRA_CFLAGS -DFLAC_DYNAMIC=\\\"$flac_lib\\\""
   515             else
   516                 EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lFLAC"
   517             fi
   518         fi
   519     else
   520         AC_MSG_WARN([*** Unable to find FLAC library (http://flac.sourceforge.net/)])
   521         AC_MSG_WARN([FLAC support disabled])
   522     fi
   523 fi
   524 
   525 AC_CHECK_HEADERS([signal.h], [EXTRA_CFLAGS="$EXTRA_CFLAGS -DHAVE_SIGNAL_H"])
   526 AC_CHECK_FUNCS(setbuf, [EXTRA_CFLAGS="$EXTRA_CFLAGS -DHAVE_SETBUF"])
   527 
   528 AC_ARG_ENABLE(music-mp3,
   529 AC_HELP_STRING([--enable-music-mp3], [enable MP3 music via smpeg [[default=yes]]]),
   530               [], enable_music_mp3=yes)
   531 AC_ARG_ENABLE([music-mp3-shared],
   532 AC_HELP_STRING([--enable-music-mp3-shared], [dynamically load MP3 support [[default=yes]]]),
   533               [], [enable_music_mp3_shared=yes])
   534 if test x$enable_music_mp3 = xyes; then
   535     SMPEG_VERSION=0.4.3
   536     AM_PATH_SMPEG($SMPEG_VERSION, have_smpeg=yes, have_smpeg=no)
   537     if test x$have_smpeg = xyes; then
   538         case "$host" in
   539             *-*-darwin*)
   540                 smpeg_lib=[`find_lib libsmpeg.dylib`]
   541                 ;;
   542             *-*-cygwin* | *-*-mingw32*)
   543                 smpeg_lib=[`find_lib "smpeg*.dll"`]
   544                 ;;
   545             *)
   546                 smpeg_lib=[`find_lib "libsmpeg*.so.[0-9]"`]
   547                 if test x$smpeg_lib = x; then
   548                     smpeg_lib=[`find_lib "libsmpeg*.so.[0-9]*"`]
   549                 fi
   550                 ;;
   551         esac
   552         SOURCES="$SOURCES $srcdir/*_mp3.c"
   553         EXTRA_CFLAGS="$EXTRA_CFLAGS -DMP3_MUSIC $SMPEG_CFLAGS"
   554         if test x$enable_music_mp3_shared = xyes && test x$smpeg_lib != x; then
   555             echo "-- dynamic libsmpeg -> $smpeg_lib"
   556             EXTRA_CFLAGS="$EXTRA_CFLAGS -DMP3_DYNAMIC=\\\"$smpeg_lib\\\""
   557         else
   558             EXTRA_LDFLAGS="$EXTRA_LDFLAGS $SMPEG_LIBS"
   559         fi
   560     else
   561         AC_MSG_WARN([*** Unable to find SMPEG library (http://icculus.org/smpeg/)])
   562     fi
   563 fi
   564 
   565 AC_ARG_ENABLE(music-mp3-mad-gpl,
   566 AC_HELP_STRING([--enable-music-mp3-mad-gpl], [enable MP3 music via libmad GPL code [[default=no]]]),
   567                   [], [enable_music_mp3_mad_gpl=no])
   568 if test x$enable_music_mp3_mad_gpl = xyes; then
   569     AC_MSG_CHECKING(for libmad headers)
   570     have_libmad=no
   571     AC_TRY_COMPILE([
   572      #include "mad.h"
   573     ],[
   574     ],[
   575     have_libmad=yes
   576     ])
   577     AC_MSG_RESULT($have_libmad)
   578     if test x$have_libmad = xyes; then
   579         SOURCES="$SOURCES $srcdir/music_mad.c"
   580         EXTRA_CFLAGS="$EXTRA_CFLAGS -DMP3_MAD_MUSIC"
   581         EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lmad"
   582     else
   583         AC_MSG_WARN([*** Unable to find MAD library (http://www.underbit.com/products/mad/)])
   584     fi
   585 fi
   586 
   587 if test x$have_smpeg != xyes -a x$have_libmad != xyes; then
   588     AC_MSG_WARN([MP3 support disabled])
   589 fi
   590 
   591 
   592 OBJECTS=`echo $SOURCES`
   593 DEPENDS=`echo $SOURCES`
   594 OBJECTS=`echo "$OBJECTS" | sed 's,[[^ ]]*/\([[^ ]]*\)\.c,$(objects)/\1.lo,g'`
   595 DEPENDS=`echo "$DEPENDS" | sed 's,\([[^ ]]*\)/\([[^ ]]*\)\.c,\\
   596 $(objects)/\2.lo: \1/\2.c\\
   597 	\$(LIBTOOL) --mode=compile \$(CC) \$(CFLAGS) \$(EXTRA_CFLAGS) '"$DEPENDENCY_TRACKING_OPTIONS"' -c \$< -o \$@,g'`
   598 
   599 VERSION_OBJECTS=`echo $VERSION_SOURCES`
   600 VERSION_DEPENDS=`echo $VERSION_SOURCES`
   601 VERSION_OBJECTS=`echo "$VERSION_OBJECTS" | sed 's,[[^ ]]*/\([[^ ]]*\)\.rc,$(objects)/\1.o,g'`
   602 VERSION_DEPENDS=`echo "$VERSION_DEPENDS" | sed 's,\([[^ ]]*\)/\([[^ ]]*\)\.rc,\\
   603 $(objects)/\2.o: \1/\2.rc\\
   604 	\$(WINDRES) \$< \$@,g'`
   605 
   606 PLAYWAVE_SOURCES="$srcdir/playwave.c"
   607 PLAYWAVE_OBJECTS=`echo $PLAYWAVE_SOURCES`
   608 PLAYWAVE_DEPENDS=`echo $PLAYWAVE_SOURCES`
   609 PLAYWAVE_OBJECTS=`echo "$PLAYWAVE_OBJECTS" | sed 's,[[^ ]]*/\([[^ ]]*\)\.c,$(objects)/\1.lo,g'`
   610 PLAYWAVE_DEPENDS=`echo "$PLAYWAVE_DEPENDS" | sed 's,\([[^ ]]*\)/\([[^ ]]*\)\.c,\\
   611 $(objects)/\2.lo: \1/\2.c\\
   612 	\$(LIBTOOL) --mode=compile \$(CC) \$(CFLAGS) \$(EXTRA_CFLAGS) '"$DEPENDENCY_TRACKING_OPTIONS"' -c \$< -o \$@,g'`
   613 
   614 PLAYMUS_SOURCES="$srcdir/playmus.c"
   615 PLAYMUS_OBJECTS=`echo $PLAYMUS_SOURCES`
   616 PLAYMUS_DEPENDS=`echo $PLAYMUS_SOURCES`
   617 PLAYMUS_OBJECTS=`echo "$PLAYMUS_OBJECTS" | sed 's,[[^ ]]*/\([[^ ]]*\)\.c,$(objects)/\1.lo,g'`
   618 PLAYMUS_DEPENDS=`echo "$PLAYMUS_DEPENDS" | sed 's,\([[^ ]]*\)/\([[^ ]]*\)\.c,\\
   619 $(objects)/\2.lo: \1/\2.c\\
   620 	\$(LIBTOOL) --mode=compile \$(CC) \$(CFLAGS) \$(EXTRA_CFLAGS) '"$DEPENDENCY_TRACKING_OPTIONS"' -c \$< -o \$@,g'`
   621 
   622 dnl Expand the sources and objects needed to build the library
   623 AC_SUBST(ac_aux_dir)
   624 AC_SUBST(OBJECTS)
   625 AC_SUBST(DEPENDS)
   626 AC_SUBST(VERSION_OBJECTS)
   627 AC_SUBST(VERSION_DEPENDS)
   628 AC_SUBST(PLAYWAVE_OBJECTS)
   629 AC_SUBST(PLAYWAVE_DEPENDS)
   630 AC_SUBST(PLAYMUS_OBJECTS)
   631 AC_SUBST(PLAYMUS_DEPENDS)
   632 AC_SUBST(BUILD_CFLAGS)
   633 AC_SUBST(EXTRA_CFLAGS)
   634 AC_SUBST(BUILD_LDFLAGS)
   635 AC_SUBST(EXTRA_LDFLAGS)
   636 AC_SUBST(EXE)
   637 AC_SUBST(WINDRES)
   638 AC_SUBST(SDL_VERSION)
   639 AC_SUBST(SDL_CFLAGS)
   640 AC_SUBST(SDL_LIBS)
   641 
   642 AC_OUTPUT([
   643     Makefile SDL_mixer.spec SDL_mixer.qpg SDL_mixer.pc
   644 ])