configure.in
author Thomas Bernard <miniupnp@free.fr>
Fri, 30 Nov 2018 11:04:15 +0100
branchSDL-1.2
changeset 634 68f958f43339
parent 602 5d369ebb4940
permissions -rw-r--r--
IMG_xcf.c: Avoid infinite loop in read_xcf_header()
     1 dnl Process this file with autoconf to produce a configure script.
     2 AC_INIT(README)
     3 
     4 dnl Set various version strings - taken gratefully from the GTk sources
     5 
     6 # Making releases:
     7 #   MICRO_VERSION += 1;
     8 #   INTERFACE_AGE += 1;
     9 #   BINARY_AGE += 1;
    10 # if any functions have been added, set INTERFACE_AGE to 0.
    11 # if backwards compatibility has been broken,
    12 # set BINARY_AGE and INTERFACE_AGE to 0.
    13 
    14 MAJOR_VERSION=1
    15 MINOR_VERSION=2
    16 MICRO_VERSION=13
    17 INTERFACE_AGE=5
    18 BINARY_AGE=13
    19 VERSION=$MAJOR_VERSION.$MINOR_VERSION.$MICRO_VERSION
    20 
    21 AC_SUBST(MAJOR_VERSION)
    22 AC_SUBST(MINOR_VERSION)
    23 AC_SUBST(MICRO_VERSION)
    24 AC_SUBST(INTERFACE_AGE)
    25 AC_SUBST(BINARY_AGE)
    26 AC_SUBST(VERSION)
    27 
    28 # libtool versioning
    29 LT_INIT([win32-dll])
    30 
    31 LT_RELEASE=$MAJOR_VERSION.$MINOR_VERSION
    32 LT_CURRENT=`expr $MICRO_VERSION - $INTERFACE_AGE`
    33 LT_REVISION=$INTERFACE_AGE
    34 LT_AGE=`expr $BINARY_AGE - $INTERFACE_AGE`
    35 
    36 AC_SUBST(LT_RELEASE)
    37 AC_SUBST(LT_CURRENT)
    38 AC_SUBST(LT_REVISION)
    39 AC_SUBST(LT_AGE)
    40 
    41 dnl Detect the canonical build and host environments
    42 AC_CANONICAL_HOST
    43 
    44 dnl Setup for automake
    45 AM_INIT_AUTOMAKE(SDL_image, $VERSION)
    46 
    47 dnl Check for tools
    48 AC_PROG_LIBTOOL
    49 AC_PROG_CC
    50 AC_PROG_OBJC
    51 AC_C_INLINE
    52 AC_PROG_INSTALL
    53 AC_PROG_MAKE_SET
    54 if test -z "$host_alias"; then
    55     hostaliaswindres=
    56 else
    57     hostaliaswindres="$host_alias-windres"
    58 fi
    59 AC_CHECK_PROGS(WINDRES, [windres $hostaliaswindres $host_os-windres])
    60 
    61 case "$host" in
    62     *-*-beos*)
    63         ac_default_prefix=/boot/develop/tools/gnupro
    64         ;;
    65     *-*-cygwin* | *-*-mingw32*)
    66         if test "$build" != "$host"; then # cross-compiling
    67             # Default cross-compile location
    68             ac_default_prefix=/usr/local/cross-tools/i386-mingw32
    69         else
    70             # Look for the location of the tools and install there
    71             if test "$BUILD_PREFIX" != ""; then
    72                 ac_default_prefix=$BUILD_PREFIX
    73             fi
    74         fi
    75         if test x$WINDRES != x; then
    76             use_version_rc=true
    77         fi
    78         ;;
    79     *-*-darwin*)
    80         AC_ARG_ENABLE([imageio], [AC_HELP_STRING([--enable-imageio], [use native Mac OS X frameworks for loading images [default=yes]])],
    81                       [], [enable_imageio=yes])
    82         dnl Show a message when we use ImageIO support so it's not a surprise
    83         AC_MSG_CHECKING([for ImageIO support])
    84         AC_MSG_RESULT($enable_imageio)
    85         if test x$enable_imageio = xyes; then
    86             IMG_LIBS="-Wl,-framework,ApplicationServices -lobjc $IMG_LIBS"
    87         else
    88             CFLAGS="$CFLAGS -DSDL_IMAGE_USE_COMMON_BACKEND"
    89         fi
    90         ;;
    91 esac
    92 AM_CONDITIONAL(USE_IMAGEIO, test x$enable_imageio = xyes)
    93 AM_CONDITIONAL(USE_VERSION_RC, test x$use_version_rc = xtrue)
    94 
    95 dnl set this to use on systems that use lib64 instead of lib
    96 base_libdir=`echo \${libdir} | sed 's/.*\/\(.*\)/\1/; q'`
    97 
    98 dnl Function to find a library in the compiler search path
    99 find_lib()
   100 {
   101     gcc_bin_path=[`$CC -print-search-dirs 2>/dev/null | fgrep programs: | sed 's/[^=]*=\(.*\)/\1/' | sed 's/:/ /g'`]
   102     gcc_lib_path=[`$CC -print-search-dirs 2>/dev/null | fgrep libraries: | sed 's/[^=]*=\(.*\)/\1/' | sed 's/:/ /g'`]
   103     env_lib_path=[`echo $LIBS $LDFLAGS $* | sed 's/-L[ ]*//g'`]
   104     if test "$cross_compiling" = yes; then
   105         host_lib_path=""
   106     else
   107         host_lib_path="/usr/$base_libdir /usr/local/$base_libdir"
   108     fi
   109     for path in $env_lib_path $gcc_bin_path $gcc_lib_path $host_lib_path; do
   110         lib=[`ls -- $path/$1 2>/dev/null | sed -e '/\.so\..*\./d' -e 's,.*/,,' | sort | tail -1`]
   111         if test x$lib != x; then
   112             echo $lib
   113             return
   114         fi
   115     done
   116 }
   117 
   118 dnl Check for SDL
   119 SDL_VERSION=1.2.10
   120 AC_SUBST(SDL_VERSION)
   121 AM_PATH_SDL($SDL_VERSION,
   122             :,
   123            AC_MSG_ERROR([*** SDL version $SDL_VERSION not found!])
   124 )
   125 CFLAGS="$CFLAGS $SDL_CFLAGS"
   126 LIBS="$LIBS $SDL_LIBS"
   127 saved_LIBS="$LIBS"
   128 
   129 dnl Check command-line options
   130 AC_ARG_ENABLE([bmp], [AC_HELP_STRING([--enable-bmp], [support loading BMP/ICO/CUR images [default=yes]])],
   131  [], [enable_bmp=yes])
   132 AC_ARG_ENABLE([gif], [AC_HELP_STRING([--enable-gif], [support loading GIF images [default=yes]])],
   133  [], [enable_gif=yes])
   134 AC_ARG_ENABLE([jpg], [AC_HELP_STRING([--enable-jpg], [support loading JPG images [default=yes]])],
   135  [], [enable_jpg=yes])
   136 AC_ARG_ENABLE([jpg-shared], AC_HELP_STRING([--enable-jpg-shared], [dynamically load JPG support [[default=yes]]]),
   137  [], [enable_jpg_shared=yes])
   138 AC_ARG_ENABLE([lbm], [AC_HELP_STRING([--enable-lbm], [support loading LBM images [default=yes]])],
   139  [], [enable_lbm=yes])
   140 AC_ARG_ENABLE([pcx], [AC_HELP_STRING([--enable-pcx], [support loading PCX images [default=yes]])],
   141  [], [enable_pcx=yes])
   142 AC_ARG_ENABLE([png], [AC_HELP_STRING([--enable-png], [support loading PNG images [default=yes]])],
   143  [], [enable_png=yes])
   144 AC_ARG_ENABLE([png-shared], AC_HELP_STRING([--enable-png-shared], [dynamically load PNG support [[default=yes]]]),
   145  [], [enable_png_shared=yes])
   146 AC_ARG_ENABLE([pnm], [AC_HELP_STRING([--enable-pnm], [support loading PNM images [default=yes]])],
   147  [], [enable_pnm=yes])
   148 AC_ARG_ENABLE([tga], [AC_HELP_STRING([--enable-tga], [support loading TGA images [default=yes]])],
   149  [], [enable_tga=yes])
   150 AC_ARG_ENABLE([tif], [AC_HELP_STRING([--enable-tif], [support loading TIFF images [default=yes]])],
   151  [], [enable_tif=yes])
   152 AC_ARG_ENABLE([tif-shared], AC_HELP_STRING([--enable-tif-shared], [dynamically load TIFF support [[default=yes]]]),
   153  [], [enable_tif_shared=yes])
   154 AC_ARG_ENABLE([xcf], [AC_HELP_STRING([--enable-xcf], [support loading XCF images [default=yes]])],
   155  [], [enable_xcf=yes])
   156 AC_ARG_ENABLE([xpm], [AC_HELP_STRING([--enable-xpm], [support loading XPM images [default=yes]])],
   157  [], [enable_xpm=yes])
   158 AC_ARG_ENABLE([xv], [AC_HELP_STRING([--enable-xv], [support loading XV images [default=yes]])],
   159  [], [enable_xv=yes])
   160 AC_ARG_ENABLE([webp], [AC_HELP_STRING([--enable-webp], [support loading WEBP images [default=yes]])],
   161  [], [enable_webp=yes])
   162 AC_ARG_ENABLE([webp-shared], AC_HELP_STRING([--enable-webp-shared], [dynamically load WEBP support [[default=yes]]]),
   163  [], [enable_webp_shared=yes])
   164 
   165 if (test x$enable_jpg = xyes || test x$enable_tif = xyes) && test x$enable_imageio != xyes; then
   166     AC_CHECK_HEADER([jpeglib.h], [have_jpg_hdr=yes])
   167     AC_CHECK_LIB([jpeg], [jpeg_CreateDecompress], [have_jpg_lib=yes])
   168     if test x$have_jpg_hdr = xyes -a x$have_jpg_lib = xyes; then
   169         if test x$enable_jpg = xyes; then
   170             AC_DEFINE([LOAD_JPG])
   171         fi
   172         LIBS="-ljpeg $LIBS"
   173 
   174         case "$host" in
   175             *-*-darwin*)
   176                 jpg_lib=[`find_lib libjpeg.dylib`]
   177                 ;;
   178             *-*-cygwin* | *-*-mingw32*)
   179                 jpg_lib=[`find_lib "libjpeg*.dll"`]
   180                 ;;
   181             *)
   182                 jpg_lib=[`find_lib "libjpeg[0-9]*.so.*"`]
   183                 if test x$jpg_lib = x; then
   184                     jpg_lib=[`find_lib "libjpeg.so.*"`]
   185                 fi
   186                 ;;
   187         esac
   188     elif test x$enable_jpg = xyes; then
   189         AC_MSG_WARN([*** Unable to find JPEG library (http://www.ijg.org/)])
   190         AC_MSG_WARN([JPG image loading disabled])
   191     fi
   192 fi
   193 
   194 if test x$enable_png = xyes -a x$enable_imageio != xyes; then
   195     PKG_CHECK_MODULES([LIBPNG], [libpng], [dnl
   196         have_png_hdr=yes
   197         have_png_lib=yes
   198       ], [dnl
   199         AC_CHECK_HEADER([png.h], [
   200             have_png_hdr=yes
   201             LIBPNG_CFLAGS=""
   202         ])
   203         AC_CHECK_LIB([png], [png_create_read_struct], [
   204             have_png_lib=yes
   205             LIBPNG_LIBS="-lpng -lz"
   206         ], [], [-lz])
   207       ])
   208     if test x$have_png_hdr = xyes -a x$have_png_lib = xyes; then
   209         AC_DEFINE([LOAD_PNG])
   210 
   211         case "$host" in
   212             *-*-darwin*)
   213                 png_lib=[`find_lib libpng.dylib`]
   214                 ;;
   215             *-*-cygwin* | *-*-mingw32*)
   216                 png_lib=[`find_lib "libpng*.dll"`]
   217                 ;;
   218             *)
   219                 png_lib=[`find_lib "libpng[0-9]*.so.*"`]
   220                 if test x$png_lib = x; then
   221                     png_lib=[`find_lib "libpng.so.*"`]
   222                 fi
   223                 ;;
   224         esac
   225     else
   226         AC_MSG_WARN([*** Unable to find PNG library (http://www.libpng.org/pub/png/libpng.html)])
   227         AC_MSG_WARN([PNG image loading disabled])
   228     fi
   229 fi
   230 
   231 if test x$enable_tif = xyes -a x$enable_imageio != xyes; then
   232     AC_CHECK_HEADER([tiffio.h], [have_tif_hdr=yes])
   233     AC_CHECK_LIB([tiff], [TIFFClientOpen], [have_tif_lib=yes], [], [-lz])
   234     if test x$have_tif_hdr = xyes -a x$have_tif_lib = xyes; then
   235         AC_DEFINE([LOAD_TIF])
   236 
   237         case "$host" in
   238             *-*-darwin*)
   239                 tif_lib=[`find_lib libtiff.dylib`]
   240                 ;;
   241             *-*-cygwin* | *-*-mingw32*)
   242                 tif_lib=[`find_lib "libtiff-*.dll"`]
   243                 ;;
   244             *)
   245                 tif_lib=[`find_lib "libtiff[0-9]*.so.*"`]
   246                 if test x$tif_lib = x; then
   247                     tif_lib=[`find_lib "libtiff.so.*"`]
   248                 fi
   249                 ;;
   250         esac
   251     else
   252         AC_MSG_WARN([*** Unable to find Tiff library (http://www.remotesensing.org/libtiff/)])
   253         AC_MSG_WARN([TIF image loading disabled])
   254     fi
   255 fi
   256 
   257 if test x$enable_webp = xyes; then
   258     PKG_CHECK_MODULES([LIBWEBP], [libwebp], [dnl
   259         have_webp_hdr=yes
   260         have_webp_lib=yes
   261       ], [dnl
   262         AC_CHECK_HEADER([webp/decode.h], [
   263             have_webp_hdr=yes
   264             LIBWEBP_CFLAGS=""
   265         ])
   266         AC_CHECK_LIB([webp], [WebPGetDecoderVersion], [
   267             have_webp_lib=yes
   268             LIBWEBP_LIBS="-lwebp"
   269         ], [], [-lm])
   270       ])
   271     if test x$have_webp_hdr = xyes -a x$have_webp_lib = xyes; then
   272         AC_DEFINE([LOAD_WEBP])
   273 
   274         case "$host" in
   275             *-*-darwin*)
   276                 webp_lib=[`find_lib libwebp.dylib`]
   277                 ;;
   278             *-*-cygwin* | *-*-mingw32*)
   279                 webp_lib=[`find_lib "libwebp*.dll"`]
   280                 ;;
   281             *)
   282                 webp_lib=[`find_lib "libwebp[0-9]*.so.*"`]
   283                 if test x$webp_lib = x; then
   284                     webp_lib=[`find_lib "libwebp.so.*"`]
   285                 fi
   286                 ;;
   287         esac
   288     else
   289         AC_MSG_WARN([*** Unable to find WEBP library (http://code.google.com/intl/en-US/speed/webp/index.html)])
   290         AC_MSG_WARN([WEBP Pimage loading disabled])
   291     fi
   292 fi
   293 
   294 if test x$enable_bmp = xyes; then
   295     AC_DEFINE([LOAD_BMP])
   296 fi
   297 
   298 if test x$enable_gif = xyes; then
   299     AC_DEFINE([LOAD_GIF])
   300 fi
   301 
   302 if test x$enable_lbm = xyes; then
   303     AC_DEFINE([LOAD_LBM])
   304 fi
   305 
   306 if test x$enable_pcx = xyes; then
   307     AC_DEFINE([LOAD_PCX])
   308 fi
   309 
   310 if test x$enable_pnm = xyes; then
   311     AC_DEFINE([LOAD_PNM])
   312 fi
   313 
   314 if test x$enable_tga = xyes; then
   315     AC_DEFINE([LOAD_TGA])
   316 fi
   317 
   318 if test x$enable_xcf = xyes; then
   319     AC_DEFINE([LOAD_XCF])
   320 fi
   321 
   322 if test x$enable_xpm = xyes; then
   323     AC_DEFINE([LOAD_XPM])
   324 fi
   325 
   326 if test x$enable_xv = xyes; then
   327     AC_DEFINE([LOAD_XV])
   328 fi
   329 
   330 if test x$enable_webp = xyes -a x$have_webp_hdr = xyes -a x$have_webp_lib = xyes; then
   331     CFLAGS="$LIBWEBP_CFLAGS $CFLAGS"
   332     if test x$enable_webp_shared = xyes && test x$webp_lib != x; then
   333         echo "-- dynamic libwebp -> $webp_lib"
   334         AC_DEFINE_UNQUOTED(LOAD_WEBP_DYNAMIC, "$webp_lib")
   335     else
   336         IMG_LIBS="$LIBWEBP_LIBS $IMG_LIBS"
   337     fi
   338 fi
   339 
   340 if test x$enable_tif = xyes -a x$have_tif_hdr = xyes -a x$have_tif_lib = xyes; then
   341     if test x$enable_tif_shared = xyes && test x$tif_lib != x; then
   342         echo "-- dynamic libtiff -> $tif_lib"
   343         AC_DEFINE_UNQUOTED(LOAD_TIF_DYNAMIC, "$tif_lib")
   344     else
   345         if test x$have_libjpeg = xyes; then
   346             # Disable dynamic jpeg since we're linking it explicitly
   347             jpg_lib=''
   348         fi
   349         IMG_LIBS="-ltiff -lz $IMG_LIBS"
   350     fi
   351 fi
   352 if test x$enable_jpg = xyes -a x$have_jpg_hdr = xyes -a x$have_jpg_lib = xyes; then
   353     if test x$enable_jpg_shared = xyes && test x$jpg_lib != x; then
   354         echo "-- dynamic libjpeg -> $jpg_lib"
   355         AC_DEFINE_UNQUOTED(LOAD_JPG_DYNAMIC, "$jpg_lib")
   356     else
   357         IMG_LIBS="-ljpeg $IMG_LIBS"
   358     fi
   359 fi
   360 if test x$enable_png = xyes -a x$have_png_hdr = xyes -a x$have_png_lib = xyes; then
   361     CFLAGS="$LIBPNG_CFLAGS $CFLAGS"
   362     if test x$enable_png_shared = xyes && test x$png_lib != x; then
   363         echo "-- dynamic libpng -> $png_lib"
   364         AC_DEFINE_UNQUOTED(LOAD_PNG_DYNAMIC, "$png_lib")
   365     else
   366         IMG_LIBS="$LIBPNG_LIBS $IMG_LIBS"
   367     fi
   368 fi
   369 
   370 LIBS="$saved_LIBS"
   371 
   372 AC_SUBST([WINDRES])
   373 AC_SUBST([IMG_LIBS])
   374 
   375 OBJCFLAGS=$CFLAGS
   376 
   377 # Finally create all the generated files
   378 AC_OUTPUT([
   379 Makefile
   380 SDL_image.spec
   381 SDL_image.pc
   382 ])