configure.in
author Sam Lantinga <slouken@libsdl.org>
Sat, 02 Jan 2016 20:40:40 -0800
changeset 487 20954174d833
parent 467 2b0ada991468
child 491 4088a517f9a5
permissions -rw-r--r--
Updated to version 2.0.1
     1 dnl Process this file with autoconf to produce a configure script.
     2 AC_INIT(README.txt)
     3 
     4 dnl Set various version strings - taken gratefully from the GTk sources
     5 
     6 # Making releases:
     7 #   MICRO_VERSION += 1;
     8 #   INTERFACE_AGE += 1;
     9 #   BINARY_AGE += 1;
    10 # if any functions have been added, set INTERFACE_AGE to 0.
    11 # if backwards compatibility has been broken,
    12 # set BINARY_AGE and INTERFACE_AGE to 0.
    13 
    14 MAJOR_VERSION=2
    15 MINOR_VERSION=0
    16 MICRO_VERSION=1
    17 INTERFACE_AGE=1
    18 BINARY_AGE=1
    19 VERSION=$MAJOR_VERSION.$MINOR_VERSION.$MICRO_VERSION
    20 
    21 AC_SUBST(MAJOR_VERSION)
    22 AC_SUBST(MINOR_VERSION)
    23 AC_SUBST(MICRO_VERSION)
    24 AC_SUBST(INTERFACE_AGE)
    25 AC_SUBST(BINARY_AGE)
    26 AC_SUBST(VERSION)
    27 
    28 # libtool versioning
    29 LT_INIT([win32-dll])
    30 
    31 LT_RELEASE=$MAJOR_VERSION.$MINOR_VERSION
    32 LT_CURRENT=`expr $MICRO_VERSION - $INTERFACE_AGE`
    33 LT_REVISION=$INTERFACE_AGE
    34 LT_AGE=`expr $BINARY_AGE - $INTERFACE_AGE`
    35 
    36 AC_SUBST(LT_RELEASE)
    37 AC_SUBST(LT_CURRENT)
    38 AC_SUBST(LT_REVISION)
    39 AC_SUBST(LT_AGE)
    40 
    41 dnl Detect the canonical build and host environments
    42 AC_CANONICAL_HOST
    43 
    44 dnl Setup for automake
    45 AM_INIT_AUTOMAKE(SDL2_image, $VERSION)
    46 
    47 dnl Check for tools
    48 AC_PROG_LIBTOOL
    49 AC_PROG_CC
    50 AC_PROG_OBJC
    51 AC_C_INLINE
    52 AC_PROG_INSTALL
    53 AC_PROG_MAKE_SET
    54 if test -z "$host_alias"; then
    55     hostaliaswindres=
    56 else
    57     hostaliaswindres="$host_alias-windres"
    58 fi
    59 AC_CHECK_PROGS(WINDRES, [windres $hostaliaswindres $host_os-windres])
    60 
    61 case "$host" in
    62     *-*-beos*)
    63         ac_default_prefix=/boot/develop/tools/gnupro
    64         ;;
    65     *-*-cygwin* | *-*-mingw32*)
    66         if test "$build" != "$host"; then # cross-compiling
    67             # Default cross-compile location
    68             ac_default_prefix=/usr/local/cross-tools/$host
    69         else
    70             # Look for the location of the tools and install there
    71             if test "$BUILD_PREFIX" != ""; then
    72                 ac_default_prefix=$BUILD_PREFIX
    73             fi
    74         fi
    75         if test x$WINDRES != x; then
    76             use_version_rc=true
    77         fi
    78         ;;
    79     *-*-darwin*)
    80         AC_ARG_ENABLE([imageio], [AC_HELP_STRING([--enable-imageio], [use native Mac OS X frameworks for loading images [default=yes]])],
    81                       [], [enable_imageio=yes])
    82         if test x$enable_imageio = xyes; then
    83             IMG_LIBS="-Wl,-framework,ApplicationServices -lobjc $IMG_LIBS"
    84         else
    85             CFLAGS="$CFLAGS -DSDL_IMAGE_USE_COMMON_BACKEND"
    86         fi
    87         ;;
    88 esac
    89 AM_CONDITIONAL(USE_IMAGEIO, test x$enable_imageio = xyes)
    90 AM_CONDITIONAL(USE_VERSION_RC, test x$use_version_rc = xtrue)
    91 
    92 dnl set this to use on systems that use lib64 instead of lib
    93 base_libdir=`echo \${libdir} | sed 's/.*\/\(.*\)/\1/; q'`
    94 
    95 dnl Function to find a library in the compiler search path
    96 find_lib()
    97 {
    98     gcc_bin_path=[`$CC -print-search-dirs 2>/dev/null | fgrep programs: | sed 's/[^=]*=\(.*\)/\1/' | sed 's/:/ /g'`]
    99     gcc_lib_path=[`$CC -print-search-dirs 2>/dev/null | fgrep libraries: | sed 's/[^=]*=\(.*\)/\1/' | sed 's/:/ /g'`]
   100     env_lib_path=[`echo $LIBS $LDFLAGS $* | sed 's/-L[ ]*//g'`]
   101     if test "$cross_compiling" = yes; then
   102         host_lib_path=""
   103     else
   104         host_lib_path="/usr/$base_libdir /usr/local/$base_libdir"
   105     fi
   106     for path in $env_lib_path $gcc_bin_path $gcc_lib_path $host_lib_path; do
   107         lib=[`ls -- $path/$1 2>/dev/null | sed -e '/\.so\..*\./d' -e 's,.*/,,' | sort | tail -1`]
   108         if test x$lib != x; then
   109             echo $lib
   110             return
   111         fi
   112     done
   113 }
   114 
   115 dnl Check for SDL
   116 SDL_VERSION=2.0.0
   117 AC_SUBST(SDL_VERSION)
   118 AM_PATH_SDL2($SDL_VERSION,
   119             :,
   120            AC_MSG_ERROR([*** SDL version $SDL_VERSION not found!])
   121 )
   122 CFLAGS="$CFLAGS $SDL_CFLAGS"
   123 LIBS="$LIBS $SDL_LIBS"
   124 saved_LIBS="$LIBS"
   125 
   126 dnl Check command-line options
   127 AC_ARG_ENABLE([bmp], [AC_HELP_STRING([--enable-bmp], [support loading BMP/ICO/CUR images [default=yes]])],
   128  [], [enable_bmp=yes])
   129 AC_ARG_ENABLE([gif], [AC_HELP_STRING([--enable-gif], [support loading GIF images [default=yes]])],
   130  [], [enable_gif=yes])
   131 AC_ARG_ENABLE([jpg], [AC_HELP_STRING([--enable-jpg], [support loading JPG images [default=yes]])],
   132  [], [enable_jpg=yes])
   133 AC_ARG_ENABLE([jpg-shared], AC_HELP_STRING([--enable-jpg-shared], [dynamically load JPG support [[default=yes]]]),
   134  [], [enable_jpg_shared=yes])
   135 AC_ARG_ENABLE([lbm], [AC_HELP_STRING([--enable-lbm], [support loading LBM images [default=yes]])],
   136  [], [enable_lbm=yes])
   137 AC_ARG_ENABLE([pcx], [AC_HELP_STRING([--enable-pcx], [support loading PCX images [default=yes]])],
   138  [], [enable_pcx=yes])
   139 AC_ARG_ENABLE([png], [AC_HELP_STRING([--enable-png], [support loading PNG images [default=yes]])],
   140  [], [enable_png=yes])
   141 AC_ARG_ENABLE([png-shared], AC_HELP_STRING([--enable-png-shared], [dynamically load PNG support [[default=yes]]]),
   142  [], [enable_png_shared=yes])
   143 AC_ARG_ENABLE([pnm], [AC_HELP_STRING([--enable-pnm], [support loading PNM images [default=yes]])],
   144  [], [enable_pnm=yes])
   145 AC_ARG_ENABLE([tga], [AC_HELP_STRING([--enable-tga], [support loading TGA images [default=yes]])],
   146  [], [enable_tga=yes])
   147 AC_ARG_ENABLE([tif], [AC_HELP_STRING([--enable-tif], [support loading TIFF images [default=yes]])],
   148  [], [enable_tif=yes])
   149 AC_ARG_ENABLE([tif-shared], AC_HELP_STRING([--enable-tif-shared], [dynamically load TIFF support [[default=yes]]]),
   150  [], [enable_tif_shared=yes])
   151 AC_ARG_ENABLE([xcf], [AC_HELP_STRING([--enable-xcf], [support loading XCF images [default=yes]])],
   152  [], [enable_xcf=yes])
   153 AC_ARG_ENABLE([xpm], [AC_HELP_STRING([--enable-xpm], [support loading XPM images [default=yes]])],
   154  [], [enable_xpm=yes])
   155 AC_ARG_ENABLE([xv], [AC_HELP_STRING([--enable-xv], [support loading XV images [default=yes]])],
   156  [], [enable_xv=yes])
   157 AC_ARG_ENABLE([webp], [AC_HELP_STRING([--enable-webp], [support loading WEBP images [default=yes]])],
   158  [], [enable_webp=yes])
   159 AC_ARG_ENABLE([webp-shared], AC_HELP_STRING([--enable-webp-shared], [dynamically load WEBP support [[default=yes]]]),
   160  [], [enable_webp_shared=yes])
   161 
   162 dnl Show a message when we use ImageIO support so it's not a surprise
   163 AC_MSG_CHECKING([for ImageIO support])
   164 AC_MSG_RESULT($enable_imageio)
   165 
   166 if (test x$enable_jpg = xyes || test x$enable_tif = xyes) && test x$enable_imageio != xyes; then
   167     AC_CHECK_HEADER([jpeglib.h], [have_jpg_hdr=yes])
   168     AC_CHECK_LIB([jpeg], [jpeg_CreateDecompress], [have_jpg_lib=yes])
   169     if test x$have_jpg_hdr = xyes -a x$have_jpg_lib = xyes; then
   170         if test x$enable_jpg = xyes; then
   171             AC_DEFINE([LOAD_JPG])
   172         fi
   173         LIBS="-ljpeg $LIBS"
   174 
   175         case "$host" in
   176             *-*-darwin*)
   177                 jpg_lib=[`find_lib libjpeg.dylib`]
   178                 ;;
   179             *-*-cygwin* | *-*-mingw32*)
   180                 jpg_lib=[`find_lib "libjpeg*.dll"`]
   181                 ;;
   182             *)
   183                 jpg_lib=[`find_lib "libjpeg[0-9]*.so.*"`]
   184                 if test x$jpg_lib = x; then
   185                     jpg_lib=[`find_lib "libjpeg.so.*"`]
   186                 fi
   187                 ;;
   188         esac
   189     elif test x$enable_jpg = xyes; then
   190         AC_MSG_WARN([*** Unable to find JPEG library (http://www.ijg.org/)])
   191         AC_MSG_WARN([JPG image loading disabled])
   192     fi
   193 fi
   194 
   195 if test x$enable_png = xyes -a x$enable_imageio != xyes; then
   196     PKG_CHECK_MODULES([LIBPNG], [libpng], [dnl
   197         have_png_hdr=yes
   198         CFLAGS="$LIBPNG_CFLAGS $CFLAGS"
   199         have_png_lib=yes
   200       ], [dnl
   201         AC_CHECK_HEADER([png.h], [have_png_hdr=yes])
   202         AC_CHECK_LIB([png], [png_create_read_struct], [have_png_lib=yes], [], [-lz])
   203       ])
   204     if test x$have_png_hdr = xyes -a x$have_png_lib = xyes; then
   205         AC_DEFINE([LOAD_PNG])
   206 
   207         case "$host" in
   208             *-*-darwin*)
   209                 png_lib=[`find_lib libpng.dylib`]
   210                 ;;
   211             *-*-cygwin* | *-*-mingw32*)
   212                 png_lib=[`find_lib "libpng*.dll"`]
   213                 ;;
   214             *)
   215                 png_lib=[`find_lib "libpng[0-9]*.so.*"`]
   216                 if test x$png_lib = x; then
   217                     png_lib=[`find_lib "libpng.so.*"`]
   218                 fi
   219                 ;;
   220         esac
   221     else
   222         AC_MSG_WARN([*** Unable to find PNG library (http://www.libpng.org/pub/png/libpng.html)])
   223         AC_MSG_WARN([PNG image loading disabled])
   224     fi
   225 fi
   226 
   227 if test x$enable_tif = xyes -a x$enable_imageio != xyes; then
   228     AC_CHECK_HEADER([tiffio.h], [have_tif_hdr=yes])
   229     AC_CHECK_LIB([tiff], [TIFFClientOpen], [have_tif_lib=yes], [], [-lz])
   230     if test x$have_tif_hdr = xyes -a x$have_tif_lib = xyes; then
   231         AC_DEFINE([LOAD_TIF])
   232 
   233         case "$host" in
   234             *-*-darwin*)
   235                 tif_lib=[`find_lib libtiff.dylib`]
   236                 ;;
   237             *-*-cygwin* | *-*-mingw32*)
   238                 tif_lib=[`find_lib "libtiff-*.dll"`]
   239                 ;;
   240             *)
   241                 tif_lib=[`find_lib "libtiff[0-9]*.so.*"`]
   242                 if test x$tif_lib = x; then
   243                     tif_lib=[`find_lib "libtiff.so.*"`]
   244                 fi
   245                 ;;
   246         esac
   247     else
   248         AC_MSG_WARN([*** Unable to find Tiff library (http://www.remotesensing.org/libtiff/)])
   249         AC_MSG_WARN([TIF image loading disabled])
   250     fi
   251 fi
   252 
   253 if test x$enable_webp = xyes; then
   254     PKG_CHECK_MODULES([LIBWEBP], [libwebp], [dnl
   255         have_webp_hdr=yes
   256         CFLAGS="$LIBWEBP_CFLAGS $CFLAGS"
   257         have_webp_lib=yes
   258       ], [dnl
   259         AC_CHECK_HEADER([webp/decode.h], [have_webp_hdr=yes])
   260         AC_CHECK_LIB([webp], [WebPGetDecoderVersion], [have_webp_lib=yes], [], [-lm])
   261       ])
   262     if test x$have_webp_hdr = xyes -a x$have_webp_lib = xyes; then
   263         AC_DEFINE([LOAD_WEBP])
   264 
   265         case "$host" in
   266             *-*-darwin*)
   267                 webp_lib=[`find_lib libwebp.dylib`]
   268                 ;;
   269             *-*-cygwin* | *-*-mingw32*)
   270                 webp_lib=[`find_lib "libwebp*.dll"`]
   271                 ;;
   272             *)
   273                 webp_lib=[`find_lib "libwebp[0-9]*.so.*"`]
   274                 if test x$webp_lib = x; then
   275                     webp_lib=[`find_lib "libwebp.so.*"`]
   276                 fi
   277                 ;;
   278         esac
   279     else
   280         AC_MSG_WARN([*** Unable to find WEBP library (http://code.google.com/intl/en-US/speed/webp/index.html)])
   281         AC_MSG_WARN([WEBP Pimage loading disabled])
   282     fi
   283 fi
   284 
   285 if test x$enable_bmp = xyes; then
   286     AC_DEFINE([LOAD_BMP])
   287 fi
   288 
   289 if test x$enable_gif = xyes; then
   290     AC_DEFINE([LOAD_GIF])
   291 fi
   292 
   293 if test x$enable_lbm = xyes; then
   294     AC_DEFINE([LOAD_LBM])
   295 fi
   296 
   297 if test x$enable_pcx = xyes; then
   298     AC_DEFINE([LOAD_PCX])
   299 fi
   300 
   301 if test x$enable_pnm = xyes; then
   302     AC_DEFINE([LOAD_PNM])
   303 fi
   304 
   305 if test x$enable_tga = xyes; then
   306     AC_DEFINE([LOAD_TGA])
   307 fi
   308 
   309 if test x$enable_xcf = xyes; then
   310     AC_DEFINE([LOAD_XCF])
   311 fi
   312 
   313 if test x$enable_xpm = xyes; then
   314     AC_DEFINE([LOAD_XPM])
   315 fi
   316 
   317 if test x$enable_xv = xyes; then
   318     AC_DEFINE([LOAD_XV])
   319 fi
   320 
   321 if test x$enable_webp = xyes -a x$have_webp_hdr = xyes -a x$have_webp_lib = xyes; then
   322     if test x$enable_webp_shared = xyes && test x$webp_lib != x; then
   323         echo "-- dynamic libwebp -> $webp_lib"
   324         AC_DEFINE_UNQUOTED(LOAD_WEBP_DYNAMIC, "$webp_lib")
   325     else
   326         IMG_LIBS="-lwebp $IMG_LIBS"
   327     fi
   328 fi
   329 
   330 if test x$enable_tif = xyes -a x$have_tif_hdr = xyes -a x$have_tif_lib = xyes; then
   331     if test x$enable_tif_shared = xyes && test x$tif_lib != x; then
   332         echo "-- dynamic libtiff -> $tif_lib"
   333         AC_DEFINE_UNQUOTED(LOAD_TIF_DYNAMIC, "$tif_lib")
   334     else
   335         if test x$have_libjpeg = xyes; then
   336             # Disable dynamic jpeg since we're linking it explicitly
   337             jpg_lib=''
   338         fi
   339         IMG_LIBS="-ltiff -lz $IMG_LIBS"
   340     fi
   341 fi
   342 if test x$enable_jpg = xyes -a x$have_jpg_hdr = xyes -a x$have_jpg_lib = xyes; then
   343     if test x$enable_jpg_shared = xyes && test x$jpg_lib != x; then
   344         echo "-- dynamic libjpeg -> $jpg_lib"
   345         AC_DEFINE_UNQUOTED(LOAD_JPG_DYNAMIC, "$jpg_lib")
   346     else
   347         IMG_LIBS="-ljpeg $IMG_LIBS"
   348     fi
   349 fi
   350 if test x$enable_png = xyes -a x$have_png_hdr = xyes -a x$have_png_lib = xyes; then
   351     if test x$enable_png_shared = xyes && test x$png_lib != x; then
   352         echo "-- dynamic libpng -> $png_lib"
   353         AC_DEFINE_UNQUOTED(LOAD_PNG_DYNAMIC, "$png_lib")
   354     else
   355         IMG_LIBS="-lpng -lz $IMG_LIBS"
   356     fi
   357 fi
   358 
   359 LIBS="$saved_LIBS"
   360 
   361 AC_SUBST([WINDRES])
   362 AC_SUBST([IMG_LIBS])
   363 
   364 OBJCFLAGS=$CFLAGS
   365 
   366 # Finally create all the generated files
   367 AC_OUTPUT([
   368 Makefile
   369 SDL2_image.spec
   370 SDL2_image.pc
   371 ])