configure.in
author Sam Lantinga <slouken@libsdl.org>
Sun, 01 Jan 2017 18:50:51 -0800
changeset 496 6332f9425dcc
parent 491 4088a517f9a5
child 524 b4b49635cbd8
permissions -rw-r--r--
Updated copyright for 2017
     1 dnl Process this file with autoconf to produce a configure script.
     2 AC_INIT(README.txt)
     3 
     4 dnl Set various version strings - taken gratefully from the GTk sources
     5 
     6 # Making releases:
     7 #   MICRO_VERSION += 1;
     8 #   INTERFACE_AGE += 1;
     9 #   BINARY_AGE += 1;
    10 # if any functions have been added, set INTERFACE_AGE to 0.
    11 # if backwards compatibility has been broken,
    12 # set BINARY_AGE and INTERFACE_AGE to 0.
    13 
    14 MAJOR_VERSION=2
    15 MINOR_VERSION=0
    16 MICRO_VERSION=1
    17 INTERFACE_AGE=1
    18 BINARY_AGE=1
    19 VERSION=$MAJOR_VERSION.$MINOR_VERSION.$MICRO_VERSION
    20 
    21 AC_SUBST(MAJOR_VERSION)
    22 AC_SUBST(MINOR_VERSION)
    23 AC_SUBST(MICRO_VERSION)
    24 AC_SUBST(INTERFACE_AGE)
    25 AC_SUBST(BINARY_AGE)
    26 AC_SUBST(VERSION)
    27 
    28 # libtool versioning
    29 LT_INIT([win32-dll])
    30 
    31 LT_RELEASE=$MAJOR_VERSION.$MINOR_VERSION
    32 LT_CURRENT=`expr $MICRO_VERSION - $INTERFACE_AGE`
    33 LT_REVISION=$INTERFACE_AGE
    34 LT_AGE=`expr $BINARY_AGE - $INTERFACE_AGE`
    35 
    36 AC_SUBST(LT_RELEASE)
    37 AC_SUBST(LT_CURRENT)
    38 AC_SUBST(LT_REVISION)
    39 AC_SUBST(LT_AGE)
    40 
    41 dnl Detect the canonical build and host environments
    42 AC_CANONICAL_HOST
    43 
    44 dnl Setup for automake
    45 AM_INIT_AUTOMAKE(SDL2_image, $VERSION)
    46 
    47 dnl Check for tools
    48 AC_PROG_LIBTOOL
    49 AC_PROG_CC
    50 AC_PROG_OBJC
    51 AC_C_INLINE
    52 AC_PROG_INSTALL
    53 AC_PROG_MAKE_SET
    54 if test -z "$host_alias"; then
    55     hostaliaswindres=
    56 else
    57     hostaliaswindres="$host_alias-windres"
    58 fi
    59 AC_CHECK_PROGS(WINDRES, [windres $hostaliaswindres $host_os-windres])
    60 
    61 case "$host" in
    62     *-*-beos*)
    63         ac_default_prefix=/boot/develop/tools/gnupro
    64         ;;
    65     *-*-cygwin* | *-*-mingw32*)
    66         if test "$build" != "$host"; then # cross-compiling
    67             # Default cross-compile location
    68             ac_default_prefix=/usr/local/cross-tools/$host
    69         else
    70             # Look for the location of the tools and install there
    71             if test "$BUILD_PREFIX" != ""; then
    72                 ac_default_prefix=$BUILD_PREFIX
    73             fi
    74         fi
    75         if test x$WINDRES != x; then
    76             use_version_rc=true
    77         fi
    78         ;;
    79     *-*-darwin*)
    80         AC_ARG_ENABLE([imageio], [AC_HELP_STRING([--enable-imageio], [use native Mac OS X frameworks for loading images [default=yes]])],
    81                       [], [enable_imageio=yes])
    82         if test x$enable_imageio = xyes; then
    83             IMG_LIBS="-Wl,-framework,ApplicationServices -lobjc $IMG_LIBS"
    84         else
    85             CFLAGS="$CFLAGS -DSDL_IMAGE_USE_COMMON_BACKEND"
    86         fi
    87         ;;
    88 esac
    89 AM_CONDITIONAL(USE_IMAGEIO, test x$enable_imageio = xyes)
    90 AM_CONDITIONAL(USE_VERSION_RC, test x$use_version_rc = xtrue)
    91 
    92 dnl set this to use on systems that use lib64 instead of lib
    93 base_libdir=`echo \${libdir} | sed 's/.*\/\(.*\)/\1/; q'`
    94 
    95 dnl Function to find a library in the compiler search path
    96 find_lib()
    97 {
    98     gcc_bin_path=[`$CC -print-search-dirs 2>/dev/null | fgrep programs: | sed 's/[^=]*=\(.*\)/\1/' | sed 's/:/ /g'`]
    99     gcc_lib_path=[`$CC -print-search-dirs 2>/dev/null | fgrep libraries: | sed 's/[^=]*=\(.*\)/\1/' | sed 's/:/ /g'`]
   100     env_lib_path=[`echo $LIBS $LDFLAGS $* | sed 's/-L[ ]*//g'`]
   101     if test "$cross_compiling" = yes; then
   102         host_lib_path=""
   103     else
   104         host_lib_path="/usr/$base_libdir /usr/local/$base_libdir"
   105     fi
   106     for path in $env_lib_path $gcc_bin_path $gcc_lib_path $host_lib_path; do
   107         lib=[`ls -- $path/$1 2>/dev/null | sed -e '/\.so\..*\./d' -e 's,.*/,,' | sort | tail -1`]
   108         if test x$lib != x; then
   109             echo $lib
   110             return
   111         fi
   112     done
   113 }
   114 
   115 dnl Check for SDL
   116 SDL_VERSION=2.0.0
   117 AC_SUBST(SDL_VERSION)
   118 AM_PATH_SDL2($SDL_VERSION,
   119             :,
   120            AC_MSG_ERROR([*** SDL version $SDL_VERSION not found!])
   121 )
   122 CFLAGS="$CFLAGS $SDL_CFLAGS"
   123 LIBS="$LIBS $SDL_LIBS"
   124 saved_LIBS="$LIBS"
   125 
   126 dnl Check command-line options
   127 AC_ARG_ENABLE([bmp], [AC_HELP_STRING([--enable-bmp], [support loading BMP/ICO/CUR images [default=yes]])],
   128  [], [enable_bmp=yes])
   129 AC_ARG_ENABLE([gif], [AC_HELP_STRING([--enable-gif], [support loading GIF images [default=yes]])],
   130  [], [enable_gif=yes])
   131 AC_ARG_ENABLE([jpg], [AC_HELP_STRING([--enable-jpg], [support loading JPG images [default=yes]])],
   132  [], [enable_jpg=yes])
   133 AC_ARG_ENABLE([jpg-shared], AC_HELP_STRING([--enable-jpg-shared], [dynamically load JPG support [[default=yes]]]),
   134  [], [enable_jpg_shared=yes])
   135 AC_ARG_ENABLE([lbm], [AC_HELP_STRING([--enable-lbm], [support loading LBM images [default=yes]])],
   136  [], [enable_lbm=yes])
   137 AC_ARG_ENABLE([pcx], [AC_HELP_STRING([--enable-pcx], [support loading PCX images [default=yes]])],
   138  [], [enable_pcx=yes])
   139 AC_ARG_ENABLE([png], [AC_HELP_STRING([--enable-png], [support loading PNG images [default=yes]])],
   140  [], [enable_png=yes])
   141 AC_ARG_ENABLE([png-shared], AC_HELP_STRING([--enable-png-shared], [dynamically load PNG support [[default=yes]]]),
   142  [], [enable_png_shared=yes])
   143 AC_ARG_ENABLE([pnm], [AC_HELP_STRING([--enable-pnm], [support loading PNM images [default=yes]])],
   144  [], [enable_pnm=yes])
   145 AC_ARG_ENABLE([tga], [AC_HELP_STRING([--enable-tga], [support loading TGA images [default=yes]])],
   146  [], [enable_tga=yes])
   147 AC_ARG_ENABLE([tif], [AC_HELP_STRING([--enable-tif], [support loading TIFF images [default=yes]])],
   148  [], [enable_tif=yes])
   149 AC_ARG_ENABLE([tif-shared], AC_HELP_STRING([--enable-tif-shared], [dynamically load TIFF support [[default=yes]]]),
   150  [], [enable_tif_shared=yes])
   151 AC_ARG_ENABLE([xcf], [AC_HELP_STRING([--enable-xcf], [support loading XCF images [default=yes]])],
   152  [], [enable_xcf=yes])
   153 AC_ARG_ENABLE([xpm], [AC_HELP_STRING([--enable-xpm], [support loading XPM images [default=yes]])],
   154  [], [enable_xpm=yes])
   155 AC_ARG_ENABLE([xv], [AC_HELP_STRING([--enable-xv], [support loading XV images [default=yes]])],
   156  [], [enable_xv=yes])
   157 AC_ARG_ENABLE([webp], [AC_HELP_STRING([--enable-webp], [support loading WEBP images [default=yes]])],
   158  [], [enable_webp=yes])
   159 AC_ARG_ENABLE([webp-shared], AC_HELP_STRING([--enable-webp-shared], [dynamically load WEBP support [[default=yes]]]),
   160  [], [enable_webp_shared=yes])
   161 
   162 dnl Show a message when we use ImageIO support so it's not a surprise
   163 AC_MSG_CHECKING([for ImageIO support])
   164 AC_MSG_RESULT($enable_imageio)
   165 
   166 if (test x$enable_jpg = xyes || test x$enable_tif = xyes) && test x$enable_imageio != xyes; then
   167     AC_CHECK_HEADER([jpeglib.h], [have_jpg_hdr=yes])
   168     AC_CHECK_LIB([jpeg], [jpeg_CreateDecompress], [have_jpg_lib=yes])
   169     if test x$have_jpg_hdr = xyes -a x$have_jpg_lib = xyes; then
   170         if test x$enable_jpg = xyes; then
   171             AC_DEFINE([LOAD_JPG])
   172         fi
   173         LIBS="-ljpeg $LIBS"
   174 
   175         case "$host" in
   176             *-*-darwin*)
   177                 jpg_lib=[`find_lib libjpeg.dylib`]
   178                 ;;
   179             *-*-cygwin* | *-*-mingw32*)
   180                 jpg_lib=[`find_lib "libjpeg*.dll"`]
   181                 ;;
   182             *)
   183                 jpg_lib=[`find_lib "libjpeg[0-9]*.so.*"`]
   184                 if test x$jpg_lib = x; then
   185                     jpg_lib=[`find_lib "libjpeg.so.*"`]
   186                 fi
   187                 ;;
   188         esac
   189     elif test x$enable_jpg = xyes; then
   190         AC_MSG_WARN([*** Unable to find JPEG library (http://www.ijg.org/)])
   191         AC_MSG_WARN([JPG image loading disabled])
   192     fi
   193 fi
   194 
   195 if test x$enable_png = xyes -a x$enable_imageio != xyes; then
   196     PKG_CHECK_MODULES([LIBPNG], [libpng], [dnl
   197         have_png_hdr=yes
   198         have_png_lib=yes
   199       ], [dnl
   200         AC_CHECK_HEADER([png.h], [
   201             have_png_hdr=yes
   202             LIBPNG_CFLAGS=""
   203         ])
   204         AC_CHECK_LIB([png], [png_create_read_struct], [
   205             have_png_lib=yes
   206             LIBPNG_LIBS="-lpng -lz"
   207         ], [], [-lz])
   208       ])
   209     if test x$have_png_hdr = xyes -a x$have_png_lib = xyes; then
   210         AC_DEFINE([LOAD_PNG])
   211 
   212         case "$host" in
   213             *-*-darwin*)
   214                 png_lib=[`find_lib libpng.dylib`]
   215                 ;;
   216             *-*-cygwin* | *-*-mingw32*)
   217                 png_lib=[`find_lib "libpng*.dll"`]
   218                 ;;
   219             *)
   220                 png_lib=[`find_lib "libpng[0-9]*.so.*"`]
   221                 if test x$png_lib = x; then
   222                     png_lib=[`find_lib "libpng.so.*"`]
   223                 fi
   224                 ;;
   225         esac
   226     else
   227         AC_MSG_WARN([*** Unable to find PNG library (http://www.libpng.org/pub/png/libpng.html)])
   228         AC_MSG_WARN([PNG image loading disabled])
   229     fi
   230 fi
   231 
   232 if test x$enable_tif = xyes -a x$enable_imageio != xyes; then
   233     AC_CHECK_HEADER([tiffio.h], [have_tif_hdr=yes])
   234     AC_CHECK_LIB([tiff], [TIFFClientOpen], [have_tif_lib=yes], [], [-lz])
   235     if test x$have_tif_hdr = xyes -a x$have_tif_lib = xyes; then
   236         AC_DEFINE([LOAD_TIF])
   237 
   238         case "$host" in
   239             *-*-darwin*)
   240                 tif_lib=[`find_lib libtiff.dylib`]
   241                 ;;
   242             *-*-cygwin* | *-*-mingw32*)
   243                 tif_lib=[`find_lib "libtiff-*.dll"`]
   244                 ;;
   245             *)
   246                 tif_lib=[`find_lib "libtiff[0-9]*.so.*"`]
   247                 if test x$tif_lib = x; then
   248                     tif_lib=[`find_lib "libtiff.so.*"`]
   249                 fi
   250                 ;;
   251         esac
   252     else
   253         AC_MSG_WARN([*** Unable to find Tiff library (http://www.remotesensing.org/libtiff/)])
   254         AC_MSG_WARN([TIF image loading disabled])
   255     fi
   256 fi
   257 
   258 if test x$enable_webp = xyes; then
   259     PKG_CHECK_MODULES([LIBWEBP], [libwebp], [dnl
   260         have_webp_hdr=yes
   261         have_webp_lib=yes
   262       ], [dnl
   263         AC_CHECK_HEADER([webp/decode.h], [
   264             have_webp_hdr=yes
   265             LIBWEBP_CFLAGS=""
   266         ])
   267         AC_CHECK_LIB([webp], [WebPGetDecoderVersion], [
   268             have_webp_lib=yes
   269             LIBWEBP_LIBS="-lwebp"
   270         ], [], [-lm])
   271       ])
   272     if test x$have_webp_hdr = xyes -a x$have_webp_lib = xyes; then
   273         AC_DEFINE([LOAD_WEBP])
   274 
   275         case "$host" in
   276             *-*-darwin*)
   277                 webp_lib=[`find_lib libwebp.dylib`]
   278                 ;;
   279             *-*-cygwin* | *-*-mingw32*)
   280                 webp_lib=[`find_lib "libwebp*.dll"`]
   281                 ;;
   282             *)
   283                 webp_lib=[`find_lib "libwebp[0-9]*.so.*"`]
   284                 if test x$webp_lib = x; then
   285                     webp_lib=[`find_lib "libwebp.so.*"`]
   286                 fi
   287                 ;;
   288         esac
   289     else
   290         AC_MSG_WARN([*** Unable to find WEBP library (http://code.google.com/intl/en-US/speed/webp/index.html)])
   291         AC_MSG_WARN([WEBP Pimage loading disabled])
   292     fi
   293 fi
   294 
   295 if test x$enable_bmp = xyes; then
   296     AC_DEFINE([LOAD_BMP])
   297 fi
   298 
   299 if test x$enable_gif = xyes; then
   300     AC_DEFINE([LOAD_GIF])
   301 fi
   302 
   303 if test x$enable_lbm = xyes; then
   304     AC_DEFINE([LOAD_LBM])
   305 fi
   306 
   307 if test x$enable_pcx = xyes; then
   308     AC_DEFINE([LOAD_PCX])
   309 fi
   310 
   311 if test x$enable_pnm = xyes; then
   312     AC_DEFINE([LOAD_PNM])
   313 fi
   314 
   315 if test x$enable_tga = xyes; then
   316     AC_DEFINE([LOAD_TGA])
   317 fi
   318 
   319 if test x$enable_xcf = xyes; then
   320     AC_DEFINE([LOAD_XCF])
   321 fi
   322 
   323 if test x$enable_xpm = xyes; then
   324     AC_DEFINE([LOAD_XPM])
   325 fi
   326 
   327 if test x$enable_xv = xyes; then
   328     AC_DEFINE([LOAD_XV])
   329 fi
   330 
   331 if test x$enable_webp = xyes -a x$have_webp_hdr = xyes -a x$have_webp_lib = xyes; then
   332     CFLAGS="$LIBWEBP_CFLAGS $CFLAGS"
   333     if test x$enable_webp_shared = xyes && test x$webp_lib != x; then
   334         echo "-- dynamic libwebp -> $webp_lib"
   335         AC_DEFINE_UNQUOTED(LOAD_WEBP_DYNAMIC, "$webp_lib")
   336     else
   337         IMG_LIBS="$LIBWEBP_LIBS $IMG_LIBS"
   338     fi
   339 fi
   340 
   341 if test x$enable_tif = xyes -a x$have_tif_hdr = xyes -a x$have_tif_lib = xyes; then
   342     if test x$enable_tif_shared = xyes && test x$tif_lib != x; then
   343         echo "-- dynamic libtiff -> $tif_lib"
   344         AC_DEFINE_UNQUOTED(LOAD_TIF_DYNAMIC, "$tif_lib")
   345     else
   346         if test x$have_libjpeg = xyes; then
   347             # Disable dynamic jpeg since we're linking it explicitly
   348             jpg_lib=''
   349         fi
   350         IMG_LIBS="-ltiff -lz $IMG_LIBS"
   351     fi
   352 fi
   353 if test x$enable_jpg = xyes -a x$have_jpg_hdr = xyes -a x$have_jpg_lib = xyes; then
   354     if test x$enable_jpg_shared = xyes && test x$jpg_lib != x; then
   355         echo "-- dynamic libjpeg -> $jpg_lib"
   356         AC_DEFINE_UNQUOTED(LOAD_JPG_DYNAMIC, "$jpg_lib")
   357     else
   358         IMG_LIBS="-ljpeg $IMG_LIBS"
   359     fi
   360 fi
   361 if test x$enable_png = xyes -a x$have_png_hdr = xyes -a x$have_png_lib = xyes; then
   362     CFLAGS="$LIBPNG_CFLAGS $CFLAGS"
   363     if test x$enable_png_shared = xyes && test x$png_lib != x; then
   364         echo "-- dynamic libpng -> $png_lib"
   365         AC_DEFINE_UNQUOTED(LOAD_PNG_DYNAMIC, "$png_lib")
   366     else
   367         IMG_LIBS="$LIBPNG_LIBS $IMG_LIBS"
   368     fi
   369 fi
   370 
   371 LIBS="$saved_LIBS"
   372 
   373 AC_SUBST([WINDRES])
   374 AC_SUBST([IMG_LIBS])
   375 
   376 OBJCFLAGS=$CFLAGS
   377 
   378 # Finally create all the generated files
   379 AC_OUTPUT([
   380 Makefile
   381 SDL2_image.spec
   382 SDL2_image.pc
   383 ])